Simple Posing Stand

Hi,

I searched the board, but didn't find any information about that. Maybe I was looking for the wrong words, but how do you make a simple posing stand?

I mean the very simple one. That one you stand on when adjusting hair or prim-whatever on your avatar. You get these stands everywhere for free, but with a branding. I'd like to make my own. How is this done?

Thank in advance!
Jue

Its the same basic script as a poseball, when the avatar sits on the prim it will request animation permissions and if granted override the sit with a particular pose.

...That pose typically being "turn_180", the one played when going into Appearance mode.

I'm not quite sure about that. I've got a posing stand (one from Telus). When I stand on it, my avatar goes into the "editing appearance" pose. And that's not all: Above my name you even read "editing appearance". There is no menue opening, so you can work on your prim or hair and adjust it to your avatar.

There must be some kind of LSL-Line (?) that brings your avatar into that "editing"-mode. It's different to the regular poseball stuff...

Any ideas?

When sitting on a poseball the poseball disappears. The posing stand I'm talking of doesn't. You're standing atop...?

The pose ball disappearing or not is completely dependant upon the script telling it to.
The editing apperance tag will appear automatically when the turn_180 pose is activated.
You wont necessarily get a dialog, the permissions are silently granted but still have to be requested by the script.

I think I got the idea. I thought at first place I should use a "custom" animation, but it seems to be possible to use one of the build in animations. One of them is this "turn_180" according to this list:

http://wiki.secondlife.com/wiki/Internal_Animations

Then it's only a "normal" posing stand that makes my avatar go into this position.

Thanks for your help. I will post my script here, as soon as it is finished.

Jue

Here's one I made earlier

key user=NULL_KEY;

default{
    state_entry(){
        llSitTarget(<0,0,1.5>,ZERO_ROTATION);
        llSetSitText("Stand");
    }

    changed(integer change){
        if(change & CHANGED_LINK){
            key av=llAvatarOnSitTarget();
            if(av!=NULL_KEY){
                user=av;
                llRequestPermissions(av,PERMISSION_TRIGGER_ANIMATION);
            }else{
                if(user!=NULL_KEY){
                    llStopAnimation("turn_180");
                    user=NULL_KEY;
                }
            }
                
        }
    }

    run_time_permissions(integer perm){
        if(perm & PERMISSION_TRIGGER_ANIMATION){
            llStopAnimation("sit");
            llStartAnimation("turn_180");
        }
    }
}

The sit target could probably stand a little adjustment depending on your avatars size, I have a tall av and like to be able to adjust my shoes without seeing my feet disappear into the pose stand

GREAT! Thanks a lot! I'll try this later when I'm inworld.

Jue