movement with llMoveToTarget

im making a hud with the ability to have the owner do a /10 # to define a distance they wont to move at, in theroy to me this should work, i put it into a string and it dosent seam to wont to work, this is the script that is in the main prim, the other scripts are just simple touch_start / linked message commands i cant seam to figure out what is wrong it is geting to main script just isnt recording the distace that the owner defines >.>

string d = "";
integer targetID;

default
{
    state_entry()
    {
        llListen(10,"",llGetOwner(),"");
        llOwnerSay("...Reset");
    }
    listen( integer channel, string name, key id, string message )
    {
        if (message == "reset")
        {
            llOwnerSay("Resetting HUD...");
            llStopMoveToTarget();
            llResetScript();
        } 
        else
        {
            message == d;
            llOwnerSay("Distance set to "+d);
        }
    }
    link_message(integer sender_num, integer num, string msg, key id) 
    {
        if(msg == "left")
        {
            llOwnerSay("LEFT");
            vector destination = llGetPos() + <(integer)d, 0, 0>*llGetRot();
            float range = 0.1;
            targetID = llTarget( destination, range );
            llMoveToTarget( destination, .2 );
        }
        if(msg == "right")
        {
            llOwnerSay("RIGHT");
            vector destination = llGetPos() + <-(integer)d, 0, 0>*llGetRot();
            float range = 0.1;
            targetID = llTarget( destination, range );
            llMoveToTarget( destination, .2 );
        }
        if(msg == "up")
        {
            llOwnerSay("UP");
            vector destination = llGetPos() + <0, 0, (integer)d>*llGetRot();
            float range = 0.1;
            targetID = llTarget( destination, range );
            llMoveToTarget( destination, .2 );
        }
        if(msg == "down")
        {
            llOwnerSay("DOWN");
            vector destination = llGetPos() + <0, 0,-(integer)d>*llGetRot();
            float range = 0.1;
            targetID = llTarget( destination, range );
            llMoveToTarget( destination, .2 );
        }
        if(msg == "fwd")
        {
            llOwnerSay("FWD");
            vector destination = llGetPos() + <0,(integer)d,0>*llGetRot();
            float range = 0.1;
            targetID = llTarget( destination, range );
            llMoveToTarget( destination, .2 );
        }
        if(msg == "back")
        {
            llOwnerSay("BACK");
            vector destination = llGetPos() + <0,-(integer)d,0>*llGetRot();
            float range = 0.1;
            targetID = llTarget( destination, range );
            llMoveToTarget( destination, .2 );
        }
    }
    at_target( integer number, vector targetpos, vector ourpos )
    {
        llTargetRemove(targetID);
        llStopMoveToTarget();
    }
}

else
{
message == d;
llOwnerSay("Distance set to "+d);
}


This is wrong. message == d; will test to see if message and d are equal, and retrn an unused value of TRUE or FALSE. YOu problably ment

d = message;

which will set d to the same value that message has.

/me points at Lee and nods..

You can also simplify that script a bit, Mrc. Maybe something like this...

float d;
integer targetID;

DoMove (vector dir)
{
	vector destination = llGetPos() + dir * llGetRot();
	float range = 0.1;
	targetID = llTarget( destination, range );
	llMoveToTarget( destination, .2 );
}

default
{
    state_entry()
    {
        llListen(10,"",llGetOwner(),"");
        llOwnerSay("...Reset");
    }
    
    listen( integer channel, string name, key id, string message )
    {
        if (message == "reset")
        {
            llOwnerSay("Resetting HUD...");
            llStopMoveToTarget();
            llResetScript();
        } 
        else
        {
            d = (float)message;
            llOwnerSay("Distance set to " + (string)d);
        }
    }
    
    link_message(integer sender_num, integer num, string msg, key id) 
    {
        llOwnerSay(msg);

        if (msg == "left")
        {
            DoMove (<d, 0.0, 0.0>);
        }
        else if (msg == "right")
        {
            DoMove (<-d, 0.0, 0.0>);
        }
        else if (msg == "up")
        {
			DoMove (<0.0, 0.0, d>);
        }
        else if (msg == "down")
        {
            DoMove (<0.0, 0.0, -d>);
        }
        else if (msg == "fwd")
        {
            DoMove (<0.0, d, 0.0>);
        }
        else if(msg == "back")
        {
            DoMove (<0.0, -d, 0.0>);
        }
        else
        {
			llOwnerSay ("Bogus message!");
        }
    }

    at_target( integer number, vector targetpos, vector ourpos )
    {
        llTargetRemove(targetID);
        llStopMoveToTarget();
    }
}

This is posted more for doubtful scripting humour value than anything else, but you can reduce it even further...

Domove(<
(float)((msg == "left" - (msg == "right"),
(float)((msg == "fwd" - (msg == "back"),
(float)((msg == "up" - (msg == "down")
> * d);

/me throws a humbug at Ordinal.

If and when we have an obfuscated code contest for LSL, this gets my first nomination.



- Ace

It's not obfuscated code, it's data-driven programming, and probably as elegant as LSL script will ever get. Conditional logic is a vice, not a virtue.

Very kind of you to say so! I actually use that method in the control event for my Mechanical Dragonfly Wings, though since that uses bitfields it is - visually speaking - even uglier.

looks scarily like something I did recently, multplying elements of a vector by a negated boolean to get conditional additive inverses for certain rotations, in a control event you could have more fun, choosing whether or not to normalize for multiple directional inputs

o.o was that english?

Its sentences like that that make me wonder if I'm ever going to be a competent scriptor XD

If you are passing this object to others, there is one thing that stands out to me - a common problem with "listen" scripts, they establish a listen to their owner when the script is reset, but do not reset when they change owners... You can cure this by adding a changed() event handler (resetting the script again is the simplest way to do it but there are other ways):

changed(integer change)
{
if (change & CHANGED_OWNER)
llResetScript();
}

This will clear all the variables and establish the script as listening to the new owner.

sorry, my lova of abusing math at work, the code is actually much simpler than it sounds

I had a user defined vector that had a one for each axis your wanted to rotate on, multiplied by a boolean value (true false) which was negated (*-1), then each element(xyz) was multipled by the objects vector rotation (also xyz) to eliminate rotations I didn't want.

roughly...
userVector = <1, 1, 0>;
someBoolean = TRUE;
objectRot = llGetRot();

userVector *= someBoolean - 1;
objectRot.x += objectRot.x * userVector.x; //repeat for y and z

it was entirely too complex in it's original form (which this is only part of), and got trashed as being inelegant and hard for users... ordinal's solution above IS elegant though, and in a control event for a vehicle could benefit from the addition of lllVecNorm() if applied directly to thrust (to keep it from turning faster than it moves in a single direction)