UpdateSitTarget() issues?

//Sets / Updates the sit target moving the avatar on it if necessary.
UpdateSitTarget(vector pos, rotation rot)
{//Using this while the object is moving may give unpredictable results.
    llSitTarget(pos, rot);//Set the sit target
    key user = llAvatarOnSitTarget();
    if(user)//true if there is a user seated on the sittarget, if so update their position
    {
        vector size = llGetAgentSize(user);
        if(size)//This tests to make sure the user really exists.
        {
            //We need to make the position and rotation local to the current prim
            rotation localrot = ZERO_ROTATION;
            vector localpos = ZERO_VECTOR;
            if(llGetLinkNumber() > 1)//only need the local rot if it's not the root.
            {
                localrot = llGetLocalRot();
                localpos = llGetLocalPos();
            }
            pos.z += 0.4;
            integer linkNum = llGetNumberOfPrims();
            do{
                if(user == llGetLinkKey( linkNum ))//just checking to make sure the index is valid.
                {
                    llSetLinkPrimitiveParams(linkNum,
                                            [PRIM_POSITION, ((pos - (llRot2Up(rot) * size.z * 0.02638)) * localrot) + localpos,
                                             PRIM_ROTATION, rot * localrot / llGetRootRotation()]);
                    jump end;//cheaper but a tad slower then return
                }
            }while( --linkNum );
        }
        else
        {//It is rare that the sit target will bork but it does happen, this can help to fix it.
            llUnSit(user);
        }
    }
    @end;
}//Written by Strife Onizuka, size adjustment provided by Escort DeFarge

list GetSitTarget(integer prim, key av)
{//WARNING: llGetObjectDetails can introduce an error that goes as far as the 5th decimal place!
 //This is highly unlikely to be ever noticed unless compounded over time.
 //Do not use while moving (like in a moving vehicle)!!!
    vector tp = llGetAgentSize(av);
    if(tp)
    {
        if(prim == LINK_THIS)//llGetLinkKey doesn't like LINK_THIS
            prim = llGetLinkNumber();
 
        list details = [OBJECT_POS, OBJECT_ROT];
        rotation f = llList2Rot(details = (llGetObjectDetails(llGetLinkKey(prim), details) + llGetObjectDetails(av, details)), 1);
        rotation r = llList2Rot(details, 3) / f;
 
        return [((llList2Vector(details, 2) - llList2Vector(details, 0)) / f) + (llRot2Up(r) * tp.z * 0.02638) - <0.0, 0.0, 0.4>, r];
    }
    return [];
}//Written by Strife Onizuka

rotation randomRot()
{//ported from QGLViewer
  float seed = llFrand(1.0);
  float r1 = llSqrt(1.0 - seed);
  float r2 = llSqrt(seed);
  float t1 = llFrand(TWO_PI);
  float t2 = llFrand(TWO_PI);
  return <llSin(t1)*r1, llCos(t1)*r1, llSin(t2)*r2, llCos(t2)*r2>;
}

go()
{
	key user = llAvatarOnSitTarget();
	if(user)
	{
		rotation r = randomRot();
		vector p = <llFrand(5), 0, 0> * randomRot();
		llSetRot(randomRot());
		UpdateSitTarget(p, r);
		llSleep(0.1);
		llOwnerSay("Target: " + llList2CSV([p,r]) + "\nActual: " + llList2CSV(GetSitTarget(LINK_THIS, user)));
	}
}

default
{
	changed(integer change)
	{
		if(change & CHANGED_LINK)
		{
			go();
		}
	}
	touch_start(integer a)
	{
		go();
	}
}