menu driven notecard giver

integer CHANNEL = -21342;	// dialog channel
list MENU_MAIN =["note 1", "note 2", "note 3"];	// the main menu
key detected;
integer handle;

default {
	touch_start(integer total_number) {
		detected = llDetectedKey(0);
		handle = llListen(CHANNEL, "", detected, "");	// listen for dialog answers (from multiple users)
		llDialog(detected, "What do you want to want", MENU_MAIN, CHANNEL);	// present dialog on click
	}

	listen(integer channel, string name, key id, string message) {
		if (llListFindList(MENU_MAIN,[message]) != -1)	// verify dialog choice
		{
			llSay(0, name + " picked the option '" + message + "'.");	// output the answer
			if (message == "note 1")
				llGiveInventory(detected, "note 1");
			else if (message == "note 2")
				llGiveInventory(detected, "note 2");
			else if (message == "note 3")
				llGiveInventory(detected, "note 3");
		}
		else
			llSay(0, name + " picked invalid option '" + llToLower(message) + "'.");	// not a valid dialog choice
		llListenRemove(handle);
	}
}

integer CHANNEL = -21342;	// dialog channel
list MENU_MAIN =["note 1", "note 2", "note 3"];	// the main menu
key detected;
integer handle;

default {
	touch_start(integer total_number) {
		detected = llDetectedKey(0);
		handle = llListen(CHANNEL, "", detected, "");	// listen for dialog answers (from multiple users)
		llDialog(detected, "What do you want to want", MENU_MAIN, CHANNEL);	// present dialog on click
	}

	listen(integer channel, string name, key id, string message) {
		if (llListFindList(MENU_MAIN,[message]) != -1)	// verify dialog choice
		{
			llSay(0, name + " picked the option '" + message + "'.");	// output the answer
			llGiveInventory(detected, message);
		}
		llListenRemove(handle);
	}
}

//--// v7-D Notecard Giver w/ MultiPage Dialog Support //--//

string cSTR_MESSAGE = "Previous Discussion Notes:\n Choose a button to recieve a copy...";
integer cINT_DIALOG_CHANNEL = -41;
 //-- REQ: this global (store list of buttons in order)
list gLstButtons;

 //-- REQ: this function
list vfParseButtons( integer vIntPage ){
  list    vLstReturn;
  integer vIntLength = llGetListLength( gLstButtons );
  integer vIntStart = llAbs(vIntPage) * 11;

  if (vIntLength - vIntStart > 1){
    if (vIntLength - vIntStart > 12){
      vLstReturn += llList2List( gLstButtons, vIntStart + 9, vIntStart + 10 );
      
      if (vIntPage < 10){
        vLstReturn += ["MORE (0" + (string)(vIntPage + 1) + ")"];
      }
      else{
        vLstReturn += ["MORE (" + (string)(vIntPage + 1) + ")"];
      }
      vLstReturn += llList2List( gLstButtons, vIntStart + 6, vIntStart + 8 );
      vLstReturn += llList2List( gLstButtons, vIntStart + 3, vIntStart + 5 );
      vLstReturn += llList2List( gLstButtons, vIntStart, vIntStart + 2 );
    }
    else{
      integer i = vIntLength - 1;
      for (i; i - 2 >= vIntStart; i -= 3){
        vLstReturn += llList2List( gLstButtons, i -2, i );
      }
      if (i >= vIntStart){
        vLstReturn += llList2List( gLstButtons, vIntStart, i );
      }
    }
  }
  return vLstReturn;
}

default{
  state_entry(){
    llOwnerSay( "Retrieving Note List..." );
    integer i = 0;
    integer vIntNotes = llGetInventoryNumber( INVENTORY_NOTECARD );
    for (i; i < vIntNotes; ++i){
      gLstButtons += [llGetInventoryName( INVENTORY_NOTECARD, i )];
    }
    llOwnerSay( (string)vIntNotes + " Notes Available. Notecard Giver Started" );
    state vsWorking;
  }
}

state vsWorking{
  state_entry(){
  }

  touch_start( integer vIntTouched ){
    llListen( cINT_DIALOG_CHANNEL, "", llDetectedKey( 0 ), "" );
    llSetTimerEvent( 30.0 );
     //-- REQ: origination call
    llDialog( llDetectedKey( 0 ),
              cSTR_MESSAGE,
              vfParseButtons( 0 ),
              cINT_DIALOG_CHANNEL );
  }

  listen( integer vIntChannel, string vStrName, key vKeyID, string vStrMessage ){
     //-- REQ: handle new page calls
    if (llGetSubString( vStrMessage, 0, 5 ) == "MORE ("){
      llSetTimerEvent( 30.0 );
      llDialog( vKeyID,
                cSTR_MESSAGE,
                vfParseButtons( (integer)llGetSubString( vStrMessage, 6, 7 ) ),
                cINT_DIALOG_CHANNEL );
    }
    else{
      llGiveInventory( vKeyID, vStrMessage );
    }
  }

  timer(){
    llSetTimerEvent( 0.0 );
    state vsListenKill;
  }

  changed( integer vBitChanged ){
    if (vBitChanged & (CHANGED_OWNER | CHANGED_INVENTORY)){
      llOwnerSay( "Owner/Inventory Changed, Resetting..." );
      llResetScript();
    }    
  }
}

state vsListenKill{
  state_entry(){
    llOwnerSay( "Die, Listeners, Die!" );
    state vsWorking;
  }
}