Sometimes I wonder...

// LUCKY EJECTOR!

// Just like a lucky chair, but all the lucky winners in range are ejected
// from your land.

// Rez a cube and put this script in it.  It will only work if it belongs
// to the land owner (or deeded if group owned land).

// ------------------------
// stuff you want to change:

// time in seconds to change letters
float timerInterval = 120.;

// how far our reach is, in meters.
float sensorRange = 10.;

// the characters we will choose from for teh luckness. Needs to be a
// subset of txtAlphabet belowe, ordering is not important. Repeat
// characters if you want to stack the odds :o  You can add  digits
// if you want too, some people have names starting with those.
string letters = "ABCDEFGHIJKLMNOPQRSTUVWXYZ?";


// ------------------------
// Stuff you probably want to leave alone:

// a texture with characters on it so we can display them and all that.
key txtUUID = "abed27eb-71a6-7949-c684-6bfd1e77a1d7";

// this is the character set represented in the txtUUID texture.
// Its ordering does have to match the texture.
string txtAlphabet = 
    "ABCDEFGHIJKLMNOPQRSTUVWXYZ1234567890.,!@#$%^&*()-+=[]<>?/\|`~\"' ";

// Offset for the corner of the texture
vector txtOffsetA = <-0.4375, 0.4375, 0.> ;

// how far we have to shift the texture for 1 character.
float txtStep = 0.125;

// the current "lucky letter"
string luckyLetter = "";


// using all the fiddly constants above, shift our texture around so that it
// displays the requested character.
setletter (string ch) {
    if (llStringLength(ch) == 0)
        ch = " ";
    ch = llGetSubString(ch, 0, 0);
    integer strIndex = llSubStringIndex(txtAlphabet, ch);
    if (strIndex == -1)
        strIndex = llStringLength(ch) - 1;
    integer vIndex = strIndex / 8;
    integer hIndex = strIndex % 8;
    vector myTxtOffset = txtOffsetA;
    myTxtOffset.x += ((float) hIndex * 0.125);
    myTxtOffset.y -= (((float) vIndex * 0.125) + .003);

    llSetPrimitiveParams([PRIM_TEXTURE, ALL_SIDES, (string)txtUUID, <0.11, 0.11, 0>, myTxtOffset, 0.0]);
}


// choose our next set of lucky winners, at startup and on each timer tick.
next_round() {
    integer i = llFloor(llFrand(llStringLength(letters)));
    luckyLetter = llGetSubString(letters, i, i);
    if (luckyLetter == "?") {
        llSay(0, "IT'S A BLOWOUT! EVERYONE MUST GO!");
    }   
    else {
        llSay(
            0, "We're looking for anyone whose name begins with " +
            luckyLetter + "! Do you feel lucky? Well do ya, punk?"
        );
    }   
    setletter(luckyLetter);
}


// LSL event stuff
default {
    state_entry()
    {
        llSensorRepeat("", "", AGENT, sensorRange, PI, 10.);
        next_round();
        llSetTimerEvent(timerInterval);
    }

    timer() 
    {
        next_round();
    }

    sensor(integer num_detected) {
        integer i;
        for (i = 0; i < num_detected; i++) {
            string nextVictim = llDetectedName(i);
            if (luckyLetter == "?"
                || llToUpper(llGetSubString(nextVictim, 0, 0)) == luckyLetter) {

                // we have a winner!
                key VictimID = llDetectedKey(i);
                if (llOverMyLand(VictimID)) {
                    llSay(0, "w00t! " + nextVictim + "is a lucky wiener!");
                    llEjectFromLand(VictimID);
                }
            }
        }   
    }
}