Touch event limiter?

Is there a way I could set a touch event in a script to be available x seconds after it's last touch event? Say like the default script saying "Touched"; is there a way that the object will only say "Touched" after say 10 seconds has passed? I'm working on something that will have a touch even that will cause it to say something, and then do a simple action, but I don't want it to spam the area with the message I've set it to say. (I've heard the term "deviling" used to describe this.)

Sure, you could create a kind of a proxy handler. When it receives a touch event, it would setup a timer for 10 seconds, and any extra touch events would get dropped on the floor. When the timer handler fires, it says the "touched" message and then resets everything.

Because my last message wasn't really helpful, I'll post two scripts which may be helpful to what you are trying to do. I'm not exactly sure which semantics you were exactly looking for, so I'll post two flavors.

The first script makes the touch handler available only every 10 seconds. You can use it immediately when the script starts, but once you press it once, it ignores everything for 10 seconds. Once the 10 seconds are up, it will respond again (just once) and then do the 10 second thing all over again. You can replace the llSay(0, 'Touched." with some more useful function, this is just a skeleton. I tested it out quickly in the sandbox, so it should be mostly correct. Here it is:

integer available = TRUE;
integer TIMER_LENGTH = 10; // in seconds

default
{
state_entry()
{
llSay(0, "Hello, Avatar!";
}

touch_start(integer total_number)
{
if (available)
{
available = FALSE;
llSay(0, "Touched."; // replace with any function
llSetTimerEvent(TIMER_LENGTH);
}
}

timer()
{
llSetTimerEvent(0); // clear timer
available = TRUE;
}
}

To not make the post too lengthy, I'll post the second script in the next message.

Here's the second script. This one *delays* response to a touch event by 10 seconds. That's probably not what you were looking for, but it wasn't clear to me. If a touch event is received, it will count down for 10 seconds and then fire the llSay(0, "Touched." (which can be replaced with any other function). Any extra touch events will be *ignored* during those 10 seconds, i.e. all touch events during the 10 second window count as one touch. Here's the script:

integer timerSet = FALSE;
integer TIMER_LENGTH = 10; // in seconds

default
{
state_entry()
{
llSay(0, "Hello, Avatar!";
}

touch_start(integer total_number)
{
if (!timerSet)
{
llSetTimerEvent(TIMER_LENGTH);
timerSet = TRUE;
}
}
timer()
{
llSetTimerEvent(0);
timerSet = FALSE;
llSay(0, "Touched."; // replace with any function
}
}

Hope these help a little. If not, please feel free to IM me in world and we can try things together! Good luck.

float wait_time;
default
{
    touch_start(integer total_number)
    {
        float time=llGetTime();
        if(time>wait_time)
        {
            llSay(0, "Touched.");
            wait_time=time+10;
        }
            
    }
}

This has the advantage of not using a timer loop and being generally simpler.

That is true! That is a much nicer script.

Alternatively.. (using a timer though )

default
{
    touch_start(integer num)
    {
        llWhisper(0,llDetectedName(0) + " touched me.");
        state wait;
    }
}

state wait
{
    state_entry()
    {
        llSetTimerEvent(10.0);
    }

    timer()
    {
        llSetTimerEvent(0);
        state default;
    }
}

The real difference here is that because you are changing to a state that does not contain a touch event handler, all touches will be completely ignored.. in fact you will not even get the mouse cursor change that shows when an object can be touched.

That's interesting about the mouse cursor change (or lack thereof). I'll definitely remember that one. Thanks for posting!

Gaz is teh winnar!

Try llMinEventDelay()... depending on what you want to do, it might work for you.