I need a special vending machine... will pay

Hi all,

Very new to game. I have purchased several vending machines and they all do the same thiing Sell my item as many times as ppl but it.

What I need is this:

I sell very uniuque items. Only 1 unigue item to be sold onlny once and it cannot be sold again.

Can anyone help me, point me to one for sale, or is there any really good scriptors out here for hire if this isnt available yet?

Thanks all

JJ Collingwood

I don't think there's one specifically for this, but I could make you one fairly quickly and easily. PM me sometime, or IM me in world.

Are these high prim items or really large? If not, then you could just place the item itself out, enter the for sale price in the properties and check that you are selling the original. When the person buys it, the owner name changes to theirs and they can pick up the item and take it away.

I would do it in the manner that Alan suggests--simply sell the one item once. Even if they are high prim, you can put them in a box and sell the "original" of the box. You have no need for a vendor if you are selling a 1-time unique item.

I dont think so but Im really new. Its really a notcard in a box
But there are many and there individual and serialized so I want them all in a machine


THanks

JJ Collingwood

But I have many of htem , 30 or so that need ot be avaialbe so I would like them in an vendor

thanks

JJ

I understand. Hope you can find someone who can modify an existing vendor or write a new one for you.

Extra comments:

I don't think that notecards cannot be sold as originals, since if they can be read, they can be copied. But regardless of how you end up selling them, putting them in a box marked as an original might fulfill your intent of selling an original item.

The University of SL sells/used to sell scripts and notecards in little boxes that were arranged on shelves in sections and in order. Now these were copyable, so the boxes never disappeared, but I would think that with a sign explaining what you sell and small enough boxes, you could make a 50 prim vendor space at a mall work for you easily.

Whatever you decide to do, it is cool to see new folks jump right in and start making stuff. Good luck!

Here's a simple "sell once" vendor script that may do the trick for you JJ.

1) Set the item name and price at the top of the script.
2) Set the item to next owner no copy (and prob no mod too)
3) You must, as owner, have full copy/mod/transfer perms for the item.
4) Drop the item into the inventory of whatever box has this script
5) After the sale the script and item will be removed from the vending box

Have fun!
/esc

// Set this to the name of the product you wish to "sell once"
string PRODUCT_NAME = "My Product";
// Set this to the price in L$ at which you would like to sell
integer PRICE = 10;

// DON'T EDIT BELOW THIS LINE UNLESS YOU KNOW WHAT YOU ARE DOING!

default {
    state_entry() {
    	llSetText("", <1, 1, 1>, 1);
    	if (llGetInventoryKey(PRODUCT_NAME) != NULL_KEY) {
            llRequestPermissions(llGetOwner(), PERMISSION_DEBIT); 
    	} else {
	        llSetText("Waiting for inventory item:\n\"" + PRODUCT_NAME + "\"", <1, 1, 1>, 1);
    	}
    }

    run_time_permissions(integer perm) { 
        if (perm & PERMISSION_DEBIT) { 
            state sell;  
        } else { 
            llOwnerSay("You must grant debit permissions in order to continue.");
            llOwnerSay("This is to allow for customer refunds.");
            llRequestPermissions(llGetOwner(), PERMISSION_DEBIT); 
        }
    }
    
    changed(integer change) {
    	if (change & CHANGED_INVENTORY) {
    		llResetScript();
    	}
    }
}

state sell {
    state_entry() {
    	llSetText("For Sale - " + PRODUCT_NAME + "\nPay me L$" + PRICE + " to purchase", <1, 1, 0>, 1);
    }	
    
    money(key agent, integer amount) {
        if (amount >= PRICE) {
            llInstantMessage(agent, "Thank you for your purchase!");
            if (amount > PRICE) {
                llGiveMoney(agent, amount - PRICE);
                llInstantMessage(agent, "You have been given L$" + (string)(amount - PRICE) + " in change.");
            }
            llGiveInventory(agent, PRODUCT_NAME);
            llInstantMessage(llGetOwner(), llKey2Name(agent) + " purchased " + PRODUCT_NAME + " in " + llGetRegionName());
            state sold;
        } else {
            llInstantMessage(agent, "I'm afraid L$" + (string)amount + " is not enough to purchase this item. Your money has been refunded.");
            llGiveMoney(agent, amount);
        }
    } 
        
    on_rez(integer start_param) {
        llResetScript();
    }
}

state sold {
    state_entry() {
    	llSetText(PRODUCT_NAME + "\nThis item has been sold", <1, 0, 0>, 1);
    	llRemoveInventory(PRODUCT_NAME);
    	llRemoveInventory(llGetScriptName());
    }	
}