text on box

Currently, there's no better option than one of the XyText solutions. You could try to reinvent the wheel, but more than likely you'll end up with just another wheel.

XyText can be a little confusing at first, but once you understand how to get it going, you might be surprised how useable it really is.

All you need to do is:
1) Use the XyText prim-maker script to create either the 3 or 5 character prim
2) remove that utility script, add the matchin 3 or 5 character XyText script
3) save a copy of the prim for quick future use

For a single-prim display:
4) send a link message to the prim - llMessageLinked(LINK_SET, DISPLAY_STRING, "test", "";

For a multi-prim setup, it can get a little complex, but it's a simple concept:
To initialize the prims, you target a link message to each prim via it's link number... that message assigns a row integer to all the prims in a single row along with the starting character index for the column.

I use a two dimensional loop with the outer loop being a row counter, and the inner loop being the column. As well, there is an incremental link number. So, each outer loop increases the row integer... the inner loop increases the column integer and link integer, and the message sent is something like:
llMessageLinked(linkNum, SET_CELL_INFO, llList2CSV([row,col*5]), "";
(the *5 is for 5-character prims, would be *3 for 3-character XyText)

Of course, the important thing is to link the prims in the correct order... right to left, bottom to top... to make things easier.

////////////////////////////////////////////
// XyText v1.1 Script (Single Texture)*
//
// Written by Xylor Baysklef
// *modified to display one character on one face of one prim
////////////////////////////////////////////

/////////////// CONSTANTS //////////////////
// XyText Message Map
integer DISPLAY_STRING = 204000;
integer SET_CELL_INFO = 204004;

// Face number
integer MIDDLE_FACE = 0;

//////////// GLOBAL VARIABLES //////////////
// This is the key of the font we are displaying.
key gFontTexture = "b2e7394f-5e54-aa12-6e1c-ef327b6bed9e";
// All displayable characters. Default to ASCII order.
string gCharIndex;
// This is the channel to listen on while acting as a cell in a larger display.
integer gCellChannel = -1;
// This is the starting character position in the cell channel message to render.
integer gCellCharPosition = 0;
/////////// END GLOBAL VARIABLES ////////////

ResetCharIndex() {
gCharIndex = " !\"#$%&'()*+,-./0123456789:;<=>?@ABCDEFGHIJKLMNOPQRSTUVWXYZ[\\]^_`";
// \" <-- Fixes LSL syntax highlighting bug.
gCharIndex += "abcdefghijklmnopqrstuvwxyz{|}~";
gCharIndex += "\n\n\n\n\n";
}

vector GetGridOffset(integer index) {
// Calculate the offset needed to display this character.
integer Row = index / 10;
integer Col = index % 10;

// Return the offset in the texture.
return <-0.45 + 0.1 * Col, 0.45 - 0.1 * Row, 0.0>;
}

ShowChars(vector grid_offset1) {
// Set the primitive textures directly.
llSetPrimitiveParams([PRIM_TEXTURE, MIDDLE_FACE, (string) gFontTexture, <0.05, 0.1, 0>, grid_offset1, 0.0]);
}

RenderString(string str) {
// Get the grid positions for each pair of characters.
vector GridOffset1 = GetGridOffset( llSubStringIndex(gCharIndex, llGetSubString(str, 0, 0)) );

// Use these grid positions to display the correct textures/offsets.
ShowChars(GridOffset1);
}

default {
state_entry() {
// Initialize the character index.
ResetCharIndex();
}

link_message(integer sender, integer channel, string data, key id) {
if (channel == DISPLAY_STRING) {
RenderString(data);
return;
}
if (channel == gCellChannel) {
// Extract the characters we are interested in, and use those to render.
string TextToRender = llGetSubString(data, gCellCharPosition, gCellCharPosition);

RenderString( TextToRender );
return;
}
if (channel == SET_CELL_INFO) {
// Change the channel we listen to for cell commands,
// and the starting character position to extract from
list Parsed = llCSV2List(data);
gCellChannel = (integer) llList2String(Parsed, 0);
gCellCharPosition = (integer) llList2String(Parsed, 1);
return;
}
}
}