No Click Teleport ?

I understand sit teleports and the map destination options but I was wondering if an attachment could auto teleport you ?

I did wonder about warpos the Avatar but would need to be phantom to avoid walls wouldn't I ?

I have a feeling this is a 'can't do in LSL' thing.

You can't warppos an av, since an av can't contain scripts. The av would have to sit on a scripted object, which requires a click.

you can do the cheap move to target hack, but warppos wont work in an attachment because it treats the move as relative to the attachment point and doesn't take the av with (bassically failing)

llApplyImpalse and i belive llSetPos not 100% sure can also be used to move around

As Void noted above about warppos (which amounts to repeated llSetPos calls via llSetPrimitiveParams, which are effectively executed all at once), llSetPos in an attachment will move the attachment relative to the av, not the av itself. And while llApplyImpulse could push an av, it would probably be sheer luck hitting a specific location with it.

A combination of llApplyImpulse() and llMoveToTarget() could probably do a pretty good job.

I was afraid you would say that about warpos, I was guess that might be the case.

So pushing the Av is the only choice then ? What about walls, now in my case I may be able avoid them, maybe. I've been thinking this might be the deal, dang it

In my personal multi-hud I use 3 different types of TP; warpPos, a movement TP and then a physics TP.

The physics TP uses llApplyImpulse and llMoveToTarget as Heewee pointed out and should work fine in an attachment instead of in a rezzed object like I use it. The only time I use it though is when I am teleporting to a platform above the normal build range, such as a platform up at 4000 meters or so. It's one weakness is that it will not move you through objects as the other two means of TP. In other words, it will indeed move me up to the platform but the I bump against the bottom until I click sit on the platform. Still here is the code if you want to play with it.

// "Physics TP.esl"

//////////////////////////////////////////////////////////////////////////////////////////////////////
//				Physics TP V1.2
// 				"Feb 11 2008", "11:08:39"
// 				Creator: Jesse Barnett
//				Released into the Public Domain
//////////////////////////////////////////////////////////////////////////////////////////////////////


vector target;

default {
	on_rez(integer start_param) {
		llListen(start_param, "", "", "");
		llSetStatus(STATUS_ROTATE_X | STATUS_ROTATE_Y | STATUS_ROTATE_Z, FALSE);
		llSetText("Touch to ascend", <0, 0, 0 >, 1.0);
	}
	state_entry() {
		llSetObjectName("Physics TP");
	}
	listen(integer channel, string name, key id, string message) {
		target = (vector) message;
	}
	changed(integer change) {
		if (change & CHANGED_LINK) {
			key av = llAvatarOnSitTarget();
			if (av) {
				llSetStatus(STATUS_PHYSICS, TRUE);
				llTarget(target, 50);
			}
			else {
				llDie();
			}
		}
	}
	not_at_target() {
		vector impulse = target - llGetPos();
		llApplyImpulse(llGetMass() * impulse, FALSE);
	}
	at_target(integer ascend, vector target, vector cPos) {
		llTargetRemove(ascend);
		llMoveToTarget(target, 0.5);
		llSetTimerEvent(5.0);
	}
	timer() {
		if (llVecDist(llGetPos(), target) < 0.01) {
			llStopMoveToTarget();
			llApplyImpulse(-llGetMass() * llGetVel(), FALSE);
			llSetStatus(STATUS_PHYSICS, FALSE);
		}
	}
}

It recieves it's target by listening to the channel specified by the start parameter.

Am using moveto.

In my situation I 'think' I can get away with avoiding walls

There was a coder who is selling something interesting on SLExchange.

Her method involves you donning a bracelet (or popping the script from the bracelet into some prim object you often wear), and then walking into a door or portal. The collision teleports you.

The scripts are mod so you can work with them.

Sadly, I can't get her name cause the box that I was storing this in for future examination -- well, by accident I kinda dropped an llDie() script into it :{ so it all got teleported off into the Great Beyond...

Thats exactly what I'm planning to do, I was just hoping there would be a better way

better way than having to wear something with a script in it -- is what I am guessing you are meaning?

Yep, exactly

SLURLs, perhaps?