Trouble with a llGiveInventory

I'm not very good at scripting and i've been having troubles with the following script. I've been looking in the library and in the LSLwiki but it seems i fail at make it work as i want. ;_;

What i want to do it's when clicked the box(prim) send a folder with the inventory content from it. Only to the owner of the box and i want the folder in the inventory had the same name from the box (prim) where he or she clicked on. So when they look in their inventory there's a folder called for example: prim1 with its content, so it would be easier for them to search the content im giving. I wish the box would also tell to the person that the contents are now in their inventory with the following name (the name from the prim/box).

Thank you so much in advance!

string gFolder = "objectname";

key gowner;
key gtoucher;
integer gx;
integer gcount;
list gtextures;

default
{
on_rez(integer param)
{
llResetScript();
}

state_entry()
{
gowner = llGetOwner();
gcount = llGetInventoryNumber(INVENTORY_ALL);
for (gx = 0; gx < gcount; gx++)
{
gtextures = (gtextures = []) + gtextures + [llGetInventoryName(INVENTORY_ALL, gx)];
}
}

touch_start(integer total_number)
{
gtoucher = llDetectedKey(0);
if (gtoucher == gowner)
{
llGiveInventoryList(gowner, gFolder, gtextures);
}
}
}

Although there's a few bits you could do to make it neater, I don't see anything obviously wrong with it. Then again, I've never used llGiveInventoryList..

Are you just looking to get the folder name the same same the object? If so, I think you just want to do this:

llGiveInventoryList(llGetOwner(), llGetObjectName(), gtextures);


...or is there something else wrong?

edit: and you probably want to add this bit so you pick up on changes to the inventory after the script resets:

changed (integer mask)
{
if (mask & CHANGED_INVENTORY)
{
llResetScript();
}
}

So what's not working? Your script seems to compile OK. Do you just want it to say what's in it and then tell the buyer that s/he has just received a folder? If so, then add llSay or llOwnerSay statements in a couple of spots. For example ....

for (gx = 0; gx < gcount; gx++)
{
     llSay(0,llGetInventoryName(INVENTORY_ALL,gx));
     gtextures = (gtextures = []) + gtextures + [llGetInventoryName(INVENTORY_ALL, gx)];
}

and

if (gtoucher == gowner)
{
     string gFolder = llGetObjectName();
     llGiveInventoryList(gowner, gFolder, gtextures);
     llOwnerSay("Look in your inventory for a new folder named " + gFolder);
}

and remove gFolder from your list of global variables, since it doesn't need to be global if you do this.

As an aside, you might try visiting the Virtual Learning Library in the NW corner of the Info Island sim. (I'd give you a SLURL but I can't get in world to grab it right now. Use your map.) Go to the Scripting collection on the second floor and look for the two boxes of freebie scripts. Among other things, these contain a couple of vendor scripts you might be able to use or learn from, plus a script that displays an object's contents in scrolling hover text.

Likely, your problem is here:

touch_start(integer total_number) {
    gtoucher = llDetectedKey(0);
    if (gtoucher == gowner) {
        llGiveInventoryList(gowner, gFolder, gtextures);
    }
}

Since you set gowner in state_entry(), it will have your key in it. When you give/sell it to someone else, it will still have your key.

Replace the highlighted line(s) above with:

    if (gtoucher == llGetOwner()) {
        llGiveInventoryList(llGetOwner(), gFolder, gtextures);
    }

Meade's solution will work, too, unless you have other reasons for not resetting the script upon selling/transferring the product.

Thank you so much for your help guys.
I did have troubles editing again the script, with this fix

if (gtoucher == llGetOwner()) {
llGiveInventoryList(llGetOwner(), gFolder, gtextures);
}

it compiled but it isnt working.

I was trying also Roling's options but im having troubles with setting again the list of variables. (Also thank you for the suggestion for the place, im heading over).

string gFolder = "objectname"; //such a pain

key gowner;
key gtoucher;
integer gx;
integer gcount;
list gtextures;

default
{
on_rez(integer param)
{
llResetScript();
}

state_entry()
{
gowner = llGetOwner();
gcount = llGetInventoryNumber(INVENTORY_ALL);
for (gx = 0; gx < gcount; gx++)
{
gtextures = (gtextures = []) + gtextures + [llGetInventoryName(INVENTORY_ALL, gx)];
}
}

touch_start(integer total_number)
{
gtoucher = llDetectedKey(0);
if (gtoucher == llGetOwner()) {
llGiveInventoryList(llGetOwner(), gFolder, gtextures);
}
}
}

Nice catch.

How's this work?

list gtextures;

default
{
	on_rez(integer param)
	{
		llResetScript();
	}

	changed (integer mask)
	{
		if (mask & CHANGED_INVENTORY)
		{
			llResetScript();
		}
	}

	state_entry()
	{
		integer gcount = llGetInventoryNumber(INVENTORY_ALL);
		integer gx;

		for (gx = 0; gx < gcount; gx++)
		{
			gtextures = (gtextures = []) + gtextures + [llGetInventoryName(INVENTORY_ALL, gx)];
		}
	}

	touch_start(integer total_number)
	{
		if (llDetectedKey(0) == llGetOwner())
		{
			llInstantMessage (llGetOwner(), "Here, have a folder named '" + llGetObjectName() + "'!!");
			llGiveInventoryList(llGetOwner(), llGetObjectName(), gtextures);
		}
	}
}

Meade's cleaned-up version will work fine. If you still want to tell the user what's going on, just pop the llSay and llOwnerSay statements I suggested into her script and you should be good to go.

It worked perfectly! Thank you!!

You're welcome!

Do you see what I did differently?