Welcome to the Second Life Forums Archive

These forums are CLOSED. Please visit the new forums HERE

Anyway to set something physics with more than 30 prim?
Mobius Hashimoto
Registered User
Join date: 18 Aug 2006
Posts: 146
09-29-2006 04:38
i forgot if it was 30 or 32, but i have 51, is there anyway to make my car physical?

thanks for the help
Mobius
Ashrilyn Hayashida
Registered User
Join date: 6 Jul 2006
Posts: 103
09-30-2006 19:39
The only suggestion I can think of would be to have most of the extra prims as a wearable attachment that fits in with the physical vehicle when seated.

I think the limit is, practically, 31. (Though technically 32. Each rider counts as one, so 31 prims + the driver = 32)
LaZy Hulka
Registered User
Join date: 11 Apr 2006
Posts: 32
09-30-2006 19:58
NonPhy movement v3

This works for more prims the 32. Works up too 254 prims that how many prims you can have link up. So that is the number you can use. Just follow the notes in the script to learn how to use them

First script name it: Main script
CODE

// Non-Physical Flying Vehicle
// A.K.A: How to exploit tricks in LSL to get your way
//
// (your way being: up to 254 prims on a vehicle, in this case)
// Author: Jesrad Seraph
// Modify and redistribute freely, as long as your permit free modification and redistribution

integer hidden_face = 5;

float max_fwd = 2.0;        // max speed in m per quarter of a second
integer max_rot = 4;        // max turning speed in degrees per quarter of a second
float hover_height = 0.25;    // prefered minimum height above ground

integer down;
integer change;

float fwd_accel = 0.015625;    // forward/back acceleration
float up_accel = 0.015625;    // vertical acceleration
float left_accel = 0.015625;    // strafing acceleration
float rot_accel = 0.03125;    // turning acceleration

float inertia = 0.75;        // movement slowdown rate
float moment = 0.5;        // turning slowdown rate


// internal stuff, don't modify
vector velocity;
float rotacity;
vector veloff = <0.5, 0.5, 0.5>;
integer timeout;

integer controls;
key pilot;

stop()
{
    vector aim;
    llReleaseControls();
    llResetOtherScript("turn");
    llResetOtherScript("turn 1");
    llResetOtherScript("turn 2");
    llResetOtherScript("turn 3");
    llResetOtherScript("rota");
    llResetOtherScript("rota 1");
    llResetOtherScript("rota 2");
    llResetOtherScript("rota 3");
    llResetOtherScript("move");
    llResetOtherScript("move 1");
    llResetOtherScript("move 2");
    llResetOtherScript("move 3");
    timeout = 0;
    llSetTimerEvent(0.0);
    pilot = NULL_KEY;
    velocity = ZERO_VECTOR;
    rotacity = 0.0;
    llSetColor(velocity + veloff, hidden_face);
    llSetAlpha(rotacity + 0.5, hidden_face);
    aim = llRot2Euler(llGetRot());
    aim.x = 0.0;
    aim.y = 0.0;
    llSetRot(llEuler2Rot(aim));
}

default
{
    state_entry()
    {
        controls = CONTROL_FWD|CONTROL_BACK|CONTROL_UP|CONTROL_DOWN|CONTROL_LEFT|CONTROL_RIGHT|CONTROL_ROT_LEFT|CONTROL_ROT_RIGHT;
        stop();
        llSitTarget(<0.25, 0.0, 0.4>, ZERO_ROTATION);
        llSetCameraAtOffset(<1.0, 0.0, 0.0>);
        llSetCameraEyeOffset(<-3.0, 0.0, 0.0>);
    }

    on_rez(integer param)
    {
        llResetScript();
    }

    touch_start(integer c)
    {
        if (llDetectedKey(0) != llGetOwner()) return;
        if (pilot == llGetOwner())
        {
            stop();
        } else
        {
            llRequestPermissions(llGetOwner(), PERMISSION_TAKE_CONTROLS);
        }
    }
    
    run_time_permissions(integer p)
    {
        if (p & PERMISSION_TAKE_CONTROLS)
        {
            llResetOtherScript("turn");
            llResetOtherScript("turn1");
            llResetOtherScript("turn2");
            llResetOtherScript("turn3");
            pilot = llGetPermissionsKey();
            llTakeControls(controls, TRUE, FALSE);
            velocity = ZERO_VECTOR;
            rotacity = 0.0;
            llSetColor(velocity + veloff, hidden_face);
            llSetAlpha(rotacity + 0.5, hidden_face);
            llMessageLinked(LINK_THIS, 0, "piloted", pilot);
        } else if (llGetPermissions() & PERMISSION_TAKE_CONTROLS == FALSE)
        {
            stop();
        }
    }

    control(key id, integer level, integer edge)
    {
        down = level;
        change = edge;
        
        if (down & controls)
        {
            if (timeout == 0)
            {
                llMessageLinked(LINK_THIS, max_rot, "nonphy", (key)((string)max_fwd));
                llSetTimerEvent(0.05);
            }
            timeout = 12;
        }
    }
    
    timer()
    {
        if (--timeout == 0)
        {
            llResetOtherScript("move");
            llResetOtherScript("move1");
            llResetOtherScript("move2");
            llResetOtherScript("move3");
            llResetOtherScript("rota");
            llResetOtherScript("rota1");
            llResetOtherScript("rota2");
            llResetOtherScript("rota3");
            llSetTimerEvent(0.0);
            return;
        }

        if (down & CONTROL_FWD)
        {
            if (velocity.x < 0.0) velocity.x = 0.0;
            velocity.x += fwd_accel;
            if (velocity.x > 0.5 ) velocity.x = 0.5;
        } else if (down & CONTROL_BACK)
        {
            if (velocity.x > 0.0) velocity.x = 0.0;
            velocity.x -= fwd_accel;
            if (velocity.x < -0.5 ) velocity.x = -0.5;
        } else {
            velocity.x *= inertia;
        }
        
        if (down & CONTROL_UP)
        {
            if (velocity.z < 0.0) velocity.z = 0.0;
            velocity.z += up_accel;
            if (velocity.z > 0.5 ) velocity.z = 0.5;
        } else if (down & CONTROL_DOWN)
        {
            if (velocity.z > 0.0) velocity.z = 0.0;
            velocity.z -= up_accel;
            if (velocity.z < -0.5 ) velocity.z = -0.5;
            if (llGetPos() * <0,0,1> < llGround(ZERO_VECTOR) + max_fwd * velocity.z + hover_height)
                velocity.z = 0.0;
        } else {
            velocity.z *= inertia;
            if (llGetPos() * <0,0,1> < llGround(ZERO_VECTOR) + max_fwd * velocity.z + hover_height)
                velocity.z = 0.0;
        }
        
        if (down & CONTROL_LEFT)
        {
            if (velocity.y < 0.0) velocity.y = 0.0;
            velocity.y += left_accel;
            if (velocity.y > 0.5 ) velocity.y = 0.5;
        } else if (down & CONTROL_RIGHT)
        {
            if (velocity.y > 0.0) velocity.y = 0.0;
            velocity.y -= left_accel;
            if (velocity.y < -0.5 ) velocity.y = -0.5;
        } else {
            velocity.y *= inertia;
        }
        
        if (down & CONTROL_ROT_LEFT)
        {
            if (rotacity < 0.0) rotacity = 0.0;
            rotacity += rot_accel;
            if (rotacity > 0.5 ) rotacity = 0.5;
        } else if (down & CONTROL_ROT_RIGHT)
        {
            if (rotacity > 0.0) rotacity = 0.0;
            rotacity -= rot_accel;
            if (rotacity < -0.5 ) rotacity = -0.5;
        } else {
            rotacity *= moment;
        }

        llSetColor(velocity * llGetRot() + veloff, hidden_face);
        llSetAlpha(rotacity + 0.5, hidden_face);
    }
}



Second Script name it: turn
CODE

//Turn script, copy 4 times (call them turn, turn1, turn2 and turn3).
default
{
    link_message(integer part, integer code, string msg, key id)
    {
        if (msg == "piloted")
        {
            if (id != "")
            {
                llRequestPermissions(id, PERMISSION_TRACK_CAMERA);
            }
        }
    }

    run_time_permissions(integer p)
    {
        if (p & PERMISSION_TRACK_CAMERA)
        {
            vector aim;
            rotation ro;
            key id = llGetPermissionsKey();
            vector cor = ZERO_VECTOR;
            llSleep(0.05 * (integer)llGetSubString(llGetScriptName(), -1, -1));
            while(TRUE)
            {
                if (llGetAgentInfo(id) & AGENT_MOUSELOOK)
                {
                    aim = llRot2Fwd(llGetCameraRot());
                    cor = aim;
                    aim.z = 0.0;
                    ro = llRotBetween(<1, 0, 0>, aim) * llRotBetween(aim, cor);
                    llSetRot(ro);
                } else llSleep(0.2);
            }
        }
    }
}



Third script name it: rota
CODE

//Rota script, copy 4 times (call them rota, rota1, rota2 and rota3).
integer hidden_face = 5;
float max_vel;

default
{
    link_message(integer part, integer code, string msg, key id)
    {
        if (msg != "nonphy") return;
        max_vel = (float)code * DEG_TO_RAD;
        llSleep(0.05 * (integer)llGetSubString(llGetScriptName(), -1, -1));
        while(TRUE)
        {
            llSetRot(llGetRot() * llEuler2Rot(<0,0,max_vel * (llGetAlpha(hidden_face) - 0.5)>) );
            llSetRot(llGetRot() * llEuler2Rot(<0,0,max_vel * (llGetAlpha(hidden_face) - 0.5)>) );
            llSetRot(llGetRot() * llEuler2Rot(<0,0,max_vel * (llGetAlpha(hidden_face) - 0.5)>) );
            llSetRot(llGetRot() * llEuler2Rot(<0,0,max_vel * (llGetAlpha(hidden_face) - 0.5)>) );
            llSetRot(llGetRot() * llEuler2Rot(<0,0,max_vel * (llGetAlpha(hidden_face) - 0.5)>) );
        }
    }
}


fourth script name it: move
CODE

//Move script, copy 4 times (call them move, move1, move2 and move3).
integer hidden_face = 5;

float max_vel;
vector veloff = <-0.5, -0.5, -0.5>;

default
{
    link_message(integer part, integer code, string msg, key id)
    {
        if (msg != "nonphy") return;
        max_vel = (float)((string)id);
        llSleep(0.05 * (integer)llGetSubString(llGetScriptName(), -1, -1));

        while(TRUE)
        {
            llSetPos(max_vel * (llGetColor(hidden_face) + veloff) + llGetPos());
            llSetPos(max_vel * (llGetColor(hidden_face) + veloff) + llGetPos());
            llSetPos(max_vel * (llGetColor(hidden_face) + veloff) + llGetPos());
            llSetPos(max_vel * (llGetColor(hidden_face) + veloff) + llGetPos());
            llSetPos(max_vel * (llGetColor(hidden_face) + veloff) + llGetPos());
        }
    }
}
_____________________
USMC Time to kick ass and take names later. Show No Mercy
Hector Greenspan
Registered User
Join date: 20 Apr 2006
Posts: 6
10-02-2006 03:56
I've just been experimenting with a system which theoretically allows an unlimited number of prims, although anything over 200 probably wouldn't be practical.

The system relies on you splitting your vehicle into multiple vehicles; one main 'chassis' where you will be seated, and others making up the other detail. There is a script which communicates the movement information to the other child vehicles.

The system is not perfect by any means, but it seems to work fairly convincingly on a lag-free sim. I'm having a few minor problems when changing direction (the vehicle tends to split momentarily) but I'm convinced this is something I can work around.

Another unfortunate side-effect is the gap between the main vehicle and the child vehicles. For a physical object to operate without going crazy and detecting loads of collisions, there has to be a gap of around 0.030m. This might not sound much, but depending on how your vehicle is built it can be quite noticable. I've found the best way of combatting this is to use prims to cover over the gaps. You can work this into the vehicle design.

I'm not releasing this to the public quite yet, as it's far from finished, but if you're interested in helping me test this system, please contact me in-game.
Kale Kawabata
Registered User
Join date: 18 Sep 2005
Posts: 41
Train
10-02-2006 06:25
From: Hector Greenspan
I've just been experimenting with a system which theoretically allows an unlimited number of prims, although anything over 200 probably wouldn't be practical.

The system relies on you splitting your vehicle into multiple vehicles; one main 'chassis' where you will be seated, and others making up the other detail. There is a script which communicates the movement information to the other child vehicles.


Hmm, sounds to me like a very realistic train could be possible... :)
_____________________
Kale Kawabata =P
ScriptScavenger Lei
Registered User
Join date: 3 Sep 2006
Posts: 14
bad ideas gone horibly wrong
10-02-2006 20:11
ok just because we can doesnt mean we should
there seams to be a "buffer" between sims and its more of an over all size than a number of prims issue, but if its to big in any one direction it tends to explode and u dont always get all the pieces back
if i remember correctly its a 10m limit
but i suppose if your using the prims for detail vs size your in the clear,
just out of curiosity using a vehicle script for a 4 passanger vehicle would limit the size to 28 then ?
Mobius Hashimoto
Registered User
Join date: 18 Aug 2006
Posts: 146
10-02-2006 20:19
thanks everyone, very appreciated, specially lazy:)
_____________________
Project Mobius - Web/Graphic Design and Tech Reviews

Please check out my items @

Blog about games, gadgets & technologies @
Tiarnalalon Sismondi
Registered User
Join date: 1 Jun 2006
Posts: 402
10-03-2006 09:29
From: ScriptScavenger Lei
just out of curiosity using a vehicle script for a 4 passanger vehicle would limit the size to 28 then ?



27 actually for 4 people. Total # for a physical object is 31. Each avatar to allow to sit is 1 prim. So a 1 seat vehicle would only be 30 prim, 2 would be 29, etc.

Now a thing to note is that you could have 27 prims and technically get 5 or more people sitting on it and the vehicle would operate fine....the problem being that physics would have to already be turned on, and if they got turned off for any reason, they would not be able to turn on again until the extra people got off.
Joannah Cramer
Registered User
Join date: 12 Apr 2006
Posts: 1,539
10-03-2006 09:37
From: Hector Greenspan
I've just been experimenting with a system which theoretically allows an unlimited number of prims, although anything over 200 probably wouldn't be practical.

The system relies on you splitting your vehicle into multiple vehicles; one main 'chassis' where you will be seated, and others making up the other detail. There is a script which communicates the movement information to the other child vehicles.

It sounds like Jesrad Seraph's Multimove script.

/54/7c/94178/1.html

(the script posted by Lazy is slightly different. Allows non-physical movement of a large single linkset. The multimove allows multiple parts to move as one, which in theory allows the 'core' part of object be physical, and the other parts to match its movement to create illusion of single object)