searching dance script who can be activated by one person...

hello !
I know I've already senn the script I'searching for, but after looking everywhere, I can't find it anymore !!!
I'm searching the script for a pole dance, that can only be used by one person, I decide who...
so I want create juste a pole with a dance script inside and that could be activate just by one person...
if someone has one, or can tell me where I can find it, it would be nice...
thank you...
marylou lane

Your talking about a standard animation script that just has a specific name or key encoded into it to configure it for just that person. Something like this would work:-

// Locked Animation Player v1.0 - Newgate Ludd 
// ------------------------------------ 
// Written in responce to a posting on the Forums by Marylou Lane 
// 
string animation_name = "Slow Lap Dance";   // Name of animation 
string name = "Marylou Lane";               // Name of avatar allowed to use this item.
string sitText = "Dance!";                  // Sit Text
key avatar;                                 // Key of the avatar who's sitting on me 
vector offset = <0,0,1>;                    // Sit Target

// -------------------------- 
default 
{ 
    state_entry() 
    { 
        llSetSitText(sitText);
        llSitTarget(offset,<0,0,00,90>);
        llSay(0,llGetScriptName() + " Ready - configured for  " + name);
    } 
       
    on_rez(integer num) { llResetScript(); } 
      
    changed(integer change) 
    { 
         // The object's sit target has been triggered 
        if (change & CHANGED_LINK) // Test for a changed link 
        { 
            avatar = llAvatarOnSitTarget(); 
            
            if(avatar != NULL_KEY) // Is that changed link an avatar? 
            { 
                string avname = llKey2Name(avatar);
                if(avname != name)
                {
                    llWhisper(0,"Sorry but only " + name + " is allowed to use me.");
                    llUnSit(avatar);
                }
                else
                {
                     llRequestPermissions(avatar,PERMISSION_TRIGGER_ANIMATION); 
                     llStopAnimation("sit"); 
                     llStartAnimation(animation_name); 
                 }
            } 
            else 
            { 
                if (llGetPermissionsKey() != NULL_KEY) 
                { 
                    llStopAnimation(animation_name); 
                } 
            } 
        } 
    } 
       
    run_time_permissions(integer perm) 
    { 
        if (perm & PERMISSION_TRIGGER_ANIMATION) 
        { 
             llStopAnimation("sit"); 
             llStartAnimation(animation_name); 
        } 
    } 

} 

Obviously for greater flexiability a notecard could be used to allow configuration.

thank you very much for having an interest for my demand, I will try this script tomorrow and will say to you if it works.
thank you very much...
marylou