cant get script to reset on a timer

this is a hollow prim on touch script I picked up here on the forums and i am trying to get it to reset so the door closes again shortly after it has been opend, say 30 seconds.

so far I'm having no luck possibly due to my poor scripting skills...


//********************************************************
//This Script was pulled out for you by YadNi Monde from the SL FORUMS at /15/1.html, it is intended to stay FREE by it s author(s) and all the comments here in ORANGE must NOT be deleted. They include notes on how to use it and no help will be provided either by YadNi Monde or it s Author(s). IF YOU DO NOT AGREE WITH THIS JUST DONT USE!!!
//********************************************************






// Iris Open Script by Cera Murakami - 7/21/2006
// Touch-sensitive iris opening door
// Toggles open and closed state for a hole in a torus as an iris door
// Put this script into a flattened torus.

// Iris opening door script, using a torus
//This script enables you to use a torus as a simple touch-activated iris door, for science fiction or organic building projects. It uses a torus as the prim for the door, and opens or closes the hole in the torus to operate it.
//
//To use, make a flattened torus, the height and width you need for your door, and about 0.1M to 0.05M thick. The 'door frame' for this can be another torus, or an oval or round hole in another prim.
//
//Note that the same script should also be able to be used with a different prim shape for the iris door prim, by changing the specifications in the two llSetPrimitiveParams statements to suit the other prim shape. I'll experiment some more with that soon, and will offer some variations here later.


// ----- Global Variables ------------------
integer g_OpenNow; // True (1) if iris is 'open' now

default
{
on_rez(integer param)
{
llResetScript();
}

state_entry()
{
if (g_OpenNow == TRUE) // Prim is in open state, so calculate new 'closed' size
{
state WaitToClose;
}
else // Prim is in a closed (or undefined state), so calculate new 'open' size
{
g_OpenNow = FALSE;
state WaitToOpen;
}
}
}

state WaitToClose // Iris is Open, and waiting to close
{
touch_start(integer total_number)
{
llSetPrimitiveParams([PRIM_TYPE, PRIM_TYPE_TORUS, 0, <0.0, 1.0, 0.0>, 0.0, <0.0, 0.0, 0.0>, <1.0, 0.5, 0.0>, <0.0, 0.0, 0.0>, <0.0, 1.0, 0.0>, <0.0, 0.0, 0.0>, 1.0, 0.0, 0.0]);
g_OpenNow = FALSE;
state WaitToOpen;
}
}

state WaitToOpen // Iris is closed, and waiting to open
{
touch_start(integer total_number)
{
llSetPrimitiveParams([PRIM_TYPE, PRIM_TYPE_TORUS, 0, <0.0, 1.0, 0.0>, 0.0, <0.0, 0.0, 0.0>, <1.0, 0.05, 0.0>, <0.0, 0.0, 0.0>, <0.0, 1.0, 0.0>, <0.0, 0.0, 0.0>, 1.0, 0.0, 0.0]);
g_OpenNow = TRUE;
state WaitToClose;
}


timer()
{
llResetScript();
}
}

You don't have an llSetTimerEvent to tell it to start timing?

http://rpgstats.com/wiki/index.php?title=LlSetTimerEvent

Im playing around with default

llSetTimerEvent(30);

but having some difficulties figuring out where it goes in the script

syntax errors make me sad

//********************************************************
//This Script was pulled out for you by YadNi Monde from the SL FORUMS at /15/1.html, it is intended to stay FREE by it s author(s) and all the comments here in ORANGE must NOT be deleted. They include notes on how to use it and no help will be provided either by YadNi Monde or it s Author(s). IF YOU DO NOT AGREE WITH THIS JUST DONT USE!!!
//********************************************************






// Iris Open Script by Cera Murakami - 7/21/2006
// Touch-sensitive iris opening door
// Toggles open and closed state for a hole in a torus as an iris door
// Put this script into a flattened torus.

// Iris opening door script, using a torus
//This script enables you to use a torus as a simple touch-activated iris door, for science fiction or organic building projects. It uses a torus as the prim for the door, and opens or closes the hole in the torus to operate it.
//
//To use, make a flattened torus, the height and width you need for your door, and about 0.1M to 0.05M thick. The 'door frame' for this can be another torus, or an oval or round hole in another prim.
//
//Note that the same script should also be able to be used with a different prim shape for the iris door prim, by changing the specifications in the two llSetPrimitiveParams statements to suit the other prim shape. I'll experiment some more with that soon, and will offer some variations here later.


// ----- Global Variables ------------------
integer g_OpenNow; // True (1) if iris is 'open' now

default
{
on_rez(integer param)
{
llResetScript();
}

state_entry()
{
if (g_OpenNow == TRUE) // Prim is in open state, so calculate new 'closed' size
{
state WaitToClose;
}
else // Prim is in a closed (or undefined state), so calculate new 'open' size
{
g_OpenNow = FALSE;
state WaitToOpen;
}
}
}

state WaitToClose // Iris is Open, and waiting to close
{
touch_start(integer total_number)
{
llSetPrimitiveParams([PRIM_TYPE, PRIM_TYPE_TORUS, 0, <0.0, 1.0, 0.0>, 0.0, <0.0, 0.0, 0.0>, <1.0, 0.5, 0.0>, <0.0, 0.0, 0.0>, <0.0, 1.0, 0.0>, <0.0, 0.0, 0.0>, 1.0, 0.0, 0.0]);
g_OpenNow = FALSE;
state WaitToOpen;
}
}

state WaitToOpen // Iris is closed, and waiting to open
{
touch_start(integer total_number)
{
llSetPrimitiveParams([PRIM_TYPE, PRIM_TYPE_TORUS, 0, <0.0, 1.0, 0.0>, 0.0, <0.0, 0.0, 0.0>, <1.0, 0.05, 0.0>, <0.0, 0.0, 0.0>, <0.0, 1.0, 0.0>, <0.0, 0.0, 0.0>, 1.0, 0.0, 0.0]);
g_OpenNow = TRUE;
state WaitToClose;
}

}

llSetTimerEvent(30);
}

timer()
{
llResetScript();
}
}

give this a try...

integer g_OpenNow; // True (1) if iris is 'open' now

default
{
	on_rez(integer param)
	{
		llResetScript();
	}

	state_entry()
	{
		if (g_OpenNow == TRUE) // Prim is in open state, so calculate new 'closed' size
		{
			state WaitToClose;
		}
		else // Prim is in a closed (or undefined state), so calculate new 'open' size
		{
			g_OpenNow = FALSE;
			state WaitToOpen;
		}
	}
}

state WaitToClose // Iris is Open, and waiting to close
{
	state_entry()
	{
		llSetTimerEvent(30);		
	}

	timer()
	{
		llSetTimerEvent(0);
		llResetScript();
	}
	
	touch_start(integer total_number)
	{
		llSetTimerEvent(0);
		llSetPrimitiveParams([PRIM_TYPE, PRIM_TYPE_TORUS, 0, <0.0, 1.0, 0.0>, 0.0, <0.0, 0.0, 0.0>, <1.0, 0.5, 0.0>, <0.0, 0.0, 0.0>, <0.0, 1.0, 0.0>, <0.0, 0.0, 0.0>, 1.0, 0.0, 0.0]);
		g_OpenNow = FALSE;
		state WaitToOpen;
	}
}

state WaitToOpen // Iris is closed, and waiting to open
{
	state_entry()
	{
		llSetTimerEvent(30);		
	}

	timer()
	{
		llSetTimerEvent(0);
		llResetScript();
	}

	touch_start(integer total_number)
	{
		llSetTimerEvent(0);
		llSetPrimitiveParams([PRIM_TYPE, PRIM_TYPE_TORUS, 0, <0.0, 1.0, 0.0>, 0.0, <0.0, 0.0, 0.0>, <1.0, 0.05, 0.0>, <0.0, 0.0, 0.0>, <0.0, 1.0, 0.0>, <0.0, 0.0, 0.0>, 1.0, 0.0, 0.0]);
		g_OpenNow = TRUE;
		state WaitToClose;
	}
}

With the above code, I'd add in something to keep it from ping-ponging from state WaitToOpen to state default, which it will. If nobody is there to touch it, it will go from default to WaitToOpen and wait 30 seconds, reset, and go to default...repeated.

for some reason it doesnt seem to work, the prim hollows but still does not rest after 30 seconds

That code as written would do the following:

state default
--state entry
----g_OpenNow = undefined
----if check -> g_OpenNow = FALSE
state WaitToOpen
--state entry
----start 30 second timer
(you click the prim)
--touch start
----timer turned off
----prim hollowed
----g_OpenNow = TRUE
state WaitToClose
--state entry
----start 30 second timer
(you don't click the prim)
--timer
----timer turned off
----script reset
(this next section repeated indefinitely)
state default
--state entry
--g_OpenNow = undefined
--if check -> g_OpenNow = FALSE
state WaitToOpen
--state entry
----start 30 second timer
(you don't click the prim)
--timer
----timer turned off
----script reset
(end repeating section)

That what you wanted it to do?

An integer will get a default value of 0/FALSE if you don't explicitly set it to something else..

Yes, I'm aware of that, just pointing out that a default should have been chosen hehe

I just wanted to get the door to close automatically if it was not touched again after being opened

How about this? Untested but probably close to working..

float	TIMEOUT = 30.0;		// no touch = close after this time
integer	START_STATE = FALSE;// default to be closed
integer g_OpenNow; 			// TRUE if the door's open now

Change (integer open)
{
	g_OpenNow = open;

	if (open)
	{
		llSetPrimitiveParams([PRIM_TYPE, PRIM_TYPE_TORUS, 0, <0.0, 1.0, 0.0>, 0.0, <0.0, 0.0, 0.0>,
			 <1.0, 0.05, 0.0>, <0.0, 0.0, 0.0>, <0.0, 1.0, 0.0>, <0.0, 0.0, 0.0>, 1.0, 0.0, 0.0]);
	}
	else
	{
		llSetPrimitiveParams([PRIM_TYPE, PRIM_TYPE_TORUS, 0, <0.0, 1.0, 0.0>, 0.0, <0.0, 0.0, 0.0>,
			 <1.0, 0.5, 0.0>, <0.0, 0.0, 0.0>, <0.0, 1.0, 0.0>, <0.0, 0.0, 0.0>, 1.0, 0.0, 0.0]);
	}
}

default
{
	on_rez(integer param)
	{
		llResetScript();
	}

	state_entry()
	{
		Change (START_STATE);
	}

	touch_start(integer count)
	{
		Change (!g_OpenNow);

		float time;
		
		if (g_OpenNow)
		{
			time = TIMEOUT;
		}
		else
		{
			time = 0.0;
		}

		llSetTimerEvent(time);
	}

	timer()
	{
		Change (FALSE);
	}
}

should just have to change it to:

integer g_OpenNow = FALSE; // True (1) if iris is 'open' now

default
{
on_rez(integer param)
{
llResetScript();
}

state_entry()
{
if (g_OpenNow == TRUE) // Prim is in open state, so calculate new 'closed' size
{
state WaitToClose;
}
else // Prim is in a closed (or undefined state), so calculate new 'open' size
{
g_OpenNow = FALSE;
state WaitToOpen;
}
}
}

state WaitToClose // Iris is Open, and waiting to close
{
state_entry()
{
llSetTimerEvent(30); 
}

timer()
{
llSetTimerEvent(0);
llSetPrimitiveParams([PRIM_TYPE, PRIM_TYPE_TORUS, 0, <0.0, 1.0, 0.0>, 0.0, <0.0, 0.0, 0.0>, <1.0, 0.5, 0.0>, <0.0, 0.0, 0.0>, <0.0, 1.0, 0.0>, <0.0, 0.0, 0.0>, 1.0, 0.0, 0.0]);
g_OpenNow = FALSE;
state WaitToOpen;}

touch_start(integer total_number)
{
llSetTimerEvent(0);
llSetPrimitiveParams([PRIM_TYPE, PRIM_TYPE_TORUS, 0, <0.0, 1.0, 0.0>, 0.0, <0.0, 0.0, 0.0>, <1.0, 0.5, 0.0>, <0.0, 0.0, 0.0>, <0.0, 1.0, 0.0>, <0.0, 0.0, 0.0>, 1.0, 0.0, 0.0]);
g_OpenNow = FALSE;
state WaitToOpen;
}
}

state WaitToOpen // Iris is closed, and waiting to open
{
touch_start(integer total_number)
{
llSetPrimitiveParams([PRIM_TYPE, PRIM_TYPE_TORUS, 0, <0.0, 1.0, 0.0>, 0.0, <0.0, 0.0, 0.0>, <1.0, 0.05, 0.0>, <0.0, 0.0, 0.0>, <0.0, 1.0, 0.0>, <0.0, 0.0, 0.0>, 1.0, 0.0, 0.0]);
g_OpenNow = TRUE;
state WaitToClose;
}
} 

The above won't ping-pong between states.
It will rez and go to WaitToOpen.
It will sit there until clicked.
It will then open and go to WaitForClose and start a 30 second timer.
Whether it is clicked or the timer runs out in 30 seconds, it will close.
It will then sit in WaitForOpen until clicked again.

awesome!

simplified a bit...
refactored a bit...
got rid of the unneeded global variable and on_rez event...

default
{
    state_entry()
    {
        llSetPrimitiveParams([PRIM_TYPE, PRIM_TYPE_TORUS, 0, <0.0, 1.0, 0.0>, 0.0, <0.0, 0.0, 0.0>, <1.0, 0.5, 0.0>, <0.0, 0.0, 0.0>, <0.0, 1.0, 0.0>, <0.0, 0.0, 0.0>, 1.0, 0.0, 0.0]);
    }
    
    touch_start(integer total_number)
    {
        state open;
    }
}

state open
{
    state_entry()
    {
        llSetTimerEvent(30.0);
        llSetPrimitiveParams([PRIM_TYPE, PRIM_TYPE_TORUS, 0, <0.0, 1.0, 0.0>, 0.0, <0.0, 0.0, 0.0>, <1.0, 0.05, 0.0>, <0.0, 0.0, 0.0>, <0.0, 1.0, 0.0>, <0.0, 0.0, 0.0>, 1.0, 0.0, 0.0]);
    }
    
    touch_start(integer total_number)
    {
        state default;
    }
    
    timer()
    {
        state default;
    }
    
    state_exit()
    {
        llSetTimerEvent(0.0);
    }
}

The sole purpose of the default state seems to be to go to state WaitToOpen. The global flag seems to replicate what the states do for the script. The default state's on_rez handler can't ever run because the script never rests in the default state.