night cycle

Hi script gods.....I have a 3 prim object, that has lighting applied, and I would LOVE for it to be invisible during the day, and come into being, as it were, at night.... can anyone suggest how i might achieve this?...many thanks

Do you mean that you want

1. Visible but unlit during the day
   
2. Invisible but lit during the day
   
3. Invisible and unlit during the day
   

?

Hiya Bam.... ideally, it would be invisible unlit daytime, and visible, lit, nightime....
thanks
Turgar

you better be *really* good at remembering where you park it.........

You want something along the lines of the following:

// Day-night check action script
// Performs different actions when it becomes light or dark, checking
// every minute.

// Ordinal Malaprop
// 2006-06-20

integer daytime()
{
   vector sun = llGetSunDirection();
   return (sun.z >= 0.0);
}

default
{
   state_entry()
   {
      llSetTimerEvent(60.0);
      if (!daytime()) state night;
      // insert things to be done in the day e.g.
      llOwnerSay("I now think it is daytime");
   }

   timer()
   {
      if (!daytime()) state night;
   }

   on_rez(integer p)
   {
      llResetScript();
   }
}

state night
{
   state_entry()
   {
      // insert things to be done in the night e.g.
      llOwnerSay("I now think it is nighttime");
   }

   timer()
   {
      if (daytime()) state default;
   }

   on_rez(integer p)
   {
      llResetScript();
   }
}

To make something vanish, use llSetLinkAlpha(LINK_SET, 0.0, ALL_SIDES) - to make it appear again use 1.0 instead of 0.0. (Assuming you've not changed the alpha values of any prims in the design manually.) You can use llSetPrimitiveParams to make it emit light or stop it emitting light.

Ah, beat me to it Ordinal. I find llGetSunDirection gives good results

thanks guys......giving it a go!
Turgar