Library: Random Profile Picture Projector

...first offering to the 'Scripting Library'...

This is a kinda fun & cool toy which would work well in any store, mall or club.

It scans the area and randomly selects an AV. It then projects their profile picture as a 'holographic' image for a set time, before randomly finding someone else.

Latest script version of this product can now be found at: https://wiki.secondlife.com/wiki/Random_AV_Profile_Projector

All credit to Moriash Moreau, Coder Kas for supplying the core code and for providing inspiration on a cold UK Sunday morning...

Version4 & Version5:
Comprehensive enhancements and code optimisations. Avaliable from https://wiki.secondlife.com/wiki/Random_AV_Profile_Projector

For Version 3.x:
See Post #19 of this thread for installation instructions, configuration advice and FAQ.
See Post #29 of this thread for optional enhancements/changes to the basic code given below in Post #1

Version3.3 enhancement:
1) If an AV is selected two times in a row, rather than displaying their profile picture again, display the default texture

Version3.2 enhancement:
1) Revert to displaying DefaultTexture on no_sensor, if not shutting toy down

Version3.1 correction:
1) Handles situation of losing 8:5 format ratio when user sets a Size > 2.50m

Version3 enhancements:
1) Displays image in 8:5 format which seems to suit most profile pictures better
2) Automatically names the prim that the script is in, to avoid 'ShoutOuts' being prefixed with 'Object:'
3) More effcient communications with Owner
4) Product information for Owner
5) Delivers URL to this forum thread

Version2 contains following enhancements:
1) More comments
2) Handling for when selected AV does not have a profile picture
3) Function GiveShoutOut() added in such a way as to allow future easy development for gift-giving etc from 'Contents'
4) Ability to set own default texture for display (key DefaultTexture = UUID)
5) Ability to give a 'shout out' in the name of the person (ShoutOut = TRUE/FALSE)
6) Ability to set what the 'shout out' text will be (string ShoutOutText)
7) Ability to set how long the toy will operate before it switches itself off if no AV's are detected. Also ability to disable auto-off function (integer TotalNoScansAllowed)
Ability to project the default texture when the toy is switched off (ProjectDefaultTexture = TRUE/FALSE)

Enjoy

// ~ RANDOM PROFILE PICTURE PROJECTOR v3.3 by Debbie Trilling ~

// *** This script randomly selects an AV from a crowd & then projects their
// profile picture as a 'holographic' image ***

// idea inspired from http://forums.secondlife.com/showthread.php?t=225460
// and http://forums.secondlife.com/showthread.php?t=56343 and offered freely
// in the same spirit. Free to use as you wish by under proviso
// that the title and this introduction remain in place, and that due credit
// continues to be given to Moriash Moreau, Coder Kas
// and Debbie Trilling.

//TOUCH to switch ON and OFF

//** PARAMETERS THAT YOU CAN CHANGE **

// how often in seconds the sensor fires
float RepeatTime = 35.00;

// sensor range in meters. Maximum 96m but in practice 10 to 30m because of particle draw distance
float Range = 25.00;

// length & width size in meters of the projected image (max 4.00)
float Size = 2.50;

// height above object the centre of projected image will be (theoretical max. 50.0, in practice 2.0 to 10.0))
float Height = 2.50;

// UUID of texture to display when an AV without a profile pic is selected
key DefaultTexture = "7cfd684e-2141-941c-eac8-bd439f0d5a9f";
// if you'd like to have a random choice of a number of different default textures, see
// https://wiki.secondlife.com/wiki/Random_AV_Profile_Projector

// set to 'TRUE' to give a 'ShoutOut' to the AV once they have been selected; 'FALSE' for no 'ShoutOut'
integer ShoutOut = TRUE;

// text to 'ShoutOut' when an AV's profile is projected. Text will be proceeded by their name, eg: "<AV Name>'s face is up in lights!"
string ShoutOutText = "'s face is up in lights!";

// sets the number of consequtives times that the scanner is allowed to operate without having located an AV within range
// eg: if RepeatTime = 60.0 seconds and TotalNoScansAllowed = 30, then the toy will operate for 1800 seconds (60x30, or 30 minutes) without locating
// anyone before it automatically powers down. Set to '0.00' to disable the auto-off function
integer TotalNoScansAllowed = 10;

// sets whether the DefaultTexture will be projected when the toy is switched OFF. 'TRUE' to project; 'FALSE' to have no projection when off
integer ProjectDefaultTexture = TRUE;

// ** DO NOT CHANGE BELOW THIS LINE **
string URL_RESIDENT = "http://world.secondlife.com/resident/";
key texture = "";
integer Power = FALSE;
integer NoSensorCounter = 0;
key AVKey = "";
key ObjectOwner = "";
string OwnerName = "";
string ObjectName = "Profile Projector";
string Author = "Debbie Trilling";
string Supplier = "The Particle Crucible";
string Version = " v3.3";


GiveShoutOut()
{
	// any interaction with selected AV (give Inventory items etc) can safely be done from this function
	// this function will only execute if ShoutOut == TRUE

	//although fondly calling it a 'ShoutOut', it actually makes more sense to keep within the 20m range of llSay
	llSay(0, llKey2Name(AVKey) + ShoutOutText);

}


ProjectTexture()
{
	if (ProjectDefaultTexture)
	{
		texture = DefaultTexture;
		ParticleStart();
	}
	else
	{
		llParticleSystem([]);
	}
}


ParticleStart()
{
	//core code by Moriash Moreau. Adapted to suit by Debbie Trilling
	llParticleSystem([
		PSYS_PART_FLAGS, 0,
		PSYS_SRC_PATTERN, 4,
		PSYS_PART_START_ALPHA, 0.50,
		PSYS_PART_END_ALPHA, 0.50,
		PSYS_PART_START_COLOR, <1.0,1.0,1.0>,
		PSYS_PART_END_COLOR, <1.0,1.0,1.0>,
		PSYS_PART_START_SCALE, <Size * 1.6 ,Size,0.00>,
		PSYS_PART_END_SCALE, <Size * 1.6,Size,0.00>,
		PSYS_PART_MAX_AGE, 1.20,
		PSYS_SRC_MAX_AGE, 0.00,
		PSYS_SRC_ACCEL, <0.0,0.0,0.0>,
		PSYS_SRC_ANGLE_BEGIN, 0.00,
		PSYS_SRC_ANGLE_END, 0.00,
		PSYS_SRC_BURST_PART_COUNT, 8,
		PSYS_SRC_BURST_RADIUS, Height,
		PSYS_SRC_BURST_RATE, 0.10,
		PSYS_SRC_BURST_SPEED_MIN, 0.00,
		PSYS_SRC_BURST_SPEED_MAX, 0.00,
		PSYS_SRC_OMEGA, <0.00,0.00,0.00>,
		PSYS_SRC_TEXTURE, texture]);
}

AnnounceWelcome()
{
	llOwnerSay(
		"\nThank you for your interest in this product created by Debbie Trilling at The Particle Crucible.");
}


ShutDown()
{
	llSensorRemove();
	Power = FALSE;
	ProjectTexture();
}


default
{

	on_rez(integer start_param)
	{
		// reset script on rez
		AnnounceWelcome();
		llResetScript();
	}

	changed( integer change )
	{
		if(change & CHANGED_OWNER )
		{
			// reset script on change of owner
			AnnounceWelcome();
			llResetScript();
		}
	}

	state_entry()
	{
		//initialise system
		llParticleSystem([]);
		ObjectOwner = llGetOwner();
		OwnerName = llKey2Name(ObjectOwner);
		llSetObjectName(ObjectName + Version);
		llSetObjectDesc("Supplied by " + Author + "'s " + Supplier);
		ProjectTexture();
		llOwnerSay("\nTOUCH the " + ObjectName + " to switch it ON and OFF.");
	}

	touch_start(integer total_number)
	{
		if (llDetectedKey(0) == ObjectOwner)
		{
			// operation by Owner Only
			if (Power)
			{
				// touch to OFF
				ShutDown();
				llOwnerSay("\nThe " + ObjectName + " is now switched OFF.");
			}
			else
			{
				// touch to ON
				llSensorRepeat("",NULL_KEY,AGENT,Range,PI,RepeatTime);
				Power = TRUE;
				NoSensorCounter = 0;
				llOwnerSay("\nThe " + ObjectName + " is now switched ON. Please wait...");
			}
		}
		else
		{
			// touched by someone other than Owner
			llInstantMessage(llDetectedKey(0), "\nThank you for your interest in the " + ObjectName + " created by " + Author +
				".\nThe script is available free from http://forums.secondlife.com/showthread.php?t=225692.");
		}
	}


	sensor(integer total_number)
	{
		// select an random number from the total number of AV's scanned & then retrieve their key
		integer SelectAvIndex = (integer)llFrand(total_number);
		AVKey = llDetectedKey(SelectAvIndex);
		// core code by Coder Kas. Adapted to suit by Debbie Trilling
		llHTTPRequest( URL_RESIDENT + (string)llDetectedKey(SelectAvIndex),[HTTP_METHOD,"GET"],"");
	}


	no_sensor()
	{
		// counts the number of times that the scanner doesn't find anyone in range. If TotalNoScansAllowed is set to greater than zero, automatically powers down the toy
		// when the number of no_sensors exceeds TotalNoScansAllowed. However, this functionality is disabled if TotalNoScansAllowed is set to zero.
		NoSensorCounter++;
		if ((NoSensorCounter > TotalNoScansAllowed) && (TotalNoScansAllowed > 0))
		{
			ShutDown();
			llInstantMessage(ObjectOwner, "\nThe " + ObjectName + " has been automatically switched OFF as no Agents have been detected within the set timeframe.");
		}
		else
		{
			texture = DefaultTexture;
			ParticleStart();
		}
	}


	http_response(key req,integer stat, list met, string body)
	{
		// core code by Coder Kas Adapted to suit by Debbie Trilling
		integer s1 = 0;
		integer s2 = 0;
		integer s1l= 0;
		integer s2l= -3;
		s1 = llSubStringIndex(body,"<img alt=\"profile image\" src=\"http://secondlife.com/app/image/");
		s1l = llStringLength("<img alt=\"profile image\" src=\"http://secondlife.com/app/image/");
		s2 = llSubStringIndex(body,"\" class=\"parcelimg\" />");

		if(s1 == -1)
		{
			// selected AV doesn't have a profile picture, so use the default instead
			texture = DefaultTexture;
		}
		else
		{
			// extract the key for the selected AV's profile picture
			key TempTexture = (key)llGetSubString(body,s1+s1l,s2+s2l);
			//check whether this was the texture used last emission
			if (TempTexture == texture)
			{
				// same profile pic as last time. so display default instead
				texture = DefaultTexture;
			}
			else
			{
				// different profile from last time, so display it
				texture = TempTexture; 
				
				// give a 'ShoutOut', if set to do so
				if (ShoutOut)
				{
					GiveShoutOut();
				}
			}
		}
		// refresh the projected image using the new texture
		ParticleStart();
	}

	//default end
}

...is such a pain that php is switched off...

And if you insert a little bit of code to give away a free gift to the owner of the pic if they touch it..... hmmmm.

Not bad ^^

http_response(key req,integer stat, list met, string body)
{
texture = (key)llGetSubString(body,llSubStringIndex(body,"<img alt=\"profile image\" src=\"http://secondlife.com/app/image/"+llStringLength("<img alt=\"profile image\" src=\"http://secondlife.com/app/image/",llSubStringIndex(body,"\" class=\"parcelimg\" />"-3);
ParticleStart();
}
}

http_response(key req,integer stat, list met, string body){
integer s1 = 0;
integer s2 = 0;
integer s1l= 0;
integer s2l= -3;
s1 = llSubStringIndex(body,"<img alt=\"profile image\" src=\"http://secondlife.com/app/image/";
s1l = llStringLength("<img alt=\"profile image\" src=\"http://secondlife.com/app/image/";
s2 = llSubStringIndex(body,"\" class=\"parcelimg\" />";

if(s1 == -1){
//Do something, this user has no photo.
}else{
texture = (key)llGetSubString(body,s1+s1l,s2+s2l);
ParticleStart();
}
}

Haven't heard back any negatives yet but you can paste your code into MSWord and save in compatability mode and upload to give formatting + color coding. Or you can upload a txt file which will have indents but no color codes. Example of your script attached.

thx for the feedback, how to check for an AV without a profile picture & the php tip!

v2 pasted over orginal & also uploaded as a WORD document

If you paste formatted code _into_ php tags here, you can also get the spacing back by hitting the Quote button. Whenever I steal a script from the forums, I just quote the post then copy/paste that into SL..

edit: cool script, Debbie!

Very useful.

AH COOL!!!!! Didn't know that trick.

Meade Rocks!!!!

Double cool!. If you use the qoute trick for php tagged files, it also prevents the dreaded extra space between some letters.

oooooo it does even more. Too important. I started a seperate thread about it here:

/54/2f/226867/1.html

They should allow .lsl extensions so we could load directly into lsleditor.

It doesn't work if your in enhanced mode.

Very cool use of SL search. Any idea how to parse and list someones picks?

http://world.secondlife.com/resident/<avKey>
start by finding the index of "Top Picks", each pick will be insinde of 'li' - '/li' tags, and the title will be inside of a href tags within that

EDIT: I tried shortcutting it using Day Oh's google search trick, but don't know the element search for "in picks"... regardless it only returns partial results so not quite useful

I tried googling Day Oh's google search trick. Sounds interesting care to link me?

I'd guess a post in this forum, /54/d1/227051/1.html#post1786544 .

This all would be a lot more fun if llHTTPRequest could cough up more than 2048 characters somehow.

that why I was playing with it and the advanced search features... oddls are you'll hit the wall around the second pick, maybe sooner =(

having a proxy parse it would work, but it's more effort than I'd care for just to grab someones picks if that's all I was after

Thanks to those who have contacted my in-world about this toy...

As it seems popular, I've made a number of improvements in v3, the most significant being:
1) the profile image now projects in 8:5 format as this seems to suit most profile pictures better
2) the prim containing the script now gets automatically renamed, to avoid 'ShoutOuts' starting with "Object:...."

I've been told that a number of entrepreneurs are now selling this product in their stores. I have no problem with that but remember you saw it here first...and it will always be Open Source and Free on this forum!

v3.1 correction: changes how 8:5 format is calculated so that this ratio is preserved even if user sets 'Size' to a value greater than 2.50m

Thank you for continued kind words regarding this toy, and its good to know that for quite a number it is the first time using LSL, or scripts generally.

I must admit that when I first posted the code I had not anticipated the number of IM's that would be sent to me asking for help getting it to compile & setting it up. As this number is increasing on a daily basis, I've included below some step-by-step instructions, and answer a few FAQ that have cropped up a few times...:

To set up:

1) Click the 'Build' button to rez a default cube.
2) Size, shape and texture as desired.
For v3.x, a 0.25 x 0.25 x 0.25 sphere, textured blank, coloured dark-gray and shininess set to 'High' will work well.
If using version 5+, set 'Shininess' to 'None'; if applying the profile picture as a texture to the prim, avoid using spherical or other rounded shapes. Version 5+ lets you set the texture, full bright, alpha and colour of the prim when it is switched OFF: https://wiki.secondlife.com/wiki/Random_AV_Profile_Projector
3) Click the 'Content' tab
4) Click the 'New Script...' button
5) Right-click the New Script and select 'Open'
6) Select 'Edit | Select All'
7) Select 'Edit | Cut' to leave a blank New Script. Leave this open within SL
Locate Post #1 of this forum thread
9) Look down until you see the line "

"
10) Select all text under "
CODE
" until you see "
". Do not include either of these two php tags in the text that you have selected
11) Press <Ctrl-C> to copy the selected text to the Windows clipboard
12) Return to the blank New Script, and press <Ctrl-V> to paste the code
13) Click 'Save'
14) Close the script.
15) Close the 'Edit' window

To Operate:

1) Touch the object to switch OFF/ON

To customise:

1) For customisation instructions, read the text included at the top of the script, up to the line "// ** DO NOT CHANGE BELOW THIS LINE **"

FAQ:

Q: "It don't work, Why?"
A: It does


Q: "I'm not very good with building or scripts. Will you do it for me?"
A: 'fraid not, no. Ask a friend for help, leave a post on this thread or IM me for my rate card ;)


Q: "I've got it working, but don't know how to customise it. Will you do it for me?"
A: 'fraid not, no. Ask a friend for help, leave a post on this thread or IM me for my rate card ;)


Q: "Can I sell it in my store?"
A: This script is free to use as you wish on condition that the title and introduction remain in place within the script, and that due credit continues to be given to Moriash Moreau, Coder Kas, and Debbie Trilling. Unlike the guy at Ahern who is currently voicing that he invented it, and will sell you the "secret" for $500L!


Q: "It isn't showing a picture of me. Why?"
A: "You do have a picture loaded into your profile, right? OK, open your profile, click the gray-blank space where a profile picture is normally displayed, now browse..."


Q: "Why is it displaying my old profile picture?"
A: There appears to be a number of hours delay before the database is updated and will display a recently changed profile picture. Please try later.


Q: "It doesn't display my profile picture at all, and I have not changed it recently" 
A: On rare occasions, even though a picture is loaded into the profile, and hasn't recently been changed, no UUID is returned from the database. On the two cases that I am aware of, one seemingly "fixed itself" and started displaying the picture a few days later; the second case is only today and so is too early to comment. Please try later.

Q: "Is it possible to have more than one default texture; a texture palette from which one is randomly selected?"
A: Yes, version 4+ provides this functionality. See https://wiki.secondlife.com/wiki/Random_AV_Profile_Projector

Q: "Is it possible to apply the profile picture as a texture onto a prim?"
A: Yes, version 5+ provides this functionality. See https://wiki.secondlife.com/wiki/Random_AV_Profile_Projector 

Q: "Do you have other products?"
A. Yes.

Q: "Are they free too?"
A. No

Q: "Do you do custom work? commissions? commercial work?"
A Yes, Yes and Yes. Feel free to IM me in-world to discuss.

Q: "What are you doing tonight, darling?"
A: Duh

Enjoy! :)

LOL, that's a classic

Thanks for this script Debbie, it has been a real hit at my club, but a frequent question I get is "Where did you get my picture”?, and even a couple of complaints to my landlady that I’m suspected of having access to user accounts

In both cases I give them a copy of the script, and an offer to add them to an exclude list if they feel it violates their privacy. So far they are happy with the explanation, so the exclude list is still empty, but food for thought on version 4.0 perhaps

Hi Very, thanks for saying.



I too have had a small number of similar queries.

Although an exclude list would be relatively straightforward to add, perhaps a better solution is to suggest to the complainer that they un-check the 'Show in search' option on the '2nd Life' tab of their profile. Note, however, that it may take a few hours for the database to be updated, and in the meantime the toy will continue to display their picture should they be randomly selected.

Factually, the toy is only displaying the picture that they themselves have already chosen to be public, simply by virtue of the fact that all anyone need do to see that same picture is view their profile. It kinda makes "privacy violation" arguments a little weak, imo, but I understand that that doesn't easily wash with some people some of the time.

For more info of the source of the data, see this thread:
/54/bf/225460/1.html

v3.2 enhancement: When no one is detected within range, and the toy is not set to shutdown, project the default texture rather than continuing to display the last randomly selected profile picture.

Thanks Debbie, I added that too and forgot to mention it, I also set it so that if the same person is selected twice in a row it displays the default instead, that way each image is up for 60sec at a time. Another enhancement is to select from a list of default textures that in my case have event announcements and specials on them. Sort of a combination Profile / advertising board. And rather than further complaints I now have people coming to the club just to watch it I have handed out quite a few free copies with full perms and credits as per your initial request. I will give them a copy of your FAQ too so I don't inadvertantly add to your IM load.

update a prim within an object with a new owner's profile pic? I wanted to see if it is possible to pop a profile picture automatically into the 'avatar online' indicators I have in rental stores. As new players often battle with understanding where to drag and drop (ctrl) onto an object, with the usual fun and games when dropped into the wrong prim , this method used by you, Debbie, here makes sense to me to try as it automates the process somewhat. So I was thinking of using llSetTexture against one face of a prim after llGetOwner to first find the owner's key. However several preschool scripts later, and I still cannot get this to work. Any suggestions

DOH - gotta read the wiki more often
Found HarleenGretzky's excellent post (http://www.lslwiki.net/lslwiki/wakka.php?wakka=LibraryDisplayProfilePic) and realize that except for some small changes, it will possibly work for me

Quickly popped V3 into a prim yesterday and placed it beside a pathway on one of my sims and have had LOTS of questions and ooh's and aah's Very well done with some seriously creative code!

Very Keynes - Is it possible to add your changes to this thread? I was hoping to attempt a similar section in Debbie's script to avoid the 'annoyance factor' and not have the same avatar grabbed twice in a row. If you don't mind I would rather use your version and save me some time