How to scipt a menu sustem for an unknow quantity.

On several occasions I have needed to script a menu system without knowing the total number of items that might need to be included. Because I have never figured it out, I have had to settle with one that has a predetermined maximum and then script to cover all the possibilities been less than 12 to that maximum. All of my attempts to do avoid limiting the possible number have died in a convoluted mess, but I keep trying because I continue to believe it can be done with the right set of nifty code trick.

Its actually relatively simple.
The list that you display is limited to 12 but this can be a subset of the total list.
Just keep track of where you are in the list (i.e. first entry to display) and rebuild the list each time.

Unless I am missing something, the problem with that approach is the insertion on (next) and (back) option in the appropriate places in sublists.

Yes, you need to display up to 10 (or less) items from the list at a time, and then figure out if you need a next, prev, or both buttons. And you do that by checking to see if you're at either end of the main list or not. And then if the user hits prev or next, you move up or down in the main list.

So... don't try to insert next and prev buttons in the main list. Figure out which entries from the main list you need to currently display (depends on where you are, how many items you're displaying per screen, etc), generate that sub-list, then independently figure out if you need a next, a prev, or both buttons.

Yep...it's a very simple script really...either run 11 buttons with a "More..." or 10 buttons with a "<<Back" and "Forward>>" type button tacked on to the last.

All you need is a counter to see how many times someone has clicked a "more" button so that you can pull from your button list starting from the appropriate place. After pulling from the list, increase your counter (or, if it exceeds your list-length, set zero).

As Ziggy said, its not a problem since you dont touch the main list at all.

I've left out the populating of the list and not bothered filtering items of greater than 24 characters.

list Items; // List of Menu Items
integer CHANNEL = 0;
integer Listening = 0; 

integer first;                 // First entry to be displayed on Dialog 
integer pagesize = 10;  // Number of Items per Dialog 
// -------------------------- 
UpdateListen(key id) 
{ 
    CancelListen(); 
    CHANNEL = 0 - (integer)llFrand(2147483647);
    Listening = llListen(CHANNEL,"",id,""); 
    llSetTimerEvent(20); 
} 
// -------------------------- 
CancelListen() 
{ 
    if(Listening > 0) llListenRemove(Listening); 
    Listening = 0; 
    llSetTimerEvent(0); 
} 
// -------------------------- 
ShowMenu(key id) 
{ 
    string title = "What would you like to do?";
    list Choices = [ ]; 

    integer i;
    integer max = llGetListLength( Items ); 
    if(first > 0) 
        Choices += "Prev"; 
    if(max > (first + pagesize)) 
    { 
        Choices += "Next"; 
    } 
      
    for(i = 0;i < pagesize;i++) 
    { 
        integer j = (i + first);
        string name = llList2String(Items,j); 
        if( llStringLength(name) > 0) 
        { 
             Choices += [ name  ]; 
        } 
    } 
   // finally show the dialog 
    UpdateListen(id); 
    llDialog(id, title, Choices, CHANNEL); 
} 
 // -------------------------- 
default 
{  
    state_entry() 
    { 
    } 

    
    touch_start(integer total_number)
    {
        key id = llDetectedKey(0);
        first = 0; 
        ShowMenu(id);
    }
   
    listen(integer channel, string name, key id, string message) 
    { 
        CancelListen(); 
        // verify dialog choice 
        // present main menu on request to go back                   
        if("Prev" == message) 
        { 
            first -= pagesize; 
            ShowMenu(id); 
        } 
        else if("Next" == message) 
        { 
            first += pagesize; 
            ShowMenu(id); 
        } 
        else
        {
            integer index = llListFindList(Items, [message]); 
            if(index >= 0) 
            { 
                string text = llList2String(Items,index); 
            } 
        }
     }

    timer() 
    { 
        CancelListen(); 
    } 
    
}

Your comments have helped me think this through. Thanks to Ziggy, Kenn, and especially Newgate who when beyond the call of duty by providing and example script. Time after time one or more of you have saved my ____.

Mod