Transparency Script with Collision

excuse me, i'd need help with this script.
i'd want one transparent bridge that appears when an avatar walks above.

i've done this script:

//script traparency fade with collision

float f_alpha = 0.0; 
float f_step = 0.05; //alpha change speed

default
{
on_rez(integer start_param)
{
llResetScript();
}
collision(integer num_detected)
{
f_alpha += f_step;
if (f_alpha+f_step > 1.0) {f_step = -f_step;}
if (f_alpha+f_step < 0.0) {f_step = -f_step;}
llSetAlpha(f_alpha,ALL_SIDES);
}
}

but i have two problems:
- first i want that the prim is always transparent if anybody walks above
- second i want it remains visible if there are avatars above

now if you try the script and you are above the prim, you see that the prim continues becomes visible and full transparent continuously

thanks everyone would help me

Indiana Jones and the Last Crusade, huh?

Instead of collision, use a collision_start event to make the bridge visible and a collision_end event to make it invisible again.

eheh

could you help me to insert in the right place please?

i've done this simple script with collision start and end:

//script traparency fade with collision

float f_alpha = 0.0; 
float f_step = 1.0; //alpha change speed

default
{
on_rez(integer start_param)
{
llResetScript();
}
collision_start(integer num_detected)
{
llSetAlpha(1.0, ALL_SIDES);
}

collision_end(integer num_detected)
{
llSetAlpha(0.0, ALL_SIDES);
}
}

but i'd like that the prim becomes visible and invisible gradually
you could help me again?

I think this does the trick.

I'd probably do something like this. Normally I wouldn't use states so prolifically, but the different handling of events in this one and the fact that it makes things very understandable in this script make me more inclined toward it.

(Note: Hasn't yet been compiled; may require a couple small syntax fixes.)

float APPEAR_PERIOD = 0.5;
float DISAPPEAR_PERIOD = 0.5;
float DISAPPAEAR_DELAY = 0.5;
float FADE_UPDATE_PERIOD = 0.05;

float transitionStartTime;

default
{
   state_entry()
   {
      state invisible;
   }
}

state invisible
{
   state_entry()
   {
      llSetAlpha(0.0, ALL_SIDES);
   }

   collision_start(integer nDetected)
   {
      transitionStartTime = llGetTime();
      state appearing;
   }
}

state appearing
{
   state_entry()
   {
      llSetTimerEvent(DISAPPAEAR_DELAY);
   }

   state_exit()
   {
      llSetTimerEvent(0.0);
   }

   collision(integer nDetected)
   {
      float time = llGetTime();
      float t = (time-transitionStartTime)/APPEAR_PERIOD;

      if (t >= 1.0)
      {
         state visible;
      }

      llSetTimerEvent(DISAPPAEAR_DELAY);
      llSetAlpha(t, ALL_SIDES);
   }

   timer()
   {
      float time = llGetTime();
      float t = (time-transitionStartTime)/APPEAR_PERIOD;

      // Back calculate disappear start time for same alpha
      transitionStartTime = time-(1.0-t)*DISAPPEAR_PERIOD;

      state disappearing;
   }
}

state visible
{
   state_entry()
   {
      llSetAlpha(1.0, ALL_SIDES);
      llSetTimerEvent(DISAPPAEAR_DELAY);
   }

   state_exit()
   {
      llSetTimerEvent(0.0);
   }

   collision_start(integer nDetected)
   {
      llSetTimerEvent(DISAPPAEAR_DELAY);
   }

   timer()
   {
      transitionStartTime = llGetTime();
      state disappearing;
   }
}

state disappearing
{
   state_entry()
   {
      llSetTimerEvent(FADE_UPDATE_PERIOD);
   }

   state_exit()
   {
      llSetTimerEvent(0.0);
   }

   timer()
   {
      float time = llGetTime();
      float t = (time-transitionStartTime)/DISAPPEAR_PERIOD;

      if (t >= 1.0)
      {
         state invisible;
      }

      llSetAlpha(1.0-t, ALL_SIDES);
   }

   collision(integer nDetected)
   {
      float time = llGetTime();
      float t = (time-transitionStartTime)/DISAPPEAR_PERIOD;

      // Back calculate appear start time for same alpha
      transitionStartTime = time-(1.0-t)*APPEAR_PERIOD;

      state appearing;
   }
}

haha, hewee. i tried it. it compiles as is, but the bridge continues to appear and then fade out over and over after someone has initialized it by walking on it (whether they're still on it or not)

Oh yeah. Fixed above. I just forgot to change one of the target states when I copied and pasted. Sorry. That SHOULD fix it I think.

thanks everybody

thank to your help i resolved my problem