TP scripts / system that can go to more than 768 M?

Does anyone yet have any TP scripts / systems that can go to more than 768 M? With the new Dazzle-based 1.20 Release Candidate it is possible to build normally at up to 4096 M. But when I tried placing a Telepro II Teleport pad on a platform at 1024 M, it said it registered with the server down below, but it didn't generate a menu option for that stop?

Has anyone successfully tested or scripted a TP to over 768M yet?

Considering that the ability to build properly up to 4km was just added yesterday (That I know of), I'd give it a few days before someone comes up with a good, stable method of doing it. If someone has already, then awesome, but I just think it'll take a little bit.

Just a guess, but I'm thinking that the 'sit position' method would work, but it still has its own limit unfortunately(What was it, 200m-300m?)

Hi Ceera. I was messing around with my teleport script late last night, and a warppos from 20m to 1024 worked just fine. There's a little more complexity in getting up to 4096 to keep the script from blowing its stack, not rocket science. I imagine you'll see upgrades to commercial systems soon.

That said, for personal use I'm having to do a little experimentation even at lower elevations with warppos. I'm not sure what I'm seeing but it looks like different Havok4 collision boxes sometimes causing weird push behavior on landing, maybe just on megaprims surfaces (no cuts in the megas). Anyone else have insight on that?
.

I did one successful experiment for getting up into 'the new frontier'. *grins*

A sit elevator works just fine. I tried the one designed by Seagel Neville, which is documented in the Scripting foruns. It uses a displacement factor from your starting point, and had no problem reaching test platforms at 1024 M and at 3000 M. I used the 1.20 RC client to place the platforms and the elevator pads. It did take a while to ride from the roof of my skybox at 735 M to the platform at 3000 M, but it worked!

An added bonus: As long as I lock the platforms that are above the normal 768 M build limit, one can also safely use that sit elevator, once positioned, to travel up to and down from the higher platforms, even with the 1.19 client!

If I did not lock the platform, then just as in older releases, any attempt to move prims that have somehow been left at a height above 768 M causes those prims to snap down to 768 M. I would imagine this would apply to the elevator pad as well, though that can't be locked.

Smiles, use the "Paskis Zip Teleport Script" makes you TP everywhere without to think about the range of teleporting. Simply add a Landmark and its done. Free to copy .-)

You just need to tweak warpPos a little bit.
Drop it in a prim and sit on it to see.
Just adjust the relevant parts of your script as needed:

vector destpos = <66, 60, 4096>;	// The location the av will be teleported to.

warpPos(vector destpos)
{
	//with a little pokeing by Strife, and a bit more
	//munging by Talarus Luan
	//Final cleanup by Keknehv Psaltery
	//and of course Jesse Barnett got to jump in here
	//and made it work up to 4096 meters
	//Fail safe removed
	// Compute the number of jumps necessary
	integer jumps = (integer) (llVecDist(destpos, llGetPos()) / 10.0) + 1;
	if (jumps > 100)
		jumps = 100;	//  1km should be plenty
	list rules =[PRIM_POSITION, destpos];
	integer count = 1;
	while ((count = count << 1) < jumps)
		rules = (rules =[]) + rules + rules;
	llSetPrimitiveParams(rules + llList2List(rules, (count - jumps) << 1, count));
}

default {
	state_entry() {
		llSetText("Touch to teleport", <1, 1, 1 >, 1);
		llSitTarget(<0, 0, 0 >, ZERO_ROTATION);
	}

	changed(integer change) {
		if (change & CHANGED_LINK) {
			integer jumps = (integer) (llVecDist(destpos, llGetPos()) / 10.0) + 1;
			if (jumps > 100) {
				integer hops = jumps / 100;
				while (hops > 0) {
					hops--;
					warpPos(destpos);
				}
				warpPos(destpos);
				llSleep(0.5);
				llDie();
			}
		}
	}
}

You can always use llMapDestination.. LL built in solution, only real TP method less lag, grid wide, etc. I don't know why ppl doesn't dig it.

With the extra dialog and button press plus the ongoing teleport failures even within the same region, it's really a hard feature to love. On the plus side, the bug where totally wrong coordinates get plugged into the map seems to have been squashed.

It also kinda stinks when a teleport destination has been defined for the target land.

Argent Stonecutter has a very nice, easy to use system that can go from any point to any point in a sim, up to 4096m. It's called the NetPorter, and I can highly recommend it.

I've had a bit of a play with the above script and made it unsit the avatar and return to it's original location, much like other teleporters.

vector destpos = <2, 179, 4095>; // The location the av will be teleported to.
vector startpos;
warpPos(vector destpos)
{
    //with a little pokeing by Strife, and a bit more
    //munging by Talarus Luan
    //Final cleanup by Keknehv Psaltery
    //and of course Jesse Barnett got to jump in here
    //and made it work up to 4096 meters
    //and a bit more modding by Adelle Fitzgerald to make the prim return
    //Please note, if you move the prim, reset the script to get new start position
    //Fail safe removed
    // Compute the number of jumps necessary
    integer jumps = (integer) (llVecDist(destpos, llGetPos()) / 10.0) + 1;
    if (jumps > 100)
    jumps = 100; // 1km should be plenty
    list rules =[PRIM_POSITION, destpos];
    integer count = 1;
    while ((count = count << 1) < jumps)
    rules = (rules =[]) + rules + rules;
    llSetPrimitiveParams(rules + llList2List(rules, (count - jumps) << 1, count));
}

go_there()
{
    integer jumps = (integer) (llVecDist(destpos, llGetPos()) / 10.0) + 1;
    if (jumps > 100)
    {
        integer hops = jumps / 100;
        while (hops > 0)
        {
            hops--;
            warpPos(destpos);
        }
        warpPos(destpos);
        llSleep(0.5);
        llUnSit(llAvatarOnSitTarget());
    }
}

go_back()
{
    integer jumps = (integer) (llVecDist(startpos, llGetPos()) / 10.0) + 1;
    if (jumps > 100)
    {
        integer hops = jumps / 100;
        while (hops > 0)
        {
            hops--;
            warpPos(startpos);
        }
        warpPos(startpos);
        llSleep(0.5);
        llResetScript();
    }
    
}


default
{
    state_entry()
    {
        startpos = llGetPos();
        llSitTarget(<0.0, 0.0, 0.1>, ZERO_ROTATION);
        llSetText("Touch to teleport", <1, 1, 1 >, 1);
    }

    changed(integer change)
    {
        if (change & CHANGED_LINK)
        {
            llSleep(0.5);
            if (llAvatarOnSitTarget() != NULL_KEY)
            {
                go_there();
            }
            else
            {
                go_back();
            }
        }
    }
    on_rez( integer param )
    {
        llResetScript();
    }
}

EDIT: If you move the prim you must reset the script to reset its position.