llDialog numbered buttons from list?

Hi I hope someone can help me out - I have adapted a script that produces a sort of multi-page llDialog from a preset list so that it now populates the list from a http request from a server. That works fine.

The problem I have is that each button is named according to the particular item in the list and as a result is limited to a few characters. To get around this I would like a numbered list in the 'message' part of the dialog and then the corresponding buttons numbered (not titled).

So something like this:

___________________________

1. First Item
2. Second Item
3. Third Item
etc

[ 1 ] [ 2 ] [ 3 ] etc [ Next ]

____________________________

Instead of:
_______________________

Your message etc

[ First Item ] [ Second Ite ] [ Third Item ] etc [ Next ]

____________________________

I have pulled apart a few scripts from the forums here but they seem to rely on notecards and my knowledge on lists is basic so I'm struggling a little.

If anyone can point me in the right direction (or give a little, basic example of breaking a list down in a way that the buttons can be numbered etc) it would be appreciated!

Take a look at /54/18/313629/1.html

send a list of numbers (properly ordered) to the dialog, and in the list use the numbers to reference the list of items by their index

Errr... I can understand the logic but I'm not entirely sure how to implement it!

So, from the list created from the http response, I have a list such as:

list wibble = ["Emma Roids","Hugh Jars","Heidi Vodka","Albert Ross","Drew Peacock"];

And what I need to do is associate the index 0 with Emma, 1 with Hugh, 2 with Heidi etc. Then put the numbers onto the buttons (these vary depending how many entries are downloaded) and display the listings in the message. How would you implement that - via a strided list somehow?

I'm not looking for someone else to do the dirty work for me but I'm just trying to get my grey matter around lists lol.

In it's simplest form:

list wibble = ["Emma Roids","Hugh Jars","Heidi Vodka","Albert Ross","Drew Peacock"];
list idxList = [0,1,2,3,4];

default {
	touch_start(integer n) {
		llListen(-2312,"","","");
		llDialog(llDetectedKey(0),"test",idxList, -2312);
	}
	listen(integer channel, string name, key id, string msg) {
		llOwnerSay(llList2String(wibble, (integer)msg));
	}
}

Oooh hangon, penny dropped.

The dialog buttons are numbered based on the number of elements in the list, yeah?

Then, when the number is clicked, it tells the script to do a search through the list based on the index.

The dim light is slowly dawning on me - or is that a train?!

Thanks Void & Jessie - I think I understand it more now. When I come inworld tomorrow I'll get stuck into this. Cheers!

Glad to see you learning. Next bit of magic is to autopopulate the idxlist based on the length of the wibble list like so:

list wibble =["Emma Roids", "Hugh Jars", "Heidi Vodka", "Albert Ross", "Drew Peacock"];
list idxList;

default {
	state_entry() {
		integer len = llGetListLength(wibble);
		integer i;
		for(i = 0; i < len; ++i){
			idxList += i;
		}
	}
	touch_start(integer n) {
		llListen(-2312, "", "", "");
		llDialog(llDetectedKey(0), "test", idxList, -2312);
	}
	listen(integer channel, string name, key id, string msg) {
		llOwnerSay(llList2String(wibble, (integer) msg));
	}
}

Gotcha - its a for loop which is saying that the counter (i) is zero and whilst it is less than the list length, increase i (the counter) by 1 and add that to the list 'idxList'. Once the whole list is done, reference that list as the dialog buttons.

So now I need to put a Previous and Next button - I think that would mean llDialog would need to be limited to returning 10 entries at a time plus the "Previous" and "Next" buttons - would that mean using a temporary list, referencing the idxList and using List2List somehow?

i can always start at 1 instead of zero and end at 11 instead of list length.

Take a look here for more on lists:

http://lslwiki.net/lslwiki/wakka.php?wakka=list

Hmmm trying those scripts out gives me an error message:

llDialog: button list must contain only strings

I'm guessing its something with the idxList containing integers and not strings?

Well, had a play with it and tweaked it from:

idxList += i;

to

idxList += [(string)i];

that displays the buttons - now to tally them up!

Ahh,You are right. I tested in LSLEditor and it would not have caught that. Glad you figured it out.

One note I'd like to throw in is the ordering of buttons on dialogues, as it's left to right and top to bottom which can make for messy dialogues if you don't sort them properly. You can sort them into the correct order by doing:

integer l = ((butons != []) % 3);
if (l == 2) buttons += [" "];
else if (l == 1) buttons += [" ", " "];
buttons = llListSort(llListSort((buttons = []) + buttons, 1, TRUE), 3, FALSE);

That should ensure your buttons go from 1 to 12 or whatever.

To explain the code; the (buttons != []) is a quick way to get a list's length, and is less costly than llGetListLength(), that same line is using module (%) to see if the buttons list contains a multiple of 3 buttons or not. If it returns a non zero value (1 or 2), then it adds some blank buttons to pad the result.

The statement ((buttons = []) + buttons) is used here to save memory, this works because the buttons list is being overwritten as a result of that line. The line itself sorts the list first into ascending order, which you may be able to skip in this particular case as your list is a load of numbers which are going to be in order anyway I think? The other (outer) sort then sorts the list in groups of 3 elements so that they're ordered correctly by the dialogue.