Changing audio on deeded land

We have a radio changer that worked fine on group land, using the media change LSL, via a menu system.

Now we've put the land 'deeded to group', it no longer changes, although it goes through the motions with the whisper about changing the stream.

What do I need to change to make it work on group deeded land again?

Broccoli

You also need to deed your media change script/object to the group.

Meni.

It's "set to group" ... how do you deed an object?

Broccoli

right click -> edit; check 'share with group' and click 'deed'

meni.

That works... but now we can't edit or change any of it?

Broccoli

IM me in world and I'll get you a radio you don't need to deed for group land and you can add whatever stations you want if you don't like the 50 or so stations that are already in it.

A Radio that can change the Media-Url on group owned land without beeing deeded to the group? I doubt this is is possible. An Object that changes the stream on group-owned land needs to be deeded to the group - otherwise, it will not work...
This can be achieved though, if you have sort of a 'relay' that sets the stream and gets the information about the stream from the radio...
Needless to say - group owned land is a pain in the a*** ))

Prob is when you deed stuffs to land sometimes the inards want allow you to change them directly, you might have to take out the notecards and such to edit them then put them back in, make sure to delete the old. Also making a simple relay as Haruki Watanabe sated works too, you can use shout, say or even maybe region say to achive this, so you will have an extra prim to the radio. I found that if you are tight on prims there is Buckly's radio script you can use to throw in anything and then you can edit it to relay the url to the grp deeded thingy or you can buy one like StreamRadio it comes with a single prim version with the grp relay in the package but not sure how far it'll work, i think the relay has to be within 10m of the radio but you don't have to grp deed the radio and then you can edit the cards and such in the two mentioned.

i edited the freebie script floating around to work with a relay.

/////radio script

//  -- Bucky's Radio - 2.6.4
//  an update/expansion of an earlier script
//  Bucky.Barkley@gmail.com - August 2006

//       based on...
//=======Land Radio Script =======
//  
//  assembled for this purpose by
//  sky Honey and Dianne Mechanique 
//  based on the work of others
//
//===========9/12/05==============

// which notecard would you like to use?
string  _notecard = "Stations";

integer chatChannel = 77;
string HELP_MSG = "touch for station dialog, or use ch 77 to change stations (example \"/77 3\")";
integer chan = -6969;

list    _radioURLs;
list    _radioStations;
list    theStations;

integer _linenum = 0;
integer curStationOffset = 0;
integer stationChunk = 6;
integer curStationEnd = 5;
integer totalStations = 0;
integer dialogActive = 0;
integer curIdx  = -1;
string dispStationStr = "";

string NEXT_MSG = "Next >>";
string PREV_MSG = "<< Prev";
string LIST_MSG = "List";

string CUR_SET  = "c";
string ALL_SET  = "a";

list cmdNextChunk = [">>", "next", "Next", NEXT_MSG];
list cmdPrevChunk = ["<<", "prev", "Prev", PREV_MSG];
list cmdLsCur     = ["ls", "list", LIST_MSG];
list cmdLsAll     = ["la", "listall"];
list cmdSearch    = ["s", "search"];

string newURL;
string newDesc;
    
//-----------------------

reset_radio() {
    llSetText("starting radio ....", // message to display
              <1,0,0>, // color: <red,green,blue>
              1.0 ); // 1.0 = 100% opaque, 0.0 = transparent
    llListen(77, "", "", "");
    curStationOffset = 0;
    curStationEnd = 5;
    _linenum = 0;
    dialogActive = 0;
    _radioURLs = [];
    _radioStations = [];
    totalStations = 0;
    curIdx = -1;
    dispStationStr = "";
    llGetNotecardLine(_notecard, _linenum);
}

add_station(string line) {
    list words = llParseString2List(line, [" ", " ", "="], []);
    if (llGetListLength(words) < 2) {
        return;
    }
    string url = llList2String(words, llGetListLength(words) - 1);
    string station = "";
    integer i;

    for (i=0; i<llGetListLength(words) - 1; i++) {
        if (llStringLength(station) > 0) {
            station += " ";
        }
        station += llList2String(words, i);
    }
    
    _radioURLs += ;
    _radioStations += [station];
}


curStations() {
    theStations = [PREV_MSG, LIST_MSG, NEXT_MSG];

    integer i;
    dispStationStr = "";

   // llWhisper(0, "offset: " + (string)curStationOffset);
    // llWhisper(0, "end: " + (string)curStationEnd);
                
    for (i = curStationOffset; i <= curStationEnd; i++) {
        if (curIdx == i) {
            dispStationStr += "*";   
        } else {
            dispStationStr += "  ";   
        }
        dispStationStr += (string) (i + 1) + ") ";
        dispStationStr += llList2String(_radioStations, i);
        dispStationStr += "\n";
        
        theStations += (string)(i + 1);
    }
}


doNextSet() {
    curStationOffset += stationChunk;
    curStationEnd = curStationOffset + (stationChunk - 1);
    
    if (curStationOffset >= totalStations) {
        curStationOffset = 0;
        curStationEnd = curStationOffset + (stationChunk - 1);  
    }
    
    if (curStationEnd >= totalStations) {
        curStationEnd = totalStations - 1;   
    }
}


doPrevSet() {
    if (curStationOffset > 1  && ((curStationOffset - stationChunk) < 1)) {
        curStationOffset = 0;
    } else {
        curStationOffset -= stationChunk;
    }

    curStationEnd = curStationOffset + (stationChunk - 1);
    
    if (curStationEnd >= totalStations) {
        curStationEnd = totalStations - 1;   
    }
    
    if (curStationOffset < 0) {
        curStationEnd = totalStations - 1;
        curStationOffset = totalStations - (stationChunk - 1);  
    }
}

doListStations(string mode) {
    integer i;
    integer startPos;
    integer endPos;
    
    if (mode == "a") {
        startPos = 0;
        endPos = totalStations - 1;   
    } else {
        startPos = curStationOffset;
        endPos = curStationEnd;
    }
    
    for (i = startPos; i <= endPos; i++) {
        string newURL = llList2String(_radioURLs, i);
        string newDesc = llList2String(_radioStations, i);
        llSay(0, (string)(i + 1) + ": " + newDesc + " = " + newURL);
    }   
}


doSearch(string theTerm) {
    integer i;
    
    llSay(0, "the term is " + theTerm);
    
    for (i = 0; i < totalStations; i++) {
        string curString = llList2String(_radioStations, i);
        if (llSubStringIndex(curString, theTerm) != -1) {
            string newURL = llList2String(_radioURLs, i);
            llSay(0, (string)(i + 1) + ": " + curString + " = " + newURL); 
        }
    }  
}

//-----------------------

default {
    on_rez(integer start_param) {
        reset_radio();
    }
    
    state_entry() {
        reset_radio();
    }
    
    changed(integer change) {
        if (change & CHANGED_INVENTORY) {
            reset_radio();
        }
    }

    dataserver(key query_id, string data) {
        if (data != EOF) {
            add_station(data);
            _linenum++;
            
            if (_linenum % 5 == 0) {
                  llSetText("starting: \n" + (string)_linenum + " stations ...", // message to display
              <1,0,0>, // color: <red,green,blue>
              1.0 ); // 1.0 = 100% opaque, 0.0 = transparent    
            }
            llGetNotecardLine(_notecard, _linenum);
            return;
        }
        llListen(93, "", NULL_KEY, ""); 
        
        totalStations = llGetListLength(_radioURLs);        
        llSay(0, HELP_MSG);
        dialogActive = 1;
        llSetText("", <1,0,0>, 1.0 );
    }
    
    touch_start(integer touchNumber) {
        curStations();
        
        llDialog(llDetectedKey(0),
            dispStationStr,
            theStations, 93);        
    }

    listen(integer channel, string name, key id, string message) {

        if (dialogActive == 0) {
            llWhisper(0, " ... still loading stations ...");
            return;   
        }
        
        if (message == "") {
            message = "cur";
        }
        
        
        list words = llParseString2List(message, [" ", " ", "="], []);        
        list testFind = llList2List(words, 0, 0);
               
        if (llListFindList(cmdNextChunk, testFind) != -1) {
            doNextSet();
            curStations();
            if (channel == chatChannel) {
                doListStations(CUR_SET);
            } else {
                llDialog(id, dispStationStr,theStations, 93);
            }
            return;  
        }
         
        else if (llListFindList(cmdPrevChunk, testFind) != -1) {
            doPrevSet();
            curStations();
            if (channel == chatChannel) {
                doListStations(CUR_SET);   
            } else {
                llDialog(id, dispStationStr, theStations, 93);
            }
            return;    
        }      
          
        else if (llListFindList(cmdSearch, testFind) != -1) {
            doSearch(message);
            return;    
        }
          
        else if (llListFindList(cmdLsAll, testFind) != -1) {
            doListStations(ALL_SET);
            return;  
        }
        
        
        else if (llListFindList(cmdLsCur, testFind) != -1) {
            doListStations(CUR_SET);
            return; 
        }
        

        else if ((integer)message > 0 && (integer)message < 256) {
            curIdx = (integer)message - 1;
            
            string newURL = llList2String(_radioURLs, curIdx);
            string newDesc = llList2String(_radioStations, curIdx);
           
            llSay(0, "setting station " + message + ":");
            llSay(0, newDesc + " = " + newURL);
            llSetParcelMusicURL(newURL);
            llSay(chan, newURL);
         }
    }
}

////relay script lol, don't laugh

//string newURL;
integer chan = -6969;

default
{
    state_entry()
    {
        llListen(chan, "", NULL_KEY, "");
        llSetAlpha(0.0, ALL_SIDES);
    }
    
    listen(integer chan, string name, key id, string newURL)
    //link_message(integer sender_num, integer num, string str, key id)
    {
        llSetParcelMusicURL(newURL);
    }
}

there you go!!!!
if any one knows a script that can show current song info let me know please

Now why would I offer to give him one if I didn't have one that could do just that? And yes, you are right on with the assumption about a relay of sorts. I sell all my radios with that option in a copyable prim so they can use the radio else where too. Therefore no deeding of the actual radio.

Lol, oops. Yes if the script are all that then you can slap them in anything. It's kind of messed up how you have to actualy have the grp item deeded to the land to change media. Still anyone got a script that can grab station info?

I have one that grabs station info (who it is, what song is playing plus other things) except you have to manually insert the url. I haven't gotten around to have it pick up the url from the radio which should be easy.

thank you ... it's very nice ... ))))

you can steal that part of the hack from the tuner/board at the pavilion, max. did it a year ago.