Running a script while a Key is Held down

integer WASD = 0;
integer gRunning = FALSE;

default
{
	state_entry()
	{
		// This bit is just a shortcut to save time later
		// since we don't care exactly which control was pressed
		WASD = CONTROL_FWD | CONTROL_BACK | CONTROL_ROT_LEFT | CONTROL_LEFT | CONTROL_ROT_RIGHT | CONTROL_RIGHT;
		// Ask for permission to take controls
		if (llGetAttached()) {
			llRequestPermissions(llGetOwner(), PERMISSION_TAKE_CONTROLS);
		}
	}

	on_rez(integer p)
	{
		llResetScript();
	}

	run_time_permissions(integer perms)
	{
		if (perms & PERMISSION_TAKE_CONTROLS) {
			// We have permission, so take controls
			// but let them also act normally to move the av
			llTakeControls(WASD, TRUE, TRUE);
		}
	}

	control(key id, integer level, integer edge)
	{
		// This event will fire whenever we have taken controls
		// and the owner presses or releases WASD
		if (level & edge & WASD && !gRunning) {
			// Started pressing a control, effect not running
			llSay(0, "Particle effect starting");
			gRunning = TRUE;
		}
		else if (~level & edge & WASD && gRunning) {
			// Stopped pressing controls, effect running
			llSay(0, "Particle effect stopping");
			gRunning = FALSE;
		}
	}
}