Problem with touch start event

I'm not sure if I'm running into key bounce or what, but for reasons unknown, every time I click on the object holding the script, I end up looking at slide4. The first time I click on it, Slide has a starting value of one, which means it should be incrementing to 2 so as to show me slide2. Instead it goes straight to slide4. Anybody have clues as to why?




touch_start(integer total_number)
{
llSetTimerEvent(10.0);
TimeCheck = 1;
Slide = Slide + 1;
if (Slide = 5) {Slide = 1;}
if (Slide = 1) { llSetTexture("slide1", 1);}
if (Slide = 2) { llSetTexture("slide2", 1);}
if (Slide = 3) { llSetTexture("slide3", 1);}
if (Slide = 4) { llSetTexture("slide4", 1);}
llMinEventDelay(20.0);
}

integer Slide = 1;
integer ON = TRUE;

default{
	touch_start(integer total_number){
		if(ON){
			llSetTimerEvent(10.0);
			ON = FALSE;
		}
		else{
			llSetTimerEvent(0.0);
			ON = TRUE;
		}
	}
	timer(){
		if (Slide == 1){
			llSetTexture("slide1", 1);
		}
		else if (Slide == 2){
			llSetTexture("slide2", 1);
		}
		else if (Slide == 3){
			llSetTexture("slide3", 1);
		}
		else if (Slide == 4){
			llSetTexture("slide4", 1);
			Slide = 0;
		}
		Slide ++;
	}
}

If you look in the wiki at "timer" then you will also see how to make it so that it shows the texture immediately instead of having to wait the 10 seconds the 1st time.

integer Slide = 1;
integer ON = TRUE;


neTimed()
{
	if (Slide == 1){
		llSetTexture("slide1", 1);
	}
	else if (Slide == 2){
		llSetTexture("slide2", 1);
	}
	else if (Slide == 3){
		llSetTexture("slide3", 1);
	}
	else if (Slide == 4){
		llSetTexture("slide4", 1);
		Slide = 0;
	}
	Slide ++;
}

default{
	touch_start(integer total_number){
		if(ON){
			neTimed();
			llSetTimerEvent(10.0);
			ON = FALSE;
		}
		else{
			llSetTimerEvent(0.0);
			ON = TRUE;
		}
	}
	timer(){
		neTimed();
	}
}

I am not very verbose tonight, rough day today. Ask if there is anything you don't understand here or want clarification on.

http://www.cheesefactory.us/lslwm/timer.htm

There is also a more elegant way to do it. Have it build a list of all textures in inventory in the state entry. Then just use Slide as the integer for the place in the list where the texture is to display.

EDIT; COOL!!!!! Just now noticed this was your very 1st post!!! Welcome to the scripting forum Coro

just so you know, your if statments weren't the problem, it was those pesky assignments in those tests....

slide = 1 //-- changes slide to 1, and so is true(not zero)
slide == 1 //-- compares slide to 1, if they are the same it's true

when doing comparisons (any test statment) it's food to get into the habit of putting the value first, and the variable second, so that logic errors like this won't compile and you'll get an error notice immediately...

1 = slide //-- will not compile, gives error
1 == slide //-- compares 1 to slide like you intended

it also makes it slightly quicker to check visually since the value you are testing for is listed first

but using if/else as jesse showed is the better in 99% of cases

and since jesse brought it up, recent post regarding texture cycling, with 2 working script versions, (mine uses the method suggested by Jesse above)

In the script, you try to test the value of Slide by doing "if( Slide = 5 )..." This is wrong. It should be "if( Slide == 5 )". There is a difference between the = operator and the == operator. The = operator SETS something equal to something else. The == operator TESTS for equality. So, what your script was doing was setting Slide to 5, then since 5 is not 0, the condition is true and Slide gets set equal to 1. Slide gets set to each value from 1 to 4 in your "if" statements and ends up showing you slide4 before doing llMinEventDelay(). In short, = does not equal ==.