Looking for a simple texture changer

I am looking for a simple script to switch two textures back and forth. I dont want anything with a menu just a rez and go. I dont want to have to touch it to make it switch either. I cannot find one in the search that is as simple as I need. Any help is appreciated.

You don't want it to be touch operated so exactly how are you expecting it to know when to switch textures? A timer? Linkmessage?

I don't say another solution but a timer. Let's try to be as concise and simple as possible...

Create a box, put 2 textures in its inventory and this script:
----------------------------------------------------------------
list Textures;
integer Switch = TRUE;

default
{
state_entry()
{
Textures = [llGetInventoryName(INVENTORY_TEXTURE, 0), llGetInventoryName(INVENTORY_TEXTURE, 1)];
llSetTimerEvent(1.0);
}

timer()
{
llSetTexture(llList2String(Textures, Switch), ALL_SIDES);
Switch = !Switch;
}
}
----------------------------------------------------------------

If you prefer to use the keys of the textures, just change the way the list of textures is built:

Textures = ["key-of-1st-texture", "key-of-2nd-texture"];

I can't do less or shorter...

One detail: Give the time to the textures to rez. I don't want to see you coming back and telling me that the box just became all grey. (Grumble, grumble)

Talon I could use a video script ,but I'd have to tell it to play then tell it to loop. I just wanted a one touch to turn it on or no touch and have it switch.

Kaluura Thank You. I'll give that one a shot. I wouldnt come back and tell you the box only goes gray. I like you too much for that to ruin our friendship.

Thank you very much, Kaluura. I had been searching for exactly something like this for a dance floor. You've definitely made my day!

If I wanted to add a third texture or more, how would this be done?

Ok, I found a solution from LSL Wiki in their scripts library. If anybody needs it, check here:

http://lslwiki.net/lslwiki/wakka.php?wakka=LibraryTextureSwitcher

This should work with any number of textures in the object's inventory, with no need to reset the script if you add/delete textures.
~Boss

integer texture_index = -1; 

default
{
    state_entry()
    {
        llSetTimerEvent(3.0);
    }
    
    timer()
    {
        integer count = llGetInventoryNumber(INVENTORY_TEXTURE);
        if (count > 0)
        {
            texture_index = (texture_index + 1) % count;
            string texture_name = llGetInventoryName(INVENTORY_TEXTURE, texture_index);
            if (texture_name)
                llSetTexture(texture_name, ALL_SIDES); // apply texture
        }
    }
}

hello We run a club and do events and sometimes take pictures of our VIP and add to this picture changer script is there a way we can add a floating text or someting simular to the script for each picture say like pic one taken at furrys event pic 2 taken at coffee event ?
thanks

This can certainly be done by using llSetText() in the script when the texture changes in the for loop. However, in order to get the text, you're going to have to add a notecard reader into the script. Have a look at the dataserver event here .

If you don't want to use a notecard you could just rename the textures to the text you
want to display and use the texture name for your floating text.

Boss's script amended to do this.

integer texture_index = -1; 

default
{
    state_entry()
    {
        llSetTimerEvent(3.0);
    }
    
    timer()
    {
        integer count = llGetInventoryNumber(INVENTORY_TEXTURE);
        if (count > 0)
        {
            texture_index = (texture_index + 1) % count;
            string texture_name = llGetInventoryName(INVENTORY_TEXTURE, texture_index);
            if (texture_name)
           {
                llSetTexture(texture_name, ALL_SIDES); // apply texture
               llSetText(texture_name, <1.0, 1.0, 1.0>, 1.0);
           }
        }
    }
}