Microphone

Hey at all..
after hours of searching i try it here...
i need a microphone script with a chat range of 200 - 300 meters...
i hope your can help me...
thx Blacky

You mean using something like this...

http://wiki.secondlife.com/wiki/LlRegionSay

...or do you need to be able to broadcast announcements across sim boundaries as long as the avatars are within 300m?

no i open friday my club...
and it is a realy hughe club
so i need mics for my hosts
but the most mics are no mod....
and when they are mod they are no copy and no trans...
so ineed a script for a microphone to made my owns where i can give my hosts

It's easy enough to have a microphone pick up what you say and transmit it to some strategically-placed amplifiers, which then repeat it, either using llSay() or llShout().

I guess the tricky bit is going to be arranging the amplifiers for optimum coverage so everyone can hear but not too many people get spammed with the same message from multiple amplifiers.

What exactly do you want the microphones to do? Just re-broadcast what the host says? If so, llRegionSay would work.

so my hosts should get everyone a mic
the mic should shout over a chanel *like /4 your text* than in the chat: clubhost: the text from the host...
and that should be go over a range from 200 - 300 meters because the club is realy huge..
i have buyed a microphone system for setting up the hostes there over a not card but i cant mod the script and text from the hosts can you not read in the complete club
that is it what i want

there is a products wanted forum try there

i whant no product i need a script ^^

products wanted is where you ask for scripts if you can't make them yourself.

Um, scripts are products too you know. =p What we're telling you is that it looks like you're going to have to pay for this, as no one knows of an existing free script that does what you want. Really though, this isn't the place to ask for free stuff either.

This is the place for programmers of any level of experience to come and ask questions of their peers. If you aren't looking to write it yourself then you aren't one of our peers... =p

[Edit: In retrospect, I don't want to encourage people to post here who are hoping someone will search free script libraries for them or asking to buy programming time. So I've changed the message to reflect that.]

Yes a script is a product of ones labour spent creating code, if your asking us to make a free script outright for you that seems rather...

You know, I am as disgusted as the next guy (or gal) with people coming here asking for free scripts, but seeing as I'd love to help this person develop their microphone, and seeing as it would be more work explaining how to do it than writing such simple little scripts, here you go. I hope that the OP takes advantage of these by not only using them but also studying thier construction for use in future projects. Really people.

Anyway, this is a very simple system. No rich features or anything. The "speaker" (person talking) stands close to the mic (within 3m) and talks on channel 3 (e.g. "/3 Here is what I want to say.". The repeaters (or call them "acoustical speakers" to differentiate them from the person doing the speaking) must be placed--as mentioned above--around the area where you want messages to be heard. Keep in mind that they cover a circular area (20m in radius for normal say, 100m in radius for shout) and try to keep them from SPAMMING the neighbors or reaching the same listener from multiple sources as much as you can.

Put this in the microphone:

//// User Configuration

// The person using the mic talks on this channel
integer SPEAKER_CHANNEL = 3;

// ...and must be this close to the mic (to try to
// avoid other use of scripts broadcasting commands
// all over the club).
float MAX_SPEAKER_DIST = 3.0;


//// Address System Header

// message format: Speaker Name,Message...
integer ADDRESS_SYSTEM_CHANNEL = -1989396517;


//// States

default
{
   state_entry()
   {
      llListen(SPEAKER_CHANNEL, "", NULL_KEY, "");
   }

   listen(integer channel, string name, key id, string message)
   {
      // Check that the speaker isn't an object
      if (llGetAgentSize(id) == ZERO_VECTOR)
      {
         return;
      }
      // ...and that the speaker is close enough
      list details = llGetObjectDetails(id, [ OBJECT_POS ]);
      if (llGetListLength(details) < 1)
      {
         return;
      }
      vector micPos = llGetPos();
      vector speakerPos = llList2Vector(details, 0);
      if (llVecDist(micPos, speakerPos) > MAX_SPEAKER_DIST)
      {
         return;
      }

      llRegionSay(ADDRESS_SYSTEM_CHANNEL, name+","+message);
   }
}

Put this in the repeaters/"acoustical speakers":

//// User Configuration

// Change to TRUE if this repeater really has to cover a whole 100m circle.
// Make sure that isn't going to bleed out into public spaces or other
// businesses or whatever.
integer USE_SHOUT = FALSE;


//// Address System Header

// message format: Speaker Name,Message...
integer ADDRESS_SYSTEM_CHANNEL = -1989396517;


//// States

default
{
   state_entry()
   {
      llListen(ADDRESS_SYSTEM_CHANNEL, "", NULL_KEY, "");
   }

   listen(integer channel, string name, key id, string message)
   {
      // Make sure the mic is owned by the same resident/group as this object,
      // in case there are other public address systems close by.
      if (llGetOwnerKey(id) != llGetOwner())
      {
         return;
      }

      integer commaPos = llSubStringIndex(message, ",");
      if (commaPos < 0)
      {
         // Not formatted like we expect, so must not be from our mic.
         return;
      }

      string speakerName = llDeleteSubString(message, commaPos, -1);
      string spokenText = llDeleteSubString(message, 0, commaPos);

      // Make it look like this is coming from the speaker using the mic
      llSetObjectName(speakerName+" (mic)");

      // Loud and clear for the public.
      if (USE_SHOUT)
      {
         llShout(0, spokenText);
      } else
      {
         llSay(0, spokenText);
      }
   }
}

Enjoy, and I hope reading through them will be educational.

thx for the help and th good thing is i got no neighbors

This is my first time to post here, but I read as much as possible. I am just now starting to study scripts and applying them to different things I want to do. All the instructions are of a great value, at least to me. I am at work now so I cannot go into great detail, but I made a wagon, a sit animation and a script for the sit. I did play around with the sit script and got my animation to work with it just great. My problem now is that I have a follow script, but when used, the wagon flys around behind the ava like a bird . What I hope to do, and I sure it can be, is while one is sitting in the wagon, another can pull, have it follow them, around wherever they might go. What I read on this forum is a major help to me and I just wanted to say Thanks to everyone that shares their knowlege with others. have a great day all.

{Took out the unnecessary quote. And I may not look as dumb as I am}

Just a suggestion ...... (a) start a new thread on your topic instead of adding it to an unrelated thread, (b) include the troublesome portion of the script you have questions about and (c) don't hit the "Quote" button unless you really need to refer to an earlier comment in the thread. Otherwise,.... Hi! Sounds like a nice project.