Gonna be lazy Need help with a script

// Configurable Settings
float Range = 10; // 10 meters
float Rate = 5; // in seconds
integer SpellChannel = 3;
list SpellNames = [ "Ice","Fire","Wind","Water"];
string Spell;

// Detected list variables
list detected_list;
list detected_names;

// Dialog Handler
integer Listening;
integer ListenChannel;

 key owner = NULL_KEY;
 
// Functions
UpdateListen(key id)
{
    CancelListen();
    Listening = llListen(ListenChannel,"",id,"");
    llSetTimerEvent(30);
}

CancelListen()
{
    if(Listening > 0) llListenRemove(Listening);
    Listening = 0;
    llSetTimerEvent(0);
}

// Owner Conversation Dialog
ChooseTarget(key id)
{
    
    string text = "Cast " + Spell + " at ? ";
    ListenChannel = (integer)llFrand(2147483646) +  1;
    list AVList;
    // Simple version  - put AV names directly on Buttons
    integer len = llGetListLength(detected_list);
    if(len == 0)
    {
        text += "\n\nNO ONE HERE BUT US CHICKENS!";
    }
    else
    {
        if(len > 12)len = 12;
        AVList = llList2List(detected_names,0,len - 1);
    }
    
    llDialog(id,text,AVList,ListenChannel);
    UpdateListen(id);
}



// Select Spell Dialog
StartConversation(key id)
{
    
    string text = "Which Spell ?";
    ListenChannel = (integer)llFrand(2147483646) +  1;
     llDialog(id,text,SpellNames,ListenChannel);
    UpdateListen(id);
}


default
{
    state_entry()
    {
        owner = llGetOwner();
        llSensorRepeat("", "", AGENT, Range , PI, Rate);
    }

   on_rez(integer num) { llResetScript(); }

    changed(integer change) 
    { 
        // Test for a changed inventory 
        if (change & CHANGED_OWNER) 
        { 
            llResetScript(); 
        } 
           
    } 

   
    no_sensor()
    {
        detected_list = [];
        detected_names = [];
    }
    
    sensor( integer number_detected )
    {
        integer i;
        string name;
        detected_list = [];
        detected_names = [];
        for( i = 0; i < number_detected; i++ )
        {
            key id = llDetectedKey( i ) ;
            if(id  != owner )
            {
                // Limit name to 24 Characters
                name = llGetSubString(llDetectedName( i ), 0 ,  24);;
                
                detected_list  += id;
                detected_names += name;
            }
        }
    }

    timer()
    {
          CancelListen();
    }
    
    touch_start(integer total_number)
    {
        // Owner 
        key id = llDetectedKey(0);
        if( (id == owner))
        {
            StartConversation(id);
        }
    }
 
    listen( integer channel, string name, key id, string message )
    {
        integer index = llListFindList(detected_names, [ message ] );
        if(index >= 0)
        {
            llSay(SpellChannel,Spell + " " + message);
        }
        else
        {
            index =  llListFindList(SpellNames, [ message ] );
            if(index >= 0)
            {
                Spell = message;
                ChooseTarget(id);
            }
        }
    }
}