Looking for a pose preview script!

float  demo_length = 10.0; // adjust length of demo period here 

key    demo_target = NULL_KEY; 

play_pose( string Pose ) { 
     
    if( !( llGetPermissions() & PERMISSION_TRIGGER_ANIMATION ) ) { 
      
        llInstantMessage( demo_target, "Failed to obtain permission to animate your avatar. Please touch me again to retry." ); 
        return; 
    } 

    list current_animations = llGetAnimationList( demo_target ); 
    integer i; 
    for( i = 0; i < llGetListLength(current_animations); ++i ) llStopAnimation( llList2Key( current_animations, i ) ); 

    llStartAnimation( Pose ); 
} 

default { 

    on_rez( integer Parameter ) { llResetScript(); } 
     
    touch_start( integer ContactsTotal ) { 
     
        if( demo_target != NULL_KEY ) { llInstantMessage( llDetectedKey(0), "Am currently busy serving another customer, please try me again in few seconds..." );    return; } 
         
        demo_target = llDetectedKey(0); 
        llSetTimerEvent( 15.0 ); // 15 sec. grace period to grant permissions 
        llRequestPermissions( demo_target, PERMISSION_TRIGGER_ANIMATION ); 
    } 
     
    run_time_permissions( integer Permissions ) { 
    
        if( demo_target == NULL_KEY ) { return; }
         
        if( Permissions & PERMISSION_TRIGGER_ANIMATION ) { 

            llSetTimerEvent( demo_length ); 
            play_pose( llGetInventoryName( INVENTORY_ANIMATION, 0 ) ); 
        } 
        else { 

            llSetTimerEvent( 0.0 ); 
            demo_target = NULL_KEY; } 
    } 
     
    timer() { 

        llSetTimerEvent( 0.0 ); 
        if( llGetPermissions() & PERMISSION_TRIGGER_ANIMATION ) { play_pose( "stand" ); } 
        demo_target = NULL_KEY;         
    } 
} 

vector Angle = <0,-90,0>; //Enter a vector rotation for the sit...
vector SitLoc = <-1.3,0,-0.5>; //This is the sitTarget positioning... CANNOT EQUAL 0
string LoadText = "Sit"; // The text you want to show when the object loads...
string Context = "Sit"; //The text you want in the context menu...

//Globals!! WOOO!!
key user;
list animations;
integer animNum;
integer nextAnim = 0;


string currentAnimation;
string nextAnimation;

//This part dynamically gathers all of the animations you've placed in the object for usage later...
initialize()
{
integer x;
list oldAnim;
animNum = llGetInventoryNumber(INVENTORY_ANIMATION);
for (x = 0; x < animNum; x++)
{
string str = llGetInventoryName(INVENTORY_ANIMATION, x);
animations = oldAnim + [str];
oldAnim = animations;
}
}

ShowAnimation()
{
llSetText(nextAnimation,<1.0,1.0,1.0>, 1.0);
}

GetNextAnimation()
{
// Wrap Around the list of available animations
if (animNum > 1)
{
if (nextAnim < (animNum - 1))
{
nextAnim++;
}
else
{
nextAnim = 0;
}
nextAnimation = llList2String(animations,nextAnim);
}
}

ChangeAnimation()
{
llStopAnimation(currentAnimation);
llStartAnimation(nextAnimation);
currentAnimation = nextAnimation;
}


default
{
state_entry()
{
initialize();

//For easy rotation in the llSitTarger enter the vector rotation below..
vector eul = Angle; //45 degrees around the z-axis, in Euler form..
eul *= DEG_TO_RAD; //convert to radians...
rotation quat = llEuler2Rot( eul ); //convert to quaternion...
//Adjust the positioning of the user while siting...
//also need for llAvatarOnSit...
//if this value is equal to 0, it doesn't work, so set it to make it look right for your object
llSitTarget(SitLoc, quat);

// Initialise Main Variables
user = NULL_KEY;
currentAnimation = "sit";
nextAnimation = llList2String(animations,nextAnim);


llSay(0, LoadText); // The text you want to show when the object loads... (WHY?)
llSetSitText(Context); // Text it says under the context menu...
ShowAnimation(); // Display the name of the animation to play
}

touch_start(integer num_detected)
{
// We have been touched so cycle to the next animation
GetNextAnimation();

// Update target (SHOULDN'T BE REQUIRED BUT...)
user = llAvatarOnSitTarget();

// If some one is sat on us
if(user)
{
// Change the animation to the newly selected one
ChangeAnimation();
}
else
{
// Just update the text
ShowAnimation();
}
}
changed(integer change)
{
//If the user sits on the object...
if (change & CHANGED_LINK)
{
user = llAvatarOnSitTarget();
if (user)
{
llRequestPermissions(user, PERMISSION_TRIGGER_ANIMATION);
}
else
{
// Stop the Current Animation
llStopAnimation(currentAnimation);
ShowAnimation(); // Update the text
currentAnimation = "sit"; // reset to sit
}
}
else if(change & CHANGED_INVENTORY)
{
llResetScript();
}
}

run_time_permissions(integer perm)
{
if(perm & PERMISSION_TRIGGER_ANIMATION)
{
// Clear Any Text
llSetText("",<1.0,1.0,1.0>, 1.0);
//This starts the first animation...
ChangeAnimation();
}
}

on_rez(integer num)
{
llResetScript();
}
}
CODE