set timer event problems

i am having a syntax error and i can not figure out what i am doing wrong with the script.

default
{
state_entry() {
llListen(0,"", NULL_KEY, "";
}

listen(integer channel, string name, key id, string message) {
if (message == "start"
{
llTriggerSound("62e6535d-646f-6098-ff6d-718595ec0cd4", 1.0);
llSetTimerEvent(10);
}

timer()
{
llLoopSound("4ba2839b-9462-69e4-17af-cf8f2432a623", 1);

}

if (message == "stop"
{

llStopSound();
llTriggerSound("69b9805c-a6b8-ece4-7cd6-0c226c20040d", 1.0);

}
}
}

this seems to be messed up completely

make sure you check that every open { has a closing }
for example you must close the bracket before the timer() event but it seems that the timer() event is misplaced because you have a if (message == "stop" after that

I think this is what you wanted to do intentionally:


default
{
state_entry() {
llListen(0,"", NULL_KEY, "";
}

listen(integer channel, string name, key id, string message) {
if (message == "start"
{
llTriggerSound("62e6535d-646f-6098-ff6d-718595ec0cd4", 1.0);
llSetTimerEvent(10);
}

if (message == "stop"
{
llStopSound();
llTriggerSound("69b9805c-a6b8-ece4-7cd6-0c226c20040d", 1.0);
}
}

timer()
{
llLoopSound("4ba2839b-9462-69e4-17af-cf8f2432a623", 1);

}
}

thats very close, the sound loop started again after i used the stop command but way closer than anything i managed thanks

very close, i just need to figure out how to switch it so the loop is played between the start and stop command (with the 10 second delay, with the non looping sounds triggered by the start/stop commands and then blisful silence afterwards

in the stop you want to set the timer to 0 also

be aware, setting the timer to 0 won't clear a timer event already queued, so you might want to use a variable to test it and shortcut the timer code if it's been queued

something like
//-- in the start code
gBooRun = TRUE;

//-- in the stop code
gBooRun = FALSE;
llSetTimerEvent ( gBooRun );

//-- in the timer event
if (gBooRun){
//-- loop sound
}

although really I don't see the need for the timer to keep running at all since it's a looped sound, so setting the timer to 0 IN the timer event is probably more effective, but you may still want to use that check variable because the stop message could come before the first timer event is run... so more like this

integer gBooRun;

default{
  state_entry() {
    llListen(0,"", NULL_KEY, "");
  }

  listen(integer channel, string name, key id, string message) {
    if ("start" == message){
      llTriggerSound( "62e6535d-646f-6098-ff6d-718595ec0cd4", 1.0 );
      gBooRun = TRUE;
      llSetTimerEvent( 10 );
    }else if ("stop" == message){
      llStopSound();
      llTriggerSound( "69b9805c-a6b8-ece4-7cd6-0c226c20040d", 1.0 );
      gBooRun = FALSE;
    }
  }

  timer(){
    if (gBooRun){
      llLoopSound( "4ba2839b-9462-69e4-17af-cf8f2432a623", 1 );
    }
    llSetTimerEvent( 0 );
  }
}

will keep edge cases of the timer firing after the fact by being queued as an event already, AND keep from needlessly retriggering a sound that's already looping on it's own .