Email Timestamp to human time

list MONTHS = [ 31, 28, 31, 30, 31, 30, 31, 31, 30, 31, 30, 31 ];

// Assumes we are in the 1970 to 2099 year range, since it doesn't account for
// leap years on the century (but note that 2000 is fine since it is divisible
// by 400.
//
// Returns: [ YYYY MM DD hh mm ss ] (all elements integers)
list unixToDateTime(integer unixTime)
{
   integer time = unixTime%86400;
   integer hour = time/3600;
   integer min = (time%3600)/60;
   integer sec = time%60;

   integer day = unixTime/86400;

   integer year = 1970+4*(day/1461);
   day %= 1461;

   if (day == 789)
   {
      // Leap day!
      return [ (year+2), 2, 29, hour, min, sec ];
   } else if (day > 789)
   {
      day -= 1;
   }

   year += day/365;
   day %= 365;

   integer month;
   for (month = 1; month <= 12; ++month)
   {
      integer monthDays = llList2Integer(MONTHS, month-1);
      if (day < monthDays)
      {
         return [ year, month, (day+1), hour, min, sec ];
      }
      day -= monthDays;
   }

   // Should never get here
   return [];
}

// Test harness
default
{
   state_entry()
   {
      integer now = llGetUnixTime();
      string timestamp = llGetTimestamp();

      string result = llList2CSV(unixToDateTime(now));

      llOwnerSay("Timestamp: "+timestamp);
      llOwnerSay("Result:    "+result);
   }
}