Looking for a *very* simplified HUD for offering to hug

From: Clintok Meyer

Thanks for the response however, it wasn't helpful. I have, as I stated above, a free source HUD and I understand how they work conceptually and also understand a lot of the script in it.

What I asked for and perhaps I confused you, was a "simpler example". I want to see the code that does this:

Ask a person a question and get their response. If they say 'yes' animate them and then animate me.


Telling me to go look at a thread or grab another person's hug doesn't answer my question, but maybe someone else will read this and kindly (as has been done in other threads) cut out and paste the X lines of code that will do what I want.

Hopefully someone, maybe not here, will post a simpler example from which I can expand.

The problem with free hug huds is they want to use the SAME hug for both people and do about 20 things I am not looking to do.

My typing /hug works with the hud I bought, I want to do it with a hud I *make*.

Again thanks for trying to help.

Pretty please if anyone here is actually a programmer, could you possibly cut and past the few lines of code that do what I am asking?

In the meantime /prays for better examples on lsl wiki.

All I need is a decent example......


Thanks very much

llRequestPermissions( target ,PERMISSION_TRIGGER_ANIMATION );

llStartAnimation( animName );
llSleep(animTime);
llStopAnimation( animName );

// Multi time Hugger script.
// Newgy-ised version of Freebie Hug script.
// original reference as "Francis was here" - Francis Cheung?

// Constants
integer Channel           = 1;
integer sensorDistance    = 10;
string  HuggerAnimName    = "hug them";
string  HuggeeAnimName    = "be hugged";
integer animTime          = 30;

// Constants (used by linked messages to control actions)
integer  HUG_REQUEST  = 1;
integer  HUG_START    = 2;
integer  HUG_RESET    = 3;
integer  HUG_DECLINED = 4;
integer  HUG_ANIM     = 100;


// Not Constants
string   ownerName = "";
key      ownerKey = NULL_KEY;
string   avTarget = "";
key      avKey = NULL_KEY;
integer  avFindName = TRUE;
vector avPos;
rotation avRot;

string GetName(key id)
{
    // Get a name from a key
    string name = llKey2Name( id );
    // Reduces it to just their first name
    name = llList2String( llParseString2List( name, [ " " ], [] ), 0 );
}

usageMessage()
{
    llInstantMessage( llGetOwner(), "Usage: Face your target and Say '/" + (string)Channel + "hug [person's name]'" );
}

MoveCloser()
{
    // Move us towards the target in 3 stages.
    vector  posOffset1 = <0.3, 0, 0>;
    vector  posOffset2 = <0, 0, 0>;
    vector pos = avPos + posOffset1 * avRot;
    llMoveToTarget( pos, .5 );
    llSleep(.6);
    pos = avPos + posOffset2 * avRot;
    llMoveToTarget( pos, .5 );
    llSleep(.6);
    llMoveToTarget( pos, 1 );
    llSleep(1);
    llStopMoveToTarget();
}

SaySomethingNice()
{
    // Switch the objects name to our name
    string origName = llGetObjectName();
    llSetObjectName( ownerName );
    llSay( 0, "/me gives " + avTarget + " a hug." );
    // Switch the objects name back
    llSetObjectName( origName );
}

Animate()
{
    llStartAnimation( HuggerAnimName );
    llSleep( animTime );
    llStopAnimation( HuggerAnimName );
}

default
{
    state_entry() 
    {
        ownerKey = llGetOwner();
        ownerName = GetName(ownerKey);
        
        if ( llGetAttached() )
            llRequestPermissions(ownerKey,PERMISSION_TRIGGER_ANIMATION);
        usageMessage();
        llMessageLinked( LINK_SET, HUG_RESET, "", NULL_KEY );
    }
    
    on_rez( integer startcode ) 
    {
        llResetScript();
    }
    
    attach( key id ) 
    {
        if ( id != NULL_KEY )
            llResetScript();            
    }
    
    run_time_permissions(integer parm) 
    {
        if( parm & PERMISSION_TRIGGER_ANIMATION ) 
        {
            llListen( Channel, "", ownerKey, "" );
        }
    }
    
    sensor(integer total_number) 
    {
        if ( avFindName ) 
        {
            integer i;
            for ( i = 0; i < total_number; i++ ) 
            {
                // Ignore the owner
                if ( llDetectedKey(i) != ownerKey ) 
                {
                    // Check the names against the supplied text
                    if ( llSubStringIndex(llToLower(llDetectedName(i)), avTarget) >= 0 ) 
                    {
                        avKey = llDetectedKey(i);
                        avTarget = GetName(avKey);
                        
                        llInstantMessage( llGetOwner(), "You have offered to hug " + avTarget + "." );
                        llMessageLinked( LINK_SET, HUG_REQUEST, ownerName + " would like give you a hug. Say [Yes] to accept.", avKey );                        
                        return;
                    }
                }
            }
        }
        else 
        {
            avPos = llDetectedPos(0);
            avRot = llDetectedRot(0);

            // Move close to the target
            MoveCloser();
            
            // Say a nice message
            SaySomethingNice();
            
            // And then, do the anim - a bit of a hack to pass over time period
            llMessageLinked( LINK_SET, HUG_ANIM + animTime, HuggeeAnimName, NULL_KEY );
            Animate();
        }
    }
    
    no_sensor() 
    {
        llInstantMessage( ownerKey, "Sorry but I Couldn't find '" + avTarget + "'" );
        llMessageLinked( LINK_SET, HUG_RESET, "", NULL_KEY );
    }
    
    link_message( integer sender, integer number, string s, key id ) 
    {
        if ( number == HUG_START ) 
        {
            // Refind the target incase they moved away
            avFindName = FALSE;
            llSensor( "", avKey, AGENT, sensorDistance, PI );
        }
        else if ( number == HUG_DECLINED ) 
        {
            llInstantMessage( llGetOwner(), avTarget + " has declined your hug." );
        }
    }

    listen(integer channel,string name,key id,string message) 
    {
        // Look for the hug request
        list ldata = llParseString2List(llToLower(message), [ " " ], [ "" ]);
        string command = llList2String(ldata,0);
        if( "hug" == command ) 
        {
            avFindName = TRUE;
            avTarget = llList2String(ldata,1);
            llSensor( "", NULL_KEY, AGENT, sensorDistance, PI );
        }
    }
}

// Huggee script.
// Newgy-ised version of Freebie Hug script.
// original reference as "Francis was here" - Francis Cheung?


// Constants (used by linked messages to control actions)
integer  HUG_REQUEST  = 1;
integer  HUG_START    = 2;
integer  HUG_ANIM     = 3;
integer  HUG_RESET    = 4;
integer  HUG_DECLINED = 5;

// Variables
key      avKey = NULL_KEY; // Key of Huggee

Reset()
{
    llSetTimerEvent(0); // Stop any running timers
    avKey = NULL_KEY;   // Nullify current target
}

default
{
    state_entry() 
    {
        Reset();
    }

    link_message( integer sender, integer number, string message, key id ) 
    {
        if( number == HUG_REQUEST ) 
        {
            // Ask the target if they want to be hugged
            llRequestPermissions( id ,PERMISSION_TRIGGER_ANIMATION );
            llInstantMessage( id, message );
            llSetTimerEvent( 60 );
            avKey = id;
        }
        else if( number == HUG_RESET ) 
        {
            Reset();
        }
        else if( number > HUG_ANIM ) 
        {
            llStartAnimation( message );
            llSleep( number - HUG_ANIM );
            llStopAnimation( message );
            Reset();
        }
    }

    run_time_permissions(integer parm) 
    {
        if( parm == PERMISSION_TRIGGER_ANIMATION ) 
        {
            // The target has said yes to being hugged so start it off
            llMessageLinked( LINK_SET, HUG_START, " " , NULL_KEY );
        }
        else 
        {
            // They said no
            llMessageLinked( LINK_SET, HUG_DECLINED, " " , NULL_KEY );
        }
    }

    timer() 
    {
        // No responce so act as if they said no
        llMessageLinked( LINK_SET, HUG_DECLINED, " " , NULL_KEY );
        Reset();
    }
    
    on_rez( integer startcode ) 
    {
        Reset();
    }
    
    attach( key k ) 
    {
        Reset();            
    }
    
}

string GetName(key id) 
{ 
    // Get a name from a key 
    string name = llKey2Name( id ); 
    // Reduces it to just their first name 
    name = llList2String( llParseString2List( name, [ " " ], [] ), 0 ); 
    return name;
} 

    state_entry() 
    { 
        ownerKey = llGetOwner(); 
        ownerName = GetName(ownerKey); 
         
        if ( llGetAttached() ) 
            llRequestPermissions(ownerKey,PERMISSION_TRIGGER_ANIMATION); 
        usageMessage(); 
        llMessageLinked( LINK_SET, HUG_RESET, "", NULL_KEY ); 
		llListen(Channel,"",ownerKey,"");
    } 

string GetName(key id) 
{ 
    // Get a name from a key 
    string name = llKey2Name( id ); 
    // Reduces it to just their first name 
    name = llList2String( llParseString2List( name, [ " " ], [] ), 0 ); 
    return name;
} 

llMessageLinked( LINK_SET, HUG_RESET, "", NULL_KEY ); 

// Multi time Hugger script.
// Newgy-ised version of Freebie Hug script.
// original reference as "Francis was here" - Francis Cheung?

// Constants
integer Channel           = 1;
integer sensorDistance    = 10;
string  HuggerAnimName    = "combmain";
string  HuggeeAnimName    = "combsecondary";
integer animTime          = 30;

// Constants (used by linked messages to control actions)
integer  HUG_REQUEST  = 1;
integer  HUG_START    = 2;
integer  HUG_RESET    = 3;
integer  HUG_DECLINED = 4;
integer  HUG_ANIM     = 100;


// Not Constants
string   ownerName = "";
key      ownerKey = NULL_KEY;
string   avTarget = "";
key      avKey = NULL_KEY;
integer  avFindName = TRUE;
vector avPos;
rotation avRot;

 string GetName(key id)
{
    // Get a name from a key
    string name = llKey2Name( id );
    // Reduces it to just their first name
    name = llList2String( llParseString2List( name, [ " " ], [] ), 0 );
    return name;
} 

usageMessage()
{
    llInstantMessage( llGetOwner(), "Usage: Face your target and Say '/" + (string)Channel + "hug [person's name]'" );
}

MoveCloser()
{
    // Move us towards the target in 3 stages.
    vector  posOffset1 = <0.3, 0, 0>;
    vector  posOffset2 = <0, 0, 0>;
    vector pos = avPos + posOffset1 * avRot;
    llMoveToTarget( pos, .5 );
    llSleep(.6);
    pos = avPos + posOffset2 * avRot;
    llMoveToTarget( pos, .5 );
    llSleep(.6);
    llMoveToTarget( pos, 1 );
    llSleep(1);
    llStopMoveToTarget();
}

SaySomethingNice()
{
    // Switch the objects name to our name
    string origName = llGetObjectName();
    llSetObjectName( ownerName );
    llSay( 0, "/me gives " + avTarget + " a hug." );
    // Switch the objects name back
    llSetObjectName( origName );
}

Animate()
{
    llStartAnimation( HuggerAnimName );
    llSleep( animTime );
    llStopAnimation( HuggerAnimName );
}

default
{
 state_entry()
    {
        ownerKey = llGetOwner();
        ownerName = GetName(ownerKey);
         
        if ( llGetAttached() )
            llRequestPermissions(ownerKey,PERMISSION_TRIGGER_ANIMATION);
        usageMessage();
        llMessageLinked( LINK_SET, HUG_RESET, "", NULL_KEY );
        llListen(Channel,"",ownerKey,"");
    }
    
    on_rez( integer startcode )
    {
        llResetScript();
    }
    
    attach( key id )
    {
        if ( id != NULL_KEY )
            llResetScript();            
    }
    
    run_time_permissions(integer parm)
    {
        if( parm & PERMISSION_TRIGGER_ANIMATION )
        {
            llListen( Channel, "", ownerKey, "" );
        }
    }
    
    sensor(integer total_number)
    {
        if ( avFindName )
        {
            integer i;
            for ( i = 0; i < total_number; i++ )
            {
                // Ignore the owner
                if ( llDetectedKey(i) != ownerKey )
                {
                    // Check the names against the supplied text
                    if ( llSubStringIndex(llToLower(llDetectedName(i)), avTarget) >= 0 )
                    {
                        avKey = llDetectedKey(i);
                        avTarget = GetName(avKey);
                        
                        llInstantMessage( llGetOwner(), "You have offered to hug " + avTarget + "." );
                        llMessageLinked( LINK_SET, HUG_REQUEST, ownerName + " would like give you a hug. Say [Yes] to accept.", avKey );                        
                        return;
                    }
                }
            }
        }
        else
        {
            avPos = llDetectedPos(0);
            avRot = llDetectedRot(0);

            // Move close to the target
            MoveCloser();
            
            // Say a nice message
            SaySomethingNice();
            
            // And then, do the anim - a bit of a hack to pass over time period
            llMessageLinked( LINK_SET, HUG_ANIM + animTime, HuggeeAnimName, NULL_KEY );
            Animate();
        }
    }
    
    no_sensor()
    {
        llInstantMessage( ownerKey, "Sorry but I Couldn't find '" + avTarget + "'" );
        llMessageLinked( LINK_SET, HUG_RESET, "", NULL_KEY );
    }
    
    link_message( integer sender, integer number, string s, key id )
    {
        if ( number == HUG_START )
        {
            // Refind the target incase they moved away
            avFindName = FALSE;
            llSensor( "", avKey, AGENT, sensorDistance, PI );
        }
        else if ( number == HUG_DECLINED )
        {
            llInstantMessage( llGetOwner(), avTarget + " has declined your hug." );
        }
    }

    listen(integer channel,string name,key id,string message)
    {
        // Look for the hug request
        list ldata = llParseString2List(llToLower(message), [ " " ], [ "" ]);
        string command = llList2String(ldata,0);
        if( "hug" == command )
        {
            avFindName = TRUE;
            avTarget = llList2String(ldata,1);
            llSensor( "", NULL_KEY, AGENT, sensorDistance, PI );
        }
    }
} 

// Huggee script.
// Newgy-ised version of Freebie Hug script.
// original reference as "Francis was here" - Francis Cheung?


// Constants (used by linked messages to control actions)
integer  HUG_REQUEST  = 1;
integer  HUG_START    = 2;
integer  HUG_ANIM     = 3;
integer  HUG_RESET    = 4;
integer  HUG_DECLINED = 5;

// Variables
key      avKey = NULL_KEY; // Key of Huggee

Reset()
{
    llSetTimerEvent(0); // Stop any running timers
    avKey = NULL_KEY;   // Nullify current target
}

default
{
    state_entry()
    {
        Reset();
    }

    link_message( integer sender, integer number, string message, key id )
    {
        if( number == HUG_REQUEST )
        {
            // Ask the target if they want to be hugged
            llRequestPermissions( id ,PERMISSION_TRIGGER_ANIMATION );
            llInstantMessage( id, message );
            llSetTimerEvent( 60 );
            avKey = id;
        }
        else if( number == HUG_RESET )
        {
            Reset();
        }
        else if( number > HUG_ANIM )
        {
            llStartAnimation( message );
            llSleep( number - HUG_ANIM );
            llStopAnimation( message );
            Reset();
        }
    }

    run_time_permissions(integer parm)
    {
        if( parm == PERMISSION_TRIGGER_ANIMATION )
        {
            // The target has said yes to being hugged so start it off
            llMessageLinked( LINK_SET, HUG_START, " " , NULL_KEY );
        }
        else
        {
            // They said no
            llMessageLinked( LINK_SET, HUG_DECLINED, " " , NULL_KEY );
        }
    }

    timer()
    {
        // No responce so act as if they said no
        llMessageLinked( LINK_SET, HUG_DECLINED, " " , NULL_KEY );
        Reset();
    }
    
    on_rez( integer startcode )
    {
        Reset();
    }
    
    attach( key k )
    {
        Reset();            
    }
    
}