Library: --~<[[ DemoniX DesignZ Inc. ]]>~-- ANTI-POSEBALL:

//  --~<[[ DemoniX DesignZ Inc. ]]>~-- ANTI-POSEBALL:
//  Created: 12/16/2007
//  Modified: 01/22/2008 to add in descriptions for how to sync pose balls, and added in the
//  Animation Check feature. Also corrected a minor syntex error.
//  Scripted By: Noble Barnes of DemoniX DesignZ
//  So here goes, after reviewing several pose scripts and seeing that not one in particular
//  was actually able to do everything I needed it to do, so I went ahead and created this.
//  this is released under free trade, do with it as you wish, I do however ask that you respect the following terms
//  1.) If you use this code please allow it to be atleast mod/copy/no trans
//  2.) Please leave this header intact.
//  3.) If you use this script and like it, donate 1L$ to Noble Barnes.
//  4.) You can use this script to sell your items, but don't sell this script please.
//  5.) Don't expect any technical assistance with this script.
//  6.) This is released 'as is', it works just fine, read the headings they tell you what to do.
//  7.) Don't IM me asking for help with this script. its FREEWARE for that reason, no support included, I will do a custom version if you need one though.
//
//  Lockmeister AO compatible
//  At time of writing this script is able to override all known Animation Overriders.
//  
//  Avatar Placement position and rotation information:
//   X = +front / behind || Y = +Left / -Right || Z = +above / -below the object
vector      avPosition      =   <0.000,0.000,0.100>;    // CAN NOT BE ZERO_VECTOR ( <0,0,0> )
vector      avRotation      =   <0.000,0.000,0.000>;    // IN DEGREES 0-360
//
//  Avatar Camera placement position and rotation information:
//  X = +front / behind || Y = +Left / -Right || Z = +above / -below the object
//  HELPFUL NOTE: Camera Controls only initiate if script is in root prim, not child prim.
vector      eyeOffset       =   <1.000,0.000,1.000>;
vector      lookat          =   <0.000,0.000,0.100>;
//
//   I have text to display?
integer     TX              =   FALSE;
//  if TX == TRUE use these variables for displaying text.
string      title           =   "ANTI-POSEBALL";
vector      col             =   <1,1,1>;
float       alp             =   1.0;
//
//  Do I hide/show myself when used?
integer     SH              =   FALSE;
//  *   if SH == TRUE use these variables for show/hide options.
integer     face            =   ALL_SIDES;
float       shown           =   1.0;
float       hidden          =   0.0;
//
// Normally I put in the name of the animation I am holding for, if you want the script
//  to use any animation in the inventory change this to ANIMATION = "";
string      ANIMATION       =  "";
//  Do I need to sync anything with another script?
integer     sync            =   FALSE;
//
//  *   if sync == TRUE use these variables for link message communications.
string      syncmessage       =    "send";    // Put a message you want this pose ball to send to a linked poseball here;
string      syncresponce       =    "receive";   // Put a message you want this pose ball to wait to receive from a linked poseball here; 
integer     link            =   LINK_SET;
integer     coms            =   123456;

//this is the function that sends the above mentioned 'syncmessage''= to the poseball defined by integer link above. with the user is of the avatar sitting on me;
function1(key sitter)
{
       llMessageLinked(link,coms,syncmessage,sitter);
}

//this is the function that is performed when the above mentioned 'syncresponce'' message  defined above.  is heard by a linked poseball.
function2()
{
       //put a function in here, commonly I use this area to put in but you can put inanything        
       //you like. Simply uncomment the lines below to do so.
       //stopAnims();
       //ANIMATION = "name of second animation here";
       //llStartAnimation(ANIMATION);
}

//

//***********************************************************************
//  Variables adjusted within script below:
integer     is_sitting;
key         sitter;
//
//
//
//DO NOT MAKE CHANGES TO THE AREA BELOW THIS LINE UNLESS YOU UNDERSTAND INTERMEIDATE TO ADVANCED LEVEL SCRIPTING.
show()
{
    is_sitting  = FALSE;
    if ( TX )   {   llSetText(title, col ,alp);                     }
    if ( SH )   {   llSetAlpha(shown, face);                        }
    if ( sync ) {   llMessageLinked(link,coms,"empty",NULL_KEY);    }
}

hide()
{
    is_sitting = TRUE;
    if ( TX )   {   llSetText("", col ,alp);                        }
    if ( SH )   {   llSetAlpha(hidden, face);                       }
    if ( sync ) {   llMessageLinked(link,coms,"sat_on",NULL_KEY);   }
}

stopAnims()
{
    integer i;
    list anims = llGetAnimationList(llGetPermissionsKey());            
    for ( i = 0 ; i<llGetListLength(anims) ; ++i )
    {
        llStopAnimation(llList2Key(anims, i));
    }    
}


default
{
    state_entry()
    {
        llSitTarget(avPosition, llEuler2Rot(avRotation * DEG_TO_RAD));
        llUnSit(llAvatarOnSitTarget() );
        llSetCameraEyeOffset(eyeOffset);    
        llSetCameraAtOffset(lookat);
        if(sync == FALSE)
        {
            //ADDED THIS TEST CHECK TO VERIFY THERE IS AN ANIMATION PRESENT
            integer test = llGetInventoryNumber(INVENTORY_ANIMATION);
            if(test != 0)
            {
                 ANIMATION = llGetInventoryName(INVENTORY_ANIMATION,0);
                 show();
            }
            else
            {
                 llOwnerSay("Unable to locate any Animation in my Inventory, Please check that an Animation does exist within my Inventory");
            }
        }
    }
    
    changed(integer change)
    {
        if(change & CHANGED_INVENTORY)
        {
            llResetScript();
        }
        
        if(change & CHANGED_LINK)
        {
            key av = llAvatarOnSitTarget();
            
            if(av != NULL_KEY)
            {
                sitter  =   av;
                llRequestPermissions(av,PERMISSION_TRIGGER_ANIMATION);
            }
            
            else
            {
                if((llGetPermissions() & PERMISSION_TRIGGER_ANIMATION) && is_sitting)
                {
                    show();
                    stopAnims();
                    llSay(-8888,(string)sitter+"booton");
                }
            }
        }
    }
    
    run_time_permissions(integer perm)
    {
        if(perm & PERMISSION_TRIGGER_ANIMATION)
        {
            hide();
            function1(llAvatarOnSitTarget());
            llSay(-8888,(string)sitter+"bootoff");
            llSleep(0.250);
            stopAnims();
            llSleep(0.125);
            llStartAnimation(ANIMATION);
        }
    }
    
    link_message(integer link, integer comchan, string sData, key id)
    {
        if(comchan == coms)
        {
                function2();
        }
    }

    on_rez(integer start_param)
    {
        llResetScript();
    }
}