join a group

// Script to Add To Group Via Email
// written in responce to post by Erik Hugo 
//
// Constants
float TimePeriod = 86400.0; // Time between auto clearing of teh list in seconds (86400 = )1 day
integer MaxListLength = 50;  // or when list reaches 50 avatars
string EmailAddress = "someone@somewhere.net"; // Where to email the data
string GroupName = "My Group";

// Variables
string AddToGroup= "";   // Records the names of the avatars being added
integer ListLength = 0;  // Records how many 


default
{
    state_entry()
    {
        ListLength = 0;
        AddToGroup= "";
        llSetText("Touch me to be added to \n\"" + GroupName + "\"",<1.,1.,1.>,1.);
        llSetTimerEvent(TimePeriod);
    }
    
    touch_start(integer number)
    {
        while(--number >= 0)
        {
            string name = llDetectedName(number);
            integer index = llSubStringIndex(AddToGroup,name);
            // is it in the list already?
            if(index >= 0)
            {
                llSay(0,"Sorry " + name + ", but your add request is still pending.");
            }
            else
            {
                AddToGroup = (AddToGroup = "") + AddToGroup + name + "\n";
                llSay(0,"Thank you " + name + ", your request has been noted.");
                ++ListLength;
                
                if(ListLength >= MaxListLength)
                {
                    llSetTimerEvent(0.);
                    state Email;
                }
            }
        }
    }
    
    timer()
    {
        // Auto timer 
        llSetTimerEvent(0.);
        state Email;
    }
}
//
// Email State
//
state Email
{
    state_entry()
    {
        llSetText("Updating System. Please wait.",<1.,0.,0.>,1.);
        if(ListLength > 0) llEmail(EmailAddress,"Add to " + GroupName,AddToGroup);
        state default;
    }
}