vector

Trying to pass a vector variable from one object to another thru RezObject but cant seem to pass anything but a integer can someone help.

Simple. You can't pass anything BUT an integer.

So, how do you get around this? Well, you can either devise some system to encode the vector into an integer and pass it, or you can use the integer to specify a channel for the receiving object to listen to, and pass the vector on as a string.

I'm not sure if this would work, but I would certainly try it before opening an on_rez listen:

Convert the vector to an integer like so:

vector vec = <1,2,3>;

string str = (string) vec;
str = "" + (string) llGetSubString(str,1,1) + "" + (string) llGetSubString(str,3,3) + "" + (string) llGetSubString(str,5,5) + ""; //this makes it 123
integer int = (integer) str;
llRezObject("something", llGetPos() + <0, 0, 2>, ZERO_VECTOR, ZERO_ROTATION, int);

This sends the integer as the objects start_params, which can be gotten by llGetStartParams();
Then use a reverse method like so:

integer xcoord = (integer) llGetSubString((string) llGetStartParams(),0,0);
integer ycoord = (integer) llGetSubString((string) llGetStartParams(),1,1);
integer zcoord = (integer) llGetSubString((string) llGetStartParams(),2,2);
vector vec = (xcoord,ycoord,zcoord);

Not sure if this will work but its worth a try. Just gotta think outside the box sometimes, especially to avoid listens or other lag causing functions

Actually, Doug, that's somethign I've considered. main problem is, it won't work for all possible vectors.

You're quite right Aliasi, it won't work for all vectors, in fact it's pretty much impossible to do for all vectors.

But you could do something with coding to give you 3 sig figs on any vector with a bit of thought which is less than perfect for positions say, but probably close enough for any other application.

True enough!

integer pack_vector(vector v) {
    return ((integer)v.x & 0x00FF) << 24
         | ((integer)v.y & 0x00FF) << 16
         | ((integer)v.z & 0xFFFF);
}

vector unpack_vector(integer pv) {
    return <(pv >> 24) & 0x00FF,
            (pv >> 16) & 0x00FF,
            (pv        & 0xFFFF)  // syntax error if not ()'d
    >;
}

default {
    state_entry() {
        vector v = <255, 1, 12345>;
        llOwnerSay( (string)pack_vector(v) );
        llOwnerSay( (string)unpack_vector(pack_vector(v)) );
    }
}

This gives you 0-255 x, 0-255 y, and 0-65535 z, which is perfect for sim coordinates if you don't need fractional portions.

Another trick you could do is to rez the object with it's up (or any) axis pointing towards the vector you want, and use the integer parameter as a distance, then just multiply llRot2Up(llGetRot()) * param. You can multiply/divide it by 10s to get decimal precision. I might put together an example later.

hrmm yes.. all these things are good.. yes but why bother?


In object being rezzed:

vector new_vector;
integer on_rez_listening;

default
{
    on_rez(integer p)
    {
        // Only start the listen if it's actually needed.
        if(p) on_rez_listening = llListen(123,"","","");
    }

    listen(integer c, string n, key i, string m)
    {
        if(c == 123) // make sure it's being sent on that channel
        {
            // Remove the on_rez listen because it's not needed anymore.
            llListenRemove(on_rez_listening);
            new_vector = (vector)m;
        }
    }
}

Do anything else you want, even do normal listens, just don't use the same channel as you are using for the on_rez listen.

The llRezObject script would be something like:

vector a_vector = <12.352,143.943,86.076>;
default
{
    touch_start(integer num)
    {
        // Note that the final parameter is not 0
        llRezObject("Object Name",llGetPos(),ZERO_VECTOR,ZERO_ROTATION,1);
    }

    object_rez(key id)
    {
        llSay(123,(string)a_vector);
    }
}

You still going to need a script in both objects anyway, don't see why everything needs to be all complicated, especially when you can't rez further than 10m from the object doing the rezzing. If you were able to spawn/rez objects in other sims and so on, I could see a point to sending variant data through the integer param.

I'm not 100% sure, but I suspect if you remove the listen *before* processing the message you lose the message content. Certainly for sensors if you remove them you destroy all the llDetected* content.

But yes, you're right it is almost certainly more elegant to do it the listen way, but we were specifically asked for ways to pass a vector in the integer of the llRezObject() function.

Reasons for doing it that way who knows. Actually your code could be made safer for multi rez objects too. You use p as the listen channel. IIRC any non-zero integer evaluates as true.

Yah you can remove the listen immediately.

integer listening;

default
{
    state_entry()
    {
        llDialog(llGetOwner(),"Setup Menu",["Reset"],111);
        listening = llListen(111,"",llGetOwner(),"");
        llSensorRepeat("","", AGENT, 8, TWO_PI, 5.0);
    }

    listen(integer channel, string name, key id, string message)
    {
        llListenRemove(listening);
        // all function declared variables still hold their values
        if(message == "Reset") llResetScript();
    }

    sensor(integer num_detected)
    {
        llSensorRemove();
        // all function declared variables still hold their values
        llSay(0, "There were " + (string)num_detected + " people sensed.");

        // llDetectedKey, llDetectedname etc no longer work as they are not really
        // passed to this function.
        llSay(0, llDetectedName(0)); // returns NULL string for the message
    }
}

That at least is my understand of how the system works. I could be wrong of course.

And yes, any non-zero value is fine, although I think it must be a positive value but ofcourse you could simply change it to: if(p != 0) or whatever you needed. I wouldn't call using a listen event that is immediately removed once the information is received, "elegant".. just easier to comprehend.