Rezzing Object From Attachment 1 meter infront of me?

I'm trying to rezz an object from an attachment directly infront of me, but using llGetLocalPos, it gives a strange coodinate, it's not the one where I am, it's much smaller?

When you use llRezObject, you need to use region coordinates so it will rez in the right place. The problem with using llGetLocalPos is that is gives the position with the attachment point as the origin, so it will always be something rather small. You need to call llGetPos(), which will return the region coordinates. Be careful because calling llGetPos() in an attachment will return the position of the avatar, not the actual object.

it's either the offset from the attach point, or the offset from the root (can't remember it's on the LSL portal if you look)

IIRC llGetRootPosition is what you want, and dont forget to rotate based on the av;s rotation (getting the av's position should work too)

As the wiki says: llGetLocalPos gives the position of the attached prim relative to the root (the avatar).

What you're looking for is llGetRootPosition.

When I'm trying to rez stuff in front of me from an attachment, I find

llGetPos()+ < 1.0,0.0,0.0 > *llGetRot()

works fine, assuming it's the attachment's root prim from which I'm rezzing.

According to the wiki, llGetPos() "When called from the root of an attachment, returns the wearer's position. When called in any child prim, always returns that prim's region position" and llGetRot(), when called from the attachment's root, returns the "global rotation of avatar."

Or are you trying to rez it in front of the attachment point itself rather than the avatar?

I'm trying to rezz, infront of the avatar, regardless of where there looking.

The code I posted, then, should do it.

 llRezAtRoot("object", llGetPos()+ < 1.0,0.0,0.0 > *llGetRot(), ZERO_VECTOR, llGetRot(), 0); 

should make the object rez one meter in front of the avatar, if called from the root prim of an attachment the avatar's wearing, no matter where on the avatar the rezzing prim is attached. With the caveat, as I recall, that the avatar isn't in mouselook at the time (in which case it's 1 meter in the direction the avatar's looking -- that's how guns know where to shoot).

Is there a way to get whitch direction the Av is looking in?

I use:
llRot2Fwd(llGetRot()) for the direction vector. That automatically rezzes 1.0m in front. You can use llRot2Left() or llRot2Up() for positions along the Y or Z axis. If you want to rez 1m behind, multiply by -1.0. If you want to rez 5m, multiply by 5.0.

Take a look at this thread from a couple of days ago...

I don't think that's what Nyx is asking, guys. DoteDote's code (which does the same as mine only expressed differently) will rez the object relative to the way the avatar is facing.

I mentioned that it works differently if you're in mouselook, because then -- as I understand it -- llGetRot() doesn't return where you're facing but where you're looking, which is why if you're firing a gun, you can aim by moving your mouse around rather than swiveling your whole avatar round.

If I've properly understood it, Nyx is now asking how you'd rez something in the direction your camera's pointing, as opposed to in front of you, if you're not in mouselook.

This seems do that -- rez an object from an attachment 1 meter from the avatar in the direction at which the camera is pointed:

string my_object;

default
{
		state_entry()
		{
			my_object = llGetInventoryName(INVENTORY_OBJECT,0);
			if(llGetAttached()!=0){
				llRequestPermissions(llGetOwner(),PERMISSION_TRACK_CAMERA);
			}
		}

		touch_start(integer total_number)
		{
			
		vector CameraPoint=llGetCameraPos()+1.0*llRot2Fwd(llGetCameraRot()); // 1 meter in front of my camera, wherever that is
		vector myPos=llGetPos();
		rotation rot = llRotBetween( < 1.0, 0.0, 0.0 >, llVecNorm( CameraPoint-myPos ));// angle between the two
		vector targetPos = llGetPos()+< 1.0,0.0,0.0 > *rot; //one meter from me at that angle.
		if(llGetPermissions()&PERMISSION_TRACK_CAMERA){
			llRezAtRoot(my_object, targetPos,ZERO_VECTOR,llGetRot(),0);
			}
		}

	attach(key id){
		llResetScript();
	}
		
		
}

Innula Zenovka

Thanks very much for the code.

llGetPos()+ < 1.0,0.0,0.0 > *llGetRot()

works perfect, but why does it work? when incrementing X by one, surely X wont always be foward in llGetPos?

(trying to understand, thanks)

That's the way vector algebra works. The product < A > * < B > describes the angular displacement between them; that is, how much you have to turn to get from wherever B points to wherever A points. In this case, since A only has a non-zero component in the forward direction, what you're asking is "How much do I have to turn from llGetRot() to 'forward'?" The magnitude of the resultant vector is the displacement in that final direction. So, writing

llGetPos() + <1.0,0.0,0.0> * llGetRot()

means "Get my current position, turn me from llGetRot() to 'forward' and apply an offset of 1m in the resultant direction."

What Rollig said...

I find the easiest way to think about this is just to remember that multiplying by llGetRot() is, in effect, telling the script to use the local ruler mode in edit. The wiki article, http://wiki.secondlife.com/wiki/Rotation is very clear and accessible for non-mathematicians like me, and I find Void Singer's cheat sheet at http://wiki.secondlife.com/wiki/User:Void_Singer/Rotations absolutely invaluable.

ETA You might also find this thread answers a lot of questions about rotations: /54/31/313876/1.html