Giver "tripwire"

Hello,

I'm helping with a build that calls for a script I can toss in a prim, so when one passes though said prim, they a notecard. I've searched around but I may be searching for the wrong tearms. I found one, but it seems to want to give it to anyone within 5m of the prim. I just need a tripwire type script.

Any help is greatly appreciated!

Nerolus

default
{
    state_entry()
    {
        llVolumeDetect(TRUE);
    }
    collision_start(integer num_detected)
    {
        llGiveInventory(llDetectedKey(0),"notecard");
    }
}

This should work I think.

I'd expand that to:

list lastAvatars;
integer maxListSize = 20;

default {
    state_entry() { llVolumeDetect(TRUE); }
    collision_start(integer x) {
        while (x > 0) { // Go through all new collisions
            --x;
            key id = llDetectedKey(x);
            if (llListFindList(lastAvatars, [id]) < 0) { // Is this a new avatar?
                llGiveInventory(llDetectedKey(0), "notecard");
                lastAvatars += [id]; // Add them to the recent avatars list
            }
        }

        x = llGetListLength(lastAvatars) ;
        if (x > maxListSize) // Check the avatar list hasn't grown too large
            lastAvatars = llList2List(x - maxListSize, -1);
    }
}

Awesome! Thanks you two!

^^ doesnt work

Argh pants, I posted the version from my inventory, must be out of date. Here's the live version I use:

list lastAvatars; 
integer maxListSize = 20; 

default { 
    state_entry() { llVolumeDetect(TRUE); llMinEventDelay(0.5); } 
    collision_start(integer x) {
        string note = llGetInventoryName(INVENTORY_NOTECARD, 0); // Get a notecard
        if (note != "") {
            while ((--x) >= 0) { // Go through all new collisions 
                if (llDetectedType(x) & AGENT) { // Only avatars
                    key id = llDetectedKey(x); 
                    if (llListFindList(lastAvatars, [id]) < 0) { // Is this a new avatar? 
                        llGiveInventory(llDetectedKey(x), note); 
                        lastAvatars += [id]; // Add them to the recent avatars list 
                    }
                }
            } 

            x = llGetListLength(lastAvatars) ; 
            if (x > maxListSize) // Check the avatar list hasn't grown too large 
                lastAvatars = llList2List(lastAvatars, x - maxListSize, -1); 
        }
    } 
}

This will use the first notecard in your object's inventory, if you need it to use a different one then replace the note variable with the name.