Thoughts on best way to accomplish this....

Say you have a single six sided prim. You want to know which face of the prim is facing up (as viewed standing, with up being towards the sky).

Best way to accomplish this?

I had some luck with llGetRot and converting it to a euclid, but the problem there is the euclids come out as -180 to 180, and rotating something around its Z axis only can change it from 90, 0, 0 euclid to 0, 270, 180 for exaample, which ends up with a lot of if thens.

Ummm...

Well, I dont konw about *best*, but a way to do it that will work is to take the dot product of llRot2Fwd(rot), llRot2Left(rot) and llRot2Up(rot) with the z-axis, and see which one has the largest number, then you just have to figure out which this axis is pointing up or down, which you can probably do by just checking the z coordinate of the llRot2xxx function.

Disclaimer: its 2am in the morning, and I havent thought this through, but it probably almost works.

Azelda

should work...

Thanks much, the below works perfectly

report_pos()
{
        rotation rot;
        rot = llGetRot();
        vector vec;
        float leftz;
        float fwdz;
        float upz;
        vec = llRot2Left(rot);
        leftz = vec.z;
        vec = llRot2Fwd(rot);
        fwdz = vec.z;
        vec = llRot2Up(rot);
        upz = vec.z;
        if(upz > 0.9)
            llSay(0, "Six");
        else if(upz < -0.9)
            llSay(0, "One");
        else if(fwdz > 0.9)
            llSay(0, "Two");
        else if(fwdz < -0.9)
            llSay(0, "Five");
        else if(leftz > 0.9)
            llSay(0, "Four");
        else if(leftz < -0.9)
            llSay(0, "Three");
        else
            llSay(0, "MisThrow");
}

not to get way off topic but would it be better to make those global variables so you didn't have to declare them every single time? would that make the script faster? does it make a difference?

in this case no big deal, but normally, i wont make a global variable of something that might not be called for a while.

just depends on what the rest of your script is doing

plus in LSL, 16k mem is more of a concern than speed normally. and if you make them global, they are always using memory, if local then not.

of course monkees could be typing shakespear in Ahem as well, shrug

yes

report_pos()
{
    rotation rot;
    rot = llGetRot();
    vector vec;
    
    vec = llRot2Up(rot);
    if(vec.z > 0.9)
        llSay(0, "Six");
    else if(vec.z < -0.9)
        llSay(0, "One");
    else
    {
        vec = llRot2Fwd(rot);
        if(vec.z > 0.9)
            llSay(0, "Two");
        else if(vec.z < -0.9)
            llSay(0, "Five");
        else
        {
            vec = llRot2Left(rot);
            if(vec.z > 0.9)
                llSay(0, "Four");
            else if(vec.z < -0.9)
                llSay(0, "Three");
            else
                llSay(0, "MisThrow");
        }
    }
}