Particle parameters for ruthcloud, anyone?

Does anybody know a good llParticleSystem() setting to emulate the ruthcloud (i.e. the white gaseous entity shown while avatars are loading, now shown instead of good ole' Ruth)?

Many thanks in advance.

Wheeeeeeeeee!

// Particle parameters transcribed from newview/llvoavatar.cpp
//
// The glowy cloud texture is distributed with the viewer as cloud-particle.j2c.
// I uploaded a copy as 1759c1dc-d8e3-8081-a2bb-052190abcadf

default
{
    state_entry()
    {
        llSetText("Ruth", <.984, .686, .365>, 1.);

        llParticleSystem([
            PSYS_PART_MAX_AGE,          4.,
            PSYS_PART_START_SCALE,      <0.8, 1.0, 0.>,
            PSYS_PART_END_SCALE,        <.02, .02, 0.>,
            PSYS_PART_START_COLOR,      <1., 1., 1.>,
            PSYS_PART_START_ALPHA,      0.5,
            PSYS_PART_END_COLOR,        <1., 1., 1.>,
            PSYS_PART_END_ALPHA,        0.,
            PSYS_SRC_TEXTURE,           "1759c1dc-d8e3-8081-a2bb-052190abcadf",
            PSYS_SRC_MAX_AGE,           0.,
            PSYS_SRC_PATTERN,           PSYS_SRC_PATTERN_ANGLE_CONE,
            PSYS_SRC_INNERANGLE,        PI,
            PSYS_SRC_OUTERANGLE,        0.,
            PSYS_SRC_BURST_RATE,        0.02,
            PSYS_SRC_BURST_RADIUS,      0.,
            PSYS_SRC_BURST_PART_COUNT,  1,
            PSYS_SRC_BURST_SPEED_MIN,   0.1,
            PSYS_SRC_BURST_SPEED_MAX,   1.,
            PSYS_PART_FLAGS,
                PSYS_PART_INTERP_COLOR_MASK | PSYS_PART_INTERP_SCALE_MASK |
                PSYS_PART_EMISSIVE_MASK | PSYS_PART_TARGET_POS_MASK
        ]);

    }
}

Many thanks, Ms. Dovgal! Given your forum picture, it *had* to be you!