Light on/off scripts?

I've been looking around forever and I can't find anything along the lines of a chat-activated light script. I'm sure it can't be as hard as I'm making it. Does anyone know where I could find one or have one made?

default
{
          state_entry()
           {
                    llListen(0, "", "", ""); //Listen for messages on channel 0 (Local chat)
            }
            listen(integer channel, string name, key id, string message)
            {
                    if(llToLower(message)=="light on") //If heard message is 'light on', then
                    {
                              llSetPrimitiveParams([PRIM_POINT_LIGHT, TRUE, <1, 1, 1>, 1.0, 10.0, 0.75]); //Cause prim to emit white light, with a intensity of 1, radius of 10m, and a falloff of .75 meters.
                     }
                     else if(llToLower(message)=="light off") //Else, if heard message is 'light off', then
                     {
                               llSetPrimitiveParams([PRIM_POINT_LIGHT, FALSE, <1, 1, 1>, 1.0, 10.0, 0.75]); //Cause prim to stop/not emit light.
                      }
               }
}

There ya go... should work, I think, but not in world to test it. Commented as to what each function (Basically) does. It may not be the best script for the use, but it should work as you said. Just a basic script for a chat controlled light-source (For the specific prim, not all prims in the object). 'Light on' (Not case sensitive) will turn it on, and 'Light off' will turn it off.

You can streamline things a bit by using a single keyword as a toggle to turn the light on or off. By filtering the listen, it will also reduce some demand on the sim.

integer light;
default
{
state_entry()
{
llListen(0,"",NULL_KEY,"clap"); // or whatever keyword you like best
light = 0;
}
listen (integer channel, string name, key id, string message)
{
if (light == FALSE)
{
llSetPrimitiveParams([PRIM_POINT_LIGHT, TRUE, <1, 1, 1>, 1.0, 10.0, 0.75]); //Cause prim to emit white light, with a intensity of 1, radius of 10m, and a falloff of .75 meters.
light = 1;
}
else
{
llSetPrimitiveParams([PRIM_POINT_LIGHT, FALSE, <1, 1, 1>, 1.0, 10.0, 0.75]); //Cause prim to stop/not emit light.
light = 0;
}
}
}

I think that ought to work. Unlike Keira's example, the chat message ("clap" in this case) is case-sensitive.

slightly optimized single message version

integer gBooLit;

default{
  state_entry(){
     //-- pick a channel you like
    llListen( 42, "", "", "" );
  }

  listen( integer vIntNull, string vStrNull, key vKeySpeaker, string vStrHeard ){
     //-- only responds to owner
    if (llGetOwner() == vKeySpeaker){
       //-- only responds to the word "clap", capitalization, leading/trailing spaces don't matter
      if ("clap" == llToLower( llStringTrim( vStringHeard, STRING_TRIM ) )){
         //-- reverse the lit/dark state
        gBooLit = !gBooLit;
        llSetPrimitiveParams( [PRIM_POINT_LIGHT, gBooLit, <1, 1, 1>, 1.0, 10.0, 0.75,
                              PRIM_FULBRIGHT, ALL_SIDES, gBooLit ] );
         //-- added full bright for clients not rendering local lights.
      }
    }
  }
}

You can also use llGetSunDirection() to toggle lights on/off automatically. A couple of things I sell use that technique.

However, doesn't this only detect the 'natural' location of the sun? That is, if you change the time with the World menu, then it won't notice at all, since that's a viewer-side effect while the on/off is server side.

So, if you never change the environment settings, and aren't selling/giving away the scripted item, this would be fine, but if you ever change the sun position, or are going to be selling/giving away the item, it's not nearly ideal. Touch or chat, or even timers, in some situations, would usually be preferred, I'd think.

Valid points for sure, both are in demand, and yes, llGetSunDirection() detects the position that the server is seeing and does not, (and cannot) detect any forced settings in a client. However, there's cases where automatic lights are desired as well. For example, I sell a copy version of a street lamp that many-a-sim builders have bought from me so they can line the streets with street lamps that work like real ones, and I also have some outdoor lighting, and an ambient sound generator that generates random bird sounds by day, and crickets by night which sell well being automatic.

I definitely understand that... I just wish there was a function that could detect client settings, even though I know it's not likely to come around.

Would be sooo much better XD (I very rarely use the default environment settings, so it's rather odd to see things on at the wrong time)

I don't see that happening, it'd increase either server processing, bandwidth use, or both and require an new mode of script processing, all for something that would end up being a client side effect. (not that it wouldn't be cool, it would)