Activate particles on flight, deactivate on land

Is this possible? Basically, a light particle trail on one of my attachments, I'd like it to automatically turn on when I enter fly mode, and disable again when I land. Right now I've got to use two seperate attachments, one with the particles on, one without, and manually switch them when I switch to fly... which is really ugly. Hee. Is there a quick script to either turn on/off particles, or swap attachments in a position when switching from walking to flying and vice versa?

Thanks in advance for... well... anything.

-Psyra-

Well, maybe it's a bit unwieldly and someone here can suggest a better method, but I usually have a timer firing every two seconds or so, checking againt ( llGetAgentInfo( llGetOwner() ) & AGENT_FLYING )

If it's true, then call your happy llParticleSystem() thingie. If it's not true, then call llParticleSystem([]);

I imagine instead of using a timer one could probably use land_collision_end() or some crazy thing like that, I dunno. I'm not exactly an efficient coder. ^^

particlesystemfunction()
{
     // Your cute particle system code goes here as a function!
}

default
{
     state_entry()
     {
           llSetTimerEvent( 2 ) ;
     }

     timer()
     {
           if( llGetAgentInfo( llGetOwner() ) & AGENT_FLYING )
          {
               particlesystemfunction() ;
          }

          else
          {
               llParticleSystem( [] ) ;
          }
     }
}

Ahhhh, yeah, it was a challenge to incorporate it, but it worked! MANY THANKS!

Most welcome! Hehe, it's more or less what I used on my daemoney wings-things.

I use the same thing on my jetpack. It "unfolds" the wings (turns the alpha up from 0) and turns on the particles on the thrusters all at once.

So the way Cross posted will work, but it will send a lot of unnecessary data to your client (and everyone nearby) every 2 seconds. This one would be better:

integer isFlying = FALSE;

particlesystemfunction()
{
     // Your cute particle system code goes here as a function!
}

default
{
     state_entry()
     {
           llSetTimerEvent( 2 ) ;
     }

     timer()
     {
           if( (llGetAgentInfo( llGetOwner() ) & AGENT_FLYING) && !isFlying )
          {
               particlesystemfunction() ;
               isFlying = TRUE;
          }

          else if( !(llGetAgentInfo( llGetOwner() ) & AGENT_FLYING) && isFlying )
          {
               llParticleSystem( [] ) ;
               isFlying = FALSE;
          }
     }
}

Why? Because everytime you call the llParticleSystem(...) it sends all that information to everyone nearby, however the particle system is designed to keep goign with only 1 call. This way the system is called only when you change modes - when you start or stop flying.

I told you somoene smarter'n me would come along. ^^

Well i just found this and chopped it apart and cramed it into my fun new jet pack.... man you guys are good!!!