Enhanced Jump & Fly in No-Fly Examples?

I'll admit, I'm lookin' for a sort of 'freebie' here...searched through the library to no avail. I'm looking for example scripts of Enhanced-Jump scripts or Fly-in-No-Fly scripts that I can take apart and apply to a scripting project of my own. I'm sure I can figure it on my own...but if anyone can point me to a working example it'd be great...

Don't really have a working example handy, but in general I'll say any kind of normal scripted avatar movement or flight-assist type functionality should work as long as it is made to turn on using some logic other than llGetAgentInfo() & AGENT_FLYING.

OTOH, you can just enable "View Admin Options" in the "Advanced" menu (CTRL-ALT-D if you don't see it) to fly in no-fly areas, so no script is even really necessary if you'd rather not, "play by the rules."

Hewee...I'm not trying to circumvent rules, but to create a script that allows limited persons the ability to fly in a no-fly zone.

Additionally, the jump-enhancer need is completely separate...so it's both a jump enhancer and a fly-in-no-fly...working it out slowly...testing things here and there...but any prior knowledge would help me immensely as it's not an area of scripting I delve into often.

Here's what I would probably start a jump enhancement with. You'll have to add your own logic if you want to turn it off while it is being worn. You'll also probably want to play around with different SPEED_BOOST values.

(This hasn't been compiled or tested. It may need minor syntactical corrections.)

float SPEED_BOOST = 10.0;  // in m/s
float TIMER_PERIOD = 0.1;

integer alreadyBoosted;

// Returns whether permissions have been aquired
integer havePermissions()
{
    return (llGetPermissions() & PERMISSION_TAKE_CONTROLS) &&
           llGetPermissionsKey() == llGetOwner();
}

// Returns whether permissions have been aquired
integer acquirePermissions()
{
    if (havePermissions())
    {
        return TRUE;
    }

    llRequestPermissions(llGetOwner(), PERMISSION_TAKE_CONTROLS);
    return FALSE;
}

default
{
    state_entry()
    {
        if (llGetAttached())
        {
            if (acquirePermissions())
            {
                state active;
            }
        }
    }

    attach(key wearer)
    {
        if (wearer != NULL_KEY)
        {
            if (acquirePermissions())
            {
                state active;
            }
        }
    }

    run_time_permissions(integer perms)
    {
        if (havePermissions())
        {
            state active;
        }
    }
}

state active
{
    state_entry()
    {
        alreadyBoosted = FALSE;
        llTakeControls(
            CONTROL_UP |
                CONTROL_FWD | CONTROL_BACK | CONTROL_LEFT | CONTROL_RIGHT,
            TRUE, TRUE);
    }

    state_exit()
    {
        llSetTimerEvent(0.0);
        llReleaseControls();
    }

    attach(key wearer)
    {
        if (wearer == NULL_KEY || !havePermissions())
        {
            state default;
        }
    }

    changed(integer changes)
    {
        if (changes & CHANGED_OWNER)
        {
            state default;
        }
    }

    timer()
    {
        if (!(llGetAgentInfo(llGetOwner()) & AGENT_IN_AIR))
        {
            alreadyBoosted = FALSE;
            llSetTimerEvent(0.0);
        }
    }

    control(key id, integer held, integer changed)
    {
        if (!(held & changed & CONTROL_UP))
        {
            return;
        }
        if ((llGetAgentInfo(id) & AGENT_IN_AIR) && alreadyBoosted)
        {
            return;
        }

        integer heldFwd = held & CONTROL_FWD;
        integer heldBack = held & CONTROL_BACK;
        integer heldLeft = held & CONTROL_LEFT;
        integer heldRight = held & CONTROL_RIGHT;

        float fwdBoost = 0.0;
        if (heldFwd)
        {
            if (!heldBack)
            {
               fwdBoost = 1.0;
            }
        } else if (heldBack)
        {
            fwdBoost = -1.0;
        }

        float leftBoost = 0.0;
        if (heldLeft)
        {
            if (!heldRight)
            {
                leftBoost = 1.0;
            }
        } else if (heldRight)
        {
            leftBoost = -1.0;
        }

        vector localImpulse =
            llGetMass()*SPEED_BOOST*llVecNorm(<fwdBoost, leftBoost, 1.0>);
        llApplyImpulse(localImpulse, TRUE);

        alreadyBoosted = TRUE;
        llSetTimerEvent(TIMER_PERIOD);
    }
}

A script really isn't needed to fly in a no-fly zone. Just enable "View Admin Options" and you'll be able to fly as you normally would.

Thanks for the starter script there Hewee! That'll definitely get me going on the right track. I'll try to post the finished here for mutual benefit.

Winter...the goal isn't to get SL to allow flight...but rather to allow persons who have selected one option over another to fly within the no-fly region...

...say, for instance...an avatar can choose:
a)swim
b)run
c)fly

...if they chose C, then I'd like to 'turn on' flying for them. The only way to do so is to make it inherent in the script. (by the way, the other options aren't really swim or run...just an example...one of them, however, is enhanced-jump...which was my need for that scripting.)

The only important part in a script to make it fly in a no-fly zone is adding llTakeControls. Before someone asks, it isn't a bug, it's more of a "loophole". There had to be a way for vehicles to get out of no-fly zones, instead of being stuck in mid-air and the owners and passengers having to get out and "take" the vehicle back. That would have been a major pain................

Err...are you confusing no-fly with no-script? All no-fly zones do is keep you from putting your avatar in fly mode (except for the View Admin Options workaround). It has NO effect on scripted movement whatsoever. You don't even need llTakeControls() if you'd like an attachment to, say, pull you around by the ear in a way that's not under your direct control.

Yep that is exactly what I did.