moving a child prim on its own axis

Sorry if this has been covered before but I couldn't find it.

I want to make child prims that move on their own axis (in this case y axis), and not that of the sim or the parent. i.e 5 objects all with their y axis aligned with the radii of a sphere (the parent), will all move in and out from the centre of the sphere, whatever the spheres orientation. I am using llSetPos to move.

I am befuddled by the rotation thingy bit

p.s. i have tried this suggestion-- llSetPos(( llGetPos() + <0,1,0> ) / llGetRot());

any other ideas please.

float x=distance_to_move;
...
llSetPos( x*llRot2Left( llGetLocalRot()));
or
llSetPos( x*llRot2Left( llGetRot()));
I am not sure about the GetRot.
Anyway it should work in a child prim

Thanks - using llGetRot moves it on the region co-ordinates and using llGetLocalRot does something slightly unpredictable but the linked prim is not yet moving on its own y axis.

Using llGetLocalPos() and llGetLocalRot() instead of llGetPos() and llGetRot() should work. Oh, but you want to MULTIPLY by the rotation, not divide by it. A rotation transforms from a vector in the local coordinate frame (e.g. <0,1,0> to one in the (more) global one (in this case from the prim's coordinates to the root prim's).

llSetPos(( llGetLocalPos() + <0,0,.1> ) * llGetLocalRot());

only seems to work if the parent and child prim are rotated in the same direction. If either is turned then the child does not follow its own axis - its hard to see exactly what it does follow!

Also the distance it moves seems pretty random.

Yay Rotations are fun!! Not..

Disreguard... Totally wrong thread.. Sorry

Good luck though= )

You obviously did not make the effort to test it, but I have now:

// Studio Dora: move child on child's axis script, Dora Gustafson d.2008

float X = 1.0;
vector locpos;

default
{
    state_entry()
    {
        locpos = llGetLocalPos();
        llSetPos( locpos + X*llRot2Left( llGetLocalRot()));
    }

    touch_start(integer total_number)
    {
        state back;
    }
}

state back
{
    state_entry()
    {
        llSetPos(locpos);
    }

    touch_start(integer total_number)
    {
        state default;
    }
}

This script works like a charm when the Y axis is placed on a sphere radius.
Only change to my first suggestion is an added offset obtained with llGetLocalPos();
(the script is placed in the child prim of course)

since you are moving child prims, it may be worth noting there is a bug (and fix) associated with rotating child prims, info at https://jira.secondlife.com/browse/SVC-93 (I updated LSL Portal with issue notes for those as well)

Thank you so much everyone.

To be fair Dora, I tested it for hours but didn't know about the offset which has made all the difference.

My little creatures now go and in and out like anything!!