Curious about a possible "batch" function?

This is a snippet of code from a vegetation planter that was written by Laukosargas Svarog in this thread: 264152

else if ( message == "planter show" ) 
{ 
while( (linkKey = llGetLinkKey(i)) != NULL_KEY ) 
{ 
llSetLinkAlpha( i, 1.0, ALL_SIDES ); 
i = i + 1; 
} 
} 
else if ( message == "planter hide" ) 
{ 
while( (linkKey = llGetLinkKey(i)) != NULL_KEY ) 
{ 
llSetLinkAlpha( i, 0.0, ALL_SIDES ); 
i = i + 1; 
}

From what I can see here, this is a functon to set all prims of a linked object alpha using a single script. Is this true? And if so, can it work on avatar attachments?

Right now I use a listen script on avatar wings to turn them invisible (alpha setting just like the code above) when I'm not in flight. The annoyance being that the script needs to be placed on every single prim in the wing.

*IS* it possible to affect all the prims of an object or attachment with a /single/ script without having to dump scripts into every single child prim?

Just curious, and hopeful... it woul certainly make updating features on an avatar a LOT easier if you only had to change 15 scripts, rather than 200+ just to add a one line new function or so...

I'm stuick at work for almost 3 more hours so I can't test this.... but if it works, it could open a whole world of creating and improving all sorts of things. I almost expect someone to tell me "Oh, everyone's been doing that for years, you just never got with the program".... well, what script knowledge I have is from studying other scripts like this one.

I'm curious now too. I'm going to test this and see if you can put ONE script in a linked set and have them all go alpha at the same time from the same script.

If not, then you might have to use llMessageLink to send the same message from the root prim to all the child prims to perform the same command.

Everyone's been doing that for decades, and you're just now getting with the program.

Prims can only be affected by llSetLink* functions though, and I don't remember what functions of that type exist. Alpha is one of them though. (And you can even affect a single linked prim, rather than the whole set.)

*eats Moleculor*

I've been meaning to do that for decades, I just got with that program today too. *urrp*

Well, I came up with this as an idea for a test script. You place it in the root prim of any object, and you can toggle the whole prim's invisibility with one single 'show' or 'hide' command. Woot!

// ===========================================================
//   A nice single-script Attachment Hiding Function Thingy!
// ===========================================================

integer i;
key linkKey;

default
{
    state_entry()
    {
        key owner = llGetOwner();
        llListen(0,"",owner,"");
    }
    
    listen( integer channel, string name, key id, string message )
    {
        if( message == "hide" )
        {
             i = 1;
             while( (linkKey = llGetLinkKey(i)) != NULL_KEY ) 
             { 
             llSetLinkAlpha( i, 0.0, ALL_SIDES ); 
             i = i + 1; 
             } 
        }
        if( message == "show" )
             i = 1;
             while( (linkKey = llGetLinkKey(i)) != NULL_KEY ) 
             { 
             llSetLinkAlpha( i, 1.0, ALL_SIDES ); 
             i = i + 1; 
        }
    }
}

My knowledge of code is what I can smash together out of two scripts into one. Sometimes they work, sometimes they don't. This one does. Are there any limitations to this script I should know about??

You forgot some brackets, and there is a faster way (less function calls) to do it(especially if this script is going to stay how it is

// ===========================================================
//   A nice single-script Attachment Hiding Function Thingy!
// ===========================================================

integer i;
integer prims;

default
{
    state_entry()
    {
        llListen(0,"",llGetOwner(),"");
    }
    
    listen( integer channel, string name, key id, string message )
    {
        if( message == "hide" )
        {
             prims = llGetNumberOfPrims();
             for (i = 1; i <= prims; i++)
             { 
                     llSetLinkAlpha( i, 0.0, ALL_SIDES ); 
             } 
        }
        else if( message == "show" )
        {
             prims = llGetNumberOfPrims();
             for (i = 1; i <= prims; i++)
             { 
                     llSetLinkAlpha( i, 1.0, ALL_SIDES ); 
             }
        }
    }
}

but yeah, your way would have worked too, except it show each prim after it hides them

pretty sure this will work (know it works for llSetLinkColor)

default
{
    state_entry()
    {
        llListen(0,"",llGetOwner(),"");
    }
    
    listen( integer channel, string name, key id, string message )
    {
        channel=llListFindList(["hide","show"],[message]);
        if( channel + 1)
             llSetLinkAlpha( LINK_SET, (float)channel, ALL_SIDES ); 
    }
}

If you use that code on something, and you want to sell it, is this one that needs to have "mod" permissions set so it will work?

(just curious)

don't think so...

Damn! that's at least the 3rd time i've forgotten about that constant !

lol