Library: AGENT Visualizer

Simple tool to help visualise the AGENT's size and location. Useful when working with animations, sit offsets, and vehicles.

// AGENT Visualizer - By: Winter Ventura
// Permission is granted to fold, spindle, mutilate, slice, dice, and julianne.
// Use them together, Use them in peace.

init()
{
    llSetObjectName(llKey2Name(llGetOwner()) + "'s Agent Stand-in");
    llSetPrimitiveParams([
        PRIM_COLOR, ALL_SIDES, <0,0,0>, .25,
        PRIM_PHANTOM, TRUE,
        PRIM_TYPE, PRIM_TYPE_SPHERE, 0, <0.0, 1.0, 0.0>, 0.0, <0.0, 0.0, 0.0>, <0.0, 1.0, 0.0>,
        PRIM_TEXTURE, ALL_SIDES, "769681c6-9064-ab0f-e416-6a4eecc59e6a", <1,1,0>, <0,0,0>, 0.00,
        25, ALL_SIDES, 0.05 // PRIM_GLOW
    ]);
    llSensorRepeat("", llGetOwner(), AGENT, 96, PI, 0.1);
}

default
{
    state_entry()
    {
        init();
    }
    
    on_rez(integer start_param)
    {
        init();
    }
    
    changed (integer change)
    {
        if (change & CHANGED_OWNER) init();
    }

    sensor(integer num_detected)
    {
        llSetPrimitiveParams([
            PRIM_POSITION, llDetectedPos(0),
            PRIM_ROTATION, llDetectedRot(0),
            PRIM_SIZE, llGetAgentSize(llGetOwner())
            ]);
    }
}