touch guest book list

I just need a script that senses when an avie is within a defined range, queries them if they would like to sign the guest book , and upon approval, records them into a list. Of course that list will have to be accessable for collection later. Would appreciate any help you can give!

i have a script that does that w/o the sign-in, but that should be easy to add. IM me in-world and i can drop you a copy, or i'll post it here when i can.

There are several visitor counters around that do this, without asking them for permission as well...

yes i know , but i want it to

Ooh! I want one as well. That would be kind of cool!

Here is the visitor list I use on my home. I based it on a freebie script I found somewhere. It is keyed to group ownership, so set the group on the object and anyone with that group active can view or reset the list. Admin is done by touching the object and selecting a command from a dialog.

This script uses a sensor to detect visitors. It does not ask them to sign in. You could do that by presenting them a dialog to sign in or not, or you could ask them to come touch the object. I'd go with the dialog.

// Global variables
list visitor_list;
float range = 35.0; // in meters
float rate = 6.0; // in seconds

integer CHANNEL = 424242;
integer ListenHandle = 0;
key     User = NULL_KEY;
 
// Functions
integer isNameOnList( string name ) 
{
    integer len = llGetListLength( visitor_list );
    integer i;
    for( i = 0; i < len; i++ )
    {
        if( llList2String(visitor_list, i) == name )
        {
            return TRUE;
        }
    }
    return FALSE;
}
 
// States
default 
{
    state_entry()
    {
        llSensorRepeat( "", "", AGENT, range, TWO_PI, rate );
    }
      
    touch_start(integer total_number) 
    {
        User = llDetectedKey(0);
        if ( ! llSameGroup(User) ) return;
        
        ListenHandle = llListen(CHANNEL, "", User, "");  // listen for the dialog answer
        llDialog(User, "Guest List action:", ["List", "Reset"], CHANNEL);
    }

    sensor( integer number_detected )
    {
        integer i;
        for( i = 0; i < number_detected; i++ )
        {
            // llShout(0, "PING!  " + llGetTimestamp() );
            if( llDetectedKey( i ) != llGetOwner() )
            {
                string detected_name = llDetectedName( i );
                if( isNameOnList( detected_name ) == FALSE )
                {
                    visitor_list += detected_name;
                }
            }
        }    
    }

    listen( integer channel, string name, key id, string message )
    {
        llListenRemove(ListenHandle);
        
        if( llSameGroup(id) )
        {
            if( message == "List" )
            {
                llSay( 0, "Guest List:" );
                integer len = llGetListLength( visitor_list );
                integer i;
                for( i = 0; i < len; i++ )
                {
                    llSay( 0, llList2String(visitor_list, i) );
                }
                llSay( 0, "Total = " + (string)len ); 
            }
            else
            if( message == "Reset" )
            {
                visitor_list = llDeleteSubList(visitor_list, 0, llGetListLength(visitor_list));
                llSay( 0, "Done resetting.");
            }
        }
    }        
}

I'd replace the isNameOnList function with a call to llListFindList.

if ( llListFindList( visitor_list, [name] ) >= 0 )
// then a match was found