Scaring away Customers

I have another interesting question for you all

A friend of mine is being harassed by a former employer and his friends. They are trying to scare away all her customers.

I was wondering if anyone knew of a function or method that Ejects people from a section of land, or teleports them to somewhere else. I can easily make a list of the people to be ejected. no big there.

Is there a long distance teleport function? that would work, possibly in conjunction with bits and pieces of the elite protection script.

my psuedocode looks something like this:
{
if (bannedUserIsOnLand)//detected
{
llsay(0, $banneduser+"you are not allowed to set foot on this section of land";
//teleport them to welcome center,or force them out
}
}

I might also need a function that identified the land owned by the owner of the script.

These kinds of things always devolve into arms races, and never end well.

You can ban people from land you own, and if someone is violating the TOS, you should abuse-report them.

There are two possible ways of doing this:
llTeleportAgentHome (the scary, griefer way)
and
llEjectFromLand (the more sane alternative.)

Here's example code depicting the use of the latter:

list BANNED_AGENTS = [
"John Doe",
"Jane Doe",
"Jimmy Doe"];

// Time in seconds between each scan.
// Note: Making this number too small (less then 1.0) may induce lag.
float SCAN_INTERVAL = 5.0;

// For readability assistance:
integer LIST_INDEX_NOT_FOUND = -1;

string ownerName = "";
key nameReq = NULL_KEY;

// Set up:
default {
    state_entry() {
        // Request the owner's name.
        nameReq = llRequestAgentData(llGetOwner(), DATA_NAME);
    }
    
    dataserver(key req, string data) {
        if (req == nameReq) {
            ownerName = data;
            state scanning;
        }
    }
}

// Scan for people on the ban list:
state scanning {
    // When the state is entered:
    state_entry() {
        // Detect all agents in range.
        llSensorRepeat("", NULL_KEY, AGENT, 96, TWO_PI, SCAN_INTERVAL);
    }
    
    // When llSensor detects something:
    sensor(integer numDetected) {
        integer i;
        
        // For every agent detected:
        for (i = 0; i < numDetected; i++) {
            // Get the name of the detected agent.
            string dName = llDetectedName(i);
            
            // If the agent's name is in the banned list:
            if (llListFindList(BANNED_AGENTS, [dName]) != LIST_INDEX_NOT_FOUND) {
                // Get the key of the detected agent.
                key dKey = llDetectedKey(i);

                // If the agent is over the owner's land:
                if (llOverMyLand(dKey)) {
                    llInstantMessage(dKey, "You are not allowed on " + ownerName 
                        + "'s land. Prepare to be ejected.");
                    llUnSit(dKey);
                    llEjectFromLand(dKey);
                }
            }
        }
    }
    
    // When the object is rezzed:
    on_rez(integer foo) {
        // Owner might have changed
        // Set up again
        state default;
    }
}

==Chris

EDIT: Corrected syntax error.
EDIT2: Added llUnSit call and increased interval to 5.0 seconds.

Note that while Chris' code looks to be exactly what you asked for, it's probably not what you want. If someone's stalking or harrassing you, you need to report it.

Scanning 96.0 meters every 1.0 seconds *wlll* induce lag in a sim. You might want to set the default in that script to like 10 seconds or so.

You also want to unsit an avatar before ejecting them as ejecting them won't work if they are sitting down.

Can you elaborate, Hank? My experience with scanners is that they're very fast and efficient. Has this behaviour changed somehow?

Scripts should be sandboxed sufficiently so that any single script should not be able lag the sim in any measurable way.

my experience with listens is that they effect fps by percentage; and while a single one won't do much 50 will do alot. I expect sensors to be the same way.

The best way to handle the problem is to simply use the Report Abuse feature. It's there for times like that when someone does such an act.

The Lindens have it in their power to investigate and take whatever actions are nessecary to keep us all happy, and if that means some resident gets a boot out the door then so be it.

But then I respect other residents and if I'm asked to leave their land then it is their wish and I respect that.

Thank you for all your help

The person affected has talked with the other parties involved, and it looks like things are going to work out fine. Still they might not.

I Havent had a chance to implement the script posted by Christopher Omega(I was basking in nature), and i may not have a need for it. I might make a similar script available to others.

There are some other functions in there that I'll definitely find useful. for example, I was wondering how the area scan thing works, and whether it would cause much lag.

I've learned a few other ways to keep ill-intentioned people at bay. Hopefully I wont have to go to any real extreme measures. Its unfortunate some people are not as respectful as others. We are all here to have fun and I dont want to get someone booted permanently over a teensy dispute when there are measures I can take to keep them from spoiling my good time, or harassing my friends.

Thanks again ,
-Enkil