Funky unpack script

default
{
	on_rez(integer nevermind)
	{
		llSetText("Touch me to unpack\nyour new "+llGetObjectName()+".",<1,1,1>,1.0);
	}
	touch_start(integer total_number)
	{
		if(llDetectedKey(0) == llGetOwner()) {		 
 
		list		inventory;
		string	 name;
		integer	 num = llGetInventoryNumber(INVENTORY_ALL);
		string	 text = llGetObjectName() + " is unpacking...\n";
		integer	 i;
 
		for (i = 0; i < num; ++i) {
			name = llGetInventoryName(INVENTORY_ALL, i);
			if(llGetInventoryPermMask(name, MASK_OWNER) & PERM_TRANSFER)
				inventory += name;
			else
				llOwnerSay("Cannot give asset \""+name+"\", owner lacks copy permission");
			llSetText(text + (string)((integer)(((i + 1.0) / num) * 100))+ "%", <1, 1, 1>, 1.0);
		}
 
		text = llGetObjectName();
 
		//we don't want to give them this script
		i = llListFindList(inventory, [llGetScriptName()]);
		inventory = llDeleteSubList(inventory, i, i);
 
		if (llGetListLength(inventory) < 1) 
 
		{
			llSay(0, "No items to offer.");
		} 
		else
		{
			llGiveInventoryList(llGetOwner(), text, inventory);
			llOwnerSay("Your new "+ text +" can be found in your inventory, in a folder called '"+ text +"'. Drag it onto the ground to rez it!");
			llDie(); //Doesn't unpack all the items, just kills it here. Where should it go?
		}
 
		//llDie(); //It did not work here either
		}
		else
		llWhisper(0, "Only the owner can unpack this bag.");
	}
 
}

    default
    {
    	on_rez(integer nevermind)
    	{
    		llSetText("Touch me to unpack\nyour new "+llGetObjectName()+".",<1,1,1>,1.0);
    	}
    	touch_start(integer total_number)
    	{
    		if(llDetectedKey(0) == llGetOwner()) {		
    	
    			list		inventory;
    			string		 name;
    			integer	 num = llGetInventoryNumber(INVENTORY_ALL);
    			string		 text = llGetObjectName() + " is unpacking...\n";
    			integer	 i;
    			integer 	die = TRUE;
    			
    			for (i = 0; i < num; ++i) {
    				name = llGetInventoryName(INVENTORY_ALL, i);
    				if(llGetInventoryPermMask(name, MASK_NEXT) & PERM_COPY)
    					inventory += name;
    				else
    				{
    					llOwnerSay("Cannot give asset \""+name+"\", owner lacks copy permission");
    					die = FALSE;
    				}
    				llSetText(text + (string)((integer)(((i + 1.0) / num) * 100))+ "%", <1, 1, 1>, 1.0);
    			}
    	
    			text = llGetObjectName();
    	
    			//we don't want to give them this script
    			i = llListFindList(inventory, [llGetScriptName()]);
    			inventory = llDeleteSubList(inventory, i, i);
    	
    			if (inventory != [])
   			{
    				llGiveInventoryList(llGetOwner(), text, inventory);
    				llOwnerSay("Your new "+ text +" can be found in your inventory, in a folder called '"+ text +"'. Drag it onto the ground to rez it!");
    			}
    			if(die)
    				llDie();
    			else
    				llOwnerSay("You will have to finish unpacking the this object manualy. To do so, right click on the object and select \"Open\" then just drag the contents to your inventory.");
    		}
    		else
    			llWhisper(0, "Only the owner can unpack this bag.");
    	}
    }