AV Detector?

list gAvs = []; //sets up our info for creating a list of avatars sensed and thier position
list gpos = [];
integer gMarker = 0;

default
{
    state_entry()
    {
        llSensorRepeat("",NULL_KEY,AGENT,96,PI,1); //sets up the sensor. since we want it to update fairly regularly I have it set at 1 second
    }

    sensor(integer total_number)
    {
        gAvs = []; //sets the lists to null set to stop stack heap collisions
        gpos = [];
        llSetText((string) total_number + " Avatars Found",<1,1,1>,1); //displays how many avtars were found.
        integer i;
        for ( i = 0; i < total_number; i++) //loop to create our lists.
        {
            gAvs = gAvs + [llDetectedName(i)];
            gpos = gpos + [llDetectedPos(i)];
        }
        for ( i = 0; i < total_number; i++) //loop to rez the marker object at the appropriate spot. note the divisor 64 in the rezpos. that is so that the 96m radius will fit on a 3m diameter (1.5m radius) disc. if you wish to use a different size "map" then you should adjust this value accordingly.
        {
            vector rezpos =(-llGetPos() + llList2Vector(gpos,i))/64;
            vector rezat = (rezpos + llGetPos());
            float dist = llVecDist(llList2Vector(gpos,i),llGetPos());
            llRezObject("Marker",rezat,ZERO_VECTOR,ZERO_ROTATION,llRound(dist));
        }
    }
    
    no_sensor()
    {
        llSetText("No Avatars Found",<1,1,1>,1);
    }
}

default
{
    state_entry()
    {
    }

    on_rez(integer distance)
    {
        distance = llGetStartParameter(); //gets the distance away from the map that is sent when this object is rezzed
        llSetText((string) distance + "m",<0,1,0>,1); //sets the text on the marker to show how far away the avtar is in the world.
        llSleep(7); //delay in the script before killing the marker. this number should be changing depending on the number of avatars sensed, since with less than 3 avatars a value of 3 works smoothly, but when dealing with 15-20 values around 7 or 8 appear to be smooth.
        llDie();
    }
}

// Visual Radar Device script v0.3
// Ordinal Malaprop
// 2005-11-29
// Free for distribution, please do not sell

float radius=2.0;
vector offset=<0,0,0.25>;
float range=96.0;
float scanInterval=1.0;
integer baseChannel=10000;
integer listenNum;
float version=0.3;
integer lastN=0;

//------------------------------------------------------------------
// Supporting functions

// Interprets heard text

interpret(string message)
{
    if (llGetSubString(message, 0, 6) == "radius ") {
        radius = (float)llDeleteSubString(message, 0, 6);
        llOwnerSay("Radius set to " + (string)radius);
    }
    if (llGetSubString(message, 0, 8) == "interval ") {
        scanInterval = (float)llDeleteSubString(message, 0, 8);
        llOwnerSay("Scan interval set to " + (string)scanInterval
         + " - restart scan to activate");
    }
}

// Gives a credits notecard when touched by non-owner

give_credits(key toucher)
{
    llGiveInventory(toucher, "Visual Radar Notes");
}

// Kills n existing markers

killAll(integer n)
{
    llSay(baseChannel, "dienow");
    integer f;
    if (n != 0) {
        for (f=0; f<n; f++) {
            llSay(baseChannel+f+1, "dienow");
        }
    }
}

//------------------------------------------------------------------
// States

default
{
    on_rez(integer a)
    {
        llOwnerSay("Visual radar rezzed - touch me to start scan");
    }
    
    state_entry()
    {
        llSetAlpha(0.5, ALL_SIDES);
        listenNum = llListen(0, "", llGetOwner(), "");
    }
    
    // Turn off the listen on exit
    state_exit()
    {
        llListenRemove(listenNum);
    }
    
    // Start scan when touched
    touch_start (integer n)
    {
        if (llDetectedKey(0) == llGetOwner()) {
            state scanning;
        } else {
            give_credits(llDetectedKey(0));
        }
    }
    
    // Deal with spoken commands
    listen(integer channel, string name, key id, string message)
    {
        interpret(message);
    }
}

// Scanning state - turned on and displaying

state scanning
{
    state_entry()
    {
        llOwnerSay("Entering scan mode");
        llSetAlpha(1.0, ALL_SIDES);
        // Start scanning
        llSensorRepeat("", NULL_KEY, AGENT, 96.0, PI*2, scanInterval);
        llPlaySound("turn_on", 1.0);
        // Start listening for commands
        listenNum = llListen(0, "", llGetOwner(), "");
    }
    
    // Clean up on exit
    state_exit()
    {
        llOwnerSay("Exiting scan mode");
        llSensorRemove();
        llSetText("", <1.0,0,0>, 1.0);
        llPlaySound("turn_off", 1.0);
        llListenRemove(listenNum);
        killAll(lastN);
        lastN = 0;
    }
    
    // When targets detected...
    sensor(integer n)
    {
        integer f;
        // Kill the old base marker and add a new one
        llSay(baseChannel, "dienow");
        llRezObject("Marker", llGetPos()+offset, ZERO_VECTOR, ZERO_ROTATION, -1);
        // Determine the furthest avatar from the scanner, for scaling
        float maxRange=0.0;
        for (f=0; f<n; f++) {
            if (llVecDist(llDetectedPos(f), llGetPos()) > maxRange) {
                maxRange=llVecDist(llDetectedPos(f), llGetPos());
            }
        }
        float scale = radius/maxRange;
        // For each detected av...
        for (f=0; f<n; f++) {
            vector relPos = llDetectedPos(f) - llGetPos();
            vector markerPos = (relPos*scale) + llGetPos()+offset;
            // Kill the old marker with this number
            llSay(baseChannel+f+1, "dienow");
            // Create a new one
            llRezObject("Marker", markerPos, ZERO_VECTOR, ZERO_ROTATION, 
            f+1);
            // Tell marker if this is the owner
            if (llDetectedKey(f) == llGetOwner()) {
                llSay(baseChannel+f+1, "owner");
            }
            // Give marker name and distance information
            llSay(baseChannel+f+1, llDetectedName(f) + "\n" + 
            (string)((integer)llVecDist(llDetectedPos(f), llGetPos())) + 
            "m");
        }
        // If there are fewer markers than on the last iteration,
        // clean up any extras
        f++;
        while (f <= lastN) {
            llSay(baseChannel+f+1, "dienow");
            f++;
        }
        lastN = n;
    }
    
    // Turn off scanning if touched by owner
    touch_start (integer n)
    {
        if (llDetectedKey(0) == llGetOwner()) {
            state default;
        } else {
            give_credits(llDetectedKey(0));
        }
    }
    
    // Deal with spoken commands
    listen(integer channel, string name, key id, string message)
    {
        interpret(message);
    }
}

vector homeColor = <1.0, 0.0, 0.0>;
vector avColor = <0.0, 1.0, 0.0>;
vector ownerColor = <1.0, 1.0, 0.0>;
integer agentNum;
vector textColour = <1.0,1.0,1.0>;
float textAlpha = 0.75;
float lifespan = 30.0;
integer baseChannel = 10000;

default
{
    on_rez(integer param)
    {
//        llOwnerSay("Rezzed at " + (string)llGetPos());
        if (param != 0) {
            llSetTimerEvent(lifespan);
        }
        if (param == -1) {
            llSetColor(homeColor, ALL_SIDES);
            llListen(baseChannel, "Visual Radar Display", NULL_KEY, "");
        } else if (param != 0) {
            llSetColor(avColor, ALL_SIDES);
            agentNum = param - 1;
            llListen(baseChannel+param, "Visual Radar Display", NULL_KEY, "");
        }
    }
    
    listen(integer channel, string name, key id, string message)
    {
        if (message == "owner") {
            llSetColor(ownerColor, ALL_SIDES);
        } else if (message == "dienow") {
            llDie();
        } else {
            llSetText(message, textColour, textAlpha);
        }
    }

    timer()
    {
        llDie();
    }
}

// test

list g_lNames;
list g_lLastReports;
float g_gLastRepReq = 0;

default
{
    state_entry()
    {
        llListen(4242, "", NULL_KEY, "");
        llListen(0, "", llGetOwner(), "");
        llSensorRepeat("", NULL_KEY, AGENT, 255, PI*2, .2);
//        llSensorRepeat("", llGetOwner(), AGENT, 255, PI*2, .2);
        llSetTimerEvent(10);
    }

    touch_start(integer total_number)
    {
    }
    
    listen(integer iChannel, string strName, key id, string strMsg)
    {
        if(iChannel == 0)
        {
            if(strMsg == "reset")
            {
                llSay(4242, "end");
            }
            return;
        }
        if(id == llGetKey())
        {
            return;
        }
        if(llGetSubString(strMsg, 0, 2) == "die")
        {
            string strName = llGetSubString(strMsg, 4, -1);
            list l = [strName];
            integer iIndex = llListFindList(g_lNames, l);
            if(iIndex > -1)
            {
                llWhisper(0, "Killing entry for " + strName);

                g_lNames = llDeleteSubList(g_lNames, iIndex, iIndex);
                g_lLastReports = llDeleteSubList(g_lLastReports, iIndex, iIndex);
            }
        }
        else // assume its a key report
        {
            integer iLen = llGetListLength(g_lNames);
            string s = strMsg;
            list l = ;
            integer iIndex = llListFindList(g_lNames, l);
            if(iIndex > -1)
            {
                list lNew;
                integer iReports = 0;
                for(iReports = 0; iReports < iLen; ++iReports)
                {
                    if(iReports != iIndex)
                    {
                        lNew += llList2Float(g_lLastReports, iReports);
                    }
                    else
                    {
                        lNew += llGetTime();
                    }
                } // end for all last reports
                g_lLastReports = lNew;
            }
        }
    } // end listen
    

    sensor(integer iNum)
    {
        integer i = 0;
        for(i = 0; i < iNum; ++i)
        {
            string s = llDetectedName(i);
            list l = ;
            integer iIndex = llListFindList(g_lNames, l);
            if(iIndex == -1)
            {
                llWhisper(0, "Making icon for " + s);
                llRezObject("AVIcon", llGetPos(), ZERO_VECTOR, <0,0,0,0>, 4243+i);
                g_lNames += s;
                g_lLastReports += llGetTime();
                llSleep(.25);
                llSay(4243+i, s);
                llSleep(.25);
                llSay(4243+i, "go";
            }
        }
    }    
    
    timer()
    {
        integer i = 0;
        integer iLen = llGetListLength(g_lLastReports);
        float fNow = llGetTime();
        for(i=0; i < iLen; ++i)
        {
            float fLastReport = fNow - llList2Float(g_lLastReports, i);
            if(fLastReport > 120)
            {
                llWhisper(0, "Killing entry for " + llList2String(g_lNames, i));
                g_lNames = llDeleteSubList(g_lNames, i, i);
                g_lLastReports = llDeleteSubList(g_lLastReports, i, i);
            }
            else if(fLastReport > 30)
            {
                llSay(4242, "report " + llList2String(g_lNames, i));        
            }
        }
        
    }
}

        // Determine the furthest avatar from the scanner, for scaling
        float maxRange=0.0;
        for (f=0; f<n; f++) {
            if (llVecDist(llDetectedPos(f), llGetPos()) > maxRange) {
                maxRange=llVecDist(llDetectedPos(f), llGetPos());
            }
        }

sensor (integer x) { float maxRange = llVecDist(llDetectedPos(x - 1), llGetPos()); }

vector avatarSize = llGetAgentSize(llDetectedKey(i));
pos = pos + <0,0,(avatarSize.z / 2.0)>;