Welcome to the Second Life Forums Archive

These forums are CLOSED. Please visit the new forums HERE

link_message() remove possible? [llListenRemove() equivilant?]
Diego Pannotia
Laronzo Fitzgerald
Join date: 14 Nov 2006
Posts: 37
03-14-2007 04:54
Is there an equivilant to

llListenRemove();

for

link_message(); or llMessageLinked(); ?

I need to flush a thread in a state if remote_data is received

Many thanks,

Mark.
Darien Caldwell
Registered User
Join date: 12 Oct 2006
Posts: 3,127
03-14-2007 09:21
No, not that I'm aware of.
Lex Neva
wears dorky glasses
Join date: 27 Nov 2004
Posts: 1,361
03-14-2007 09:31
You could switch to a state without a link_message event handler.
Kenn Nilsson
AeonVox
Join date: 24 May 2005
Posts: 897
03-14-2007 12:03
If you need to flush a thread, why not just follow your original llMessage_Linked with another link message that "flushes"...ie..

CODE


llMessage_Linked(-1, x, "My thread here", NULL_KEY); //the original

llMessage_Linked(-1, x, "", NULL_KEY); //flushing the thread to a "" or NULL state

_____________________
--AeonVox--

Computer games don't affect kids; I mean if Pac-Man affected us as kids, we'd all be running around in darkened rooms chasing ghosts, eating magic pills, and listening to repetitive, addictive, electronic music.
Gaius Goodliffe
Dreamsmith
Join date: 15 Jan 2006
Posts: 116
03-14-2007 18:51
From: Kenn Nilsson
If you need to flush a thread, why not just follow your original llMessage_Linked with another link message that "flushes"...ie..

The flush would then not occur until the script gets through the link messages queued up before it, which defeats the point.

Lex has it right -- to turn off link_messages, switch to a state with no link_message handler. To flush the queue, do that, and in that state immediately switch back. I've used this trick before for scripts that would accumulate unwanted, stale link messages if things were laggy, to make sure it only responded to the next link message of a given type, not any that might be hanging around in the queue.
Strife Onizuka
Moonchild
Join date: 3 Mar 2004
Posts: 5,887
03-14-2007 19:57
It shouldn't matter if it has a link_message event or not (the target state i mean), the event queue is cleared on state change.
_____________________
Truth is a river that is always splitting up into arms that reunite. Islanded between the arms, the inhabitants argue for a lifetime as to which is the main river.
- Cyril Connolly

Without the political will to find common ground, the continual friction of tactic and counter tactic, only creates suspicion and hatred and vengeance, and perpetuates the cycle of violence.
- James Nachtwey
Kenn Nilsson
AeonVox
Join date: 24 May 2005
Posts: 897
03-14-2007 22:30
Gotcha. I don't think I've ever run into that issue...as I don't send link_messages on a repeated basis in most instances.
_____________________
--AeonVox--

Computer games don't affect kids; I mean if Pac-Man affected us as kids, we'd all be running around in darkened rooms chasing ghosts, eating magic pills, and listening to repetitive, addictive, electronic music.
Gaius Goodliffe
Dreamsmith
Join date: 15 Jan 2006
Posts: 116
03-15-2007 15:57
From: Strife Onizuka
It shouldn't matter if it has a link_message event or not (the target state i mean), the event queue is cleared on state change.

Correct. It only matters if what you're trying to do is turn off link messages.
Diego Pannotia
Laronzo Fitzgerald
Join date: 14 Nov 2006
Posts: 37
03-16-2007 06:39
State change would be ideal... but, I have a timer event (190 seconds) which would never get sparked if I changed state.

More importantly, if I change state when I receive new remote_data I will lose the latest link_message sparked by this remote_data

Background:

The "waiting" state which listens to remote_data calls a function which sends a linked message to LINK_THIS. The function then returns to the "waiting" state which picks up the linked message and loops it back to the function, thus the function loops continuously (it makes the object pulse at a variable speed) based on the integer sent from remote_data (outside sl) or listen (within sl).

I used a listen to do this initially, but found I couldn't have two listen events in the same state....

Mark.
Newgate Ludd
Out of Chesse Error
Join date: 8 Apr 2005
Posts: 2,103
03-16-2007 06:50
From: Diego Pannotia
State change would be ideal... but, I have a timer event (190 seconds) which would never get sparked if I changed state.

More importantly, if I change state when I receive new remote_data I will lose the latest link_message sparked by this remote_data

Background:

The "waiting" state which listens to remote_data calls a function which sends a linked message to LINK_THIS. The function then returns to the "waiting" state which picks up the linked message and loops it back to the function, thus the function loops continuously (it makes the object pulse at a variable speed) based on the integer sent from remote_data (outside sl) or listen (within sl).

I used a listen to do this initially, but found I couldn't have two listen events in the same state....

Mark.


Timer events are not cleared by state changes, so switch state to flush the queue then switch back to carry on the timer.
Diego Pannotia
Laronzo Fitzgerald
Join date: 14 Nov 2006
Posts: 37
03-16-2007 06:56
really? Even if the timer is actually kicked off within the state I am changing from?
Newgate Ludd
Out of Chesse Error
Join date: 8 Apr 2005
Posts: 2,103
03-16-2007 07:10
Yep, event if its in a different state.
Of course it requires a timer() event handler within the new state to actually do anything.

You can prove it with the following code
CODE

integer counter = 0;

default
{
    state_entry()
    {
        counter = 0;
        llOwnerSay("default state.");
    }

    touch_start(integer total_number)
    {
        llSay(0, "Touched.");
        llSetTimerEvent(1);
    }
    
    timer()
    {
        llOwnerSay("Default State : Timer running iteration " + (string)counter++);
        if(counter >= 3) state NoTimerEvent;
    }
}

state NoTimerEvent
{
    state_entry()
    {
        llOwnerSay("Switched to NoTimerEvent");
    }

    timer()
    {
        llOwnerSay("NoTimerEvent State : Timer running iteration " + (string)counter++);
        if(counter >= 6) state default;
    }
}


CODE

[7:11]  Object: Default State : Timer running iteration 0
[7:11]  Object: Default State : Timer running iteration 1
[7:11]  Object: Default State : Timer running iteration 2
[7:11]  Object: Switched to NoTimerEvent
[7:11]  Object: NoTimerEvent State : Timer running iteration 3
[7:11]  Object: NoTimerEvent State : Timer running iteration 4
[7:11]  Object: NoTimerEvent State : Timer running iteration 5
[7:11]  Object: default state.
[7:11]  Object: Default State : Timer running iteration 0
[7:11]  Object: Default State : Timer running iteration 1
[7:11]  Object: Default State : Timer running iteration 2
[7:11]  Object: Switched to NoTimerEvent
Diego Pannotia
Laronzo Fitzgerald
Join date: 14 Nov 2006
Posts: 37
03-16-2007 07:19
okay brilliant thanks! I still can't seem to flush the thread though, here is the code, I've tried calling state restart; to flush it on remote_data receipt:

The pulse function is what is looped continously and it is within this that the llMessageLinked is created.

The waiting state listens to listen, remote_data and the message_linked

state restart restarts the waiting state and it is here that I tried to flush the message_linked thread but to no avail...

Cheers, Mark.

CODE


list names = [
        "red","light red","dark orange","orange",
        "light orange", "dark yellow", "yellow","lime green",
        "pale green","green-3","green-2","green-1",
        "green","green+1","green+2","pale aqua",
        "aqua","dark aqua","cyan","dark cyan",
        "light blue","sky blue","blue-2","blue-1",
        "blue","deep blue","very deep blue","violet",
        "purple","light purple", "magenta","magenta+1",
        "magenta+2","pink","magenta+4","magenta+5",
        "white"
         ];

list rgb = [
        <1.0,0.0,0.0>,  <1.0,0.16,0.0>, <1.0,0.32,0.0>, <1.0,0.52,0.0>,
        <1.0,0.68,0.0>, <1.0,0.84,0.0>, <1.0,1.0,0.0>,  <0.84,1.0,0.0>,
        <0.68,1.0,0.0>, <0.52,1.0,0.0>, <0.32,1.0,0.0>, <0.16,1.0,0.0>,
        <0.0,1.0,0.0>,  <0.0,1.0,0.16>, <0.0,1.0,0.32>, <0.0,1.0,0.52>,
        <0.0,1.0,0.68>, <0.0,1.0,0.84>, <0.0,1.0,1.0>,  <0.0,0.84,1.0>,
        <0.0,0.68,1.0>, <0.0,0.52,1.0>, <0.0,0.32,1.0>, <0.0,0.16,1.0>,
        <0.0,0.0,1.0>,  <0.16,0.0,1.0>, <0.32,0.0,1.0>, <0.52,0.0,1.0>,
        <0.68,0.0,1.0>, <0.84,0.0,1.0>, <1.0,0.0,1.0>,  <1.0,0.0,0.84>,
        <1.0,0.0,0.68>, <1.0,0.0,0.52>, <1.0,0.0,0.32>, <1.0,0.0,0.16>,
        <1.0,1.0,1.0>
    ];

string c;
string b;
string a;

key     gChannel;

DEBUG(list out) 
{ 
    llSay(0, llList2CSV(out)); 
} 

Pulse(float anima) 
{ 
    integer i;

    list original = llGetPrimitiveParams([PRIM_POINT_LIGHT]);
    float c_lev = llList2Float(original, 2);

    float dim = c_lev / anima;
    
    for(i=0;i< anima;++i)
    {
        list original = llGetPrimitiveParams([PRIM_POINT_LIGHT]);
        float intense = llList2Float(original, 2);
        vector c_c = llList2Vector(original, 1);
        float take = intense - dim;
        
        llSetPrimitiveParams([PRIM_POINT_LIGHT, TRUE, c_c, take, 10, 0.75]);
    }   
    for(i=0;i< anima;++i)
    {
        list original = llGetPrimitiveParams([PRIM_POINT_LIGHT]);
        float intense = llList2Float(original, 2);
        vector c_c = llList2Vector(original, 1);
        float add = intense + dim;
        
        llSetPrimitiveParams([PRIM_POINT_LIGHT, TRUE, c_c, add, 10, 0.75]);
    }
    llMessageLinked(LINK_THIS, 0, (string)anima, NULL_KEY);
} 

colour(string col)
{
    integer index = llListFindList(names, [c=col]);
    if(~index)
    {
        vector color = llList2Vector(rgb, index);
        llSetPrimitiveParams([PRIM_COLOR, ALL_SIDES, color, 1, PRIM_POINT_LIGHT, TRUE, color, llList2Float(llGetPrimitiveParams([PRIM_POINT_LIGHT], 2)), 10, 0.75]);
    }
}

brightness(string level){
    
    b = level;
    
    list original = llGetPrimitiveParams([PRIM_POINT_LIGHT]);
    vector c_c = llList2Vector(original, 1);
    
    if (level == "dim"){ llSetPrimitiveParams([PRIM_POINT_LIGHT, TRUE, c_c, 0.1, 10, 0.75]); }
    if (level == "medium"){ llSetPrimitiveParams([PRIM_POINT_LIGHT, TRUE, c_c, 0.4, 10, 0.75]); }
    if (level == "bright"){ llSetPrimitiveParams([PRIM_POINT_LIGHT, TRUE, c_c, 1, 10, 0.75]); }
}

animation(string ani){
    
    a = ani;
                if (ani == "no anim"){ state restart; }
                if (ani == "very slow"){ Pulse(6); }
                if (ani == "slower"){ Pulse(5); }
                if (ani == "slow"){ Pulse(4); }
                if (ani == "pulse"){ Pulse(3); }
                if (ani == "medium"){ Pulse(2.75); }
                if (ani == "fast"){ Pulse(2.5); }
                if (ani == "faster"){ Pulse(2); }
                if (ani == "very fast"){ Pulse(1.75); }
                if (ani == "crescendo"){ Pulse(1.5); }
                if (ani == "heartbeat"){ Pulse(1);}
}

default 
{
    state_entry() 
    { 
        llOpenRemoteDataChannel();
        llSetText("C\n \nPervasive Lab Orb\n \n",<0,0,1>,1);
        llSetPrimitiveParams([PRIM_COLOR, ALL_SIDES, <0.32,1,0>, 1, PRIM_POINT_LIGHT, TRUE, <0.32,1,0>, 1, 10, 0.75]);
    }
 
    remote_data(integer type, key channel, key message_id, string sender, integer ival, string sval) 
    { 
        if (type == REMOTE_DATA_CHANNEL) 
        {
            gChannel = channel; 
         //   llSay(0, "Channel: " + (string)channel +""); 
         
            llHTTPRequest("http://xxx/publish.php?msg=" + (string)channel,[HTTP_METHOD,"GET"],"");
            
            state waiting;
        } else DEBUG(["Unexpected event type", type, channel, message_id, sender, ival, sval]); 
    } 
}

state waiting
{   
    state_entry()
    {
        llListen(-700, "", NULL_KEY, "" );
    }
    
    remote_data(integer type, key channel, key message_id, string sender, integer ival, string sval)
    { 
        if (type == REMOTE_DATA_REQUEST) 
        {
        // DEBUG(["Received", ival, sval]); 
            string stringPortionOfReply = "Default Reply"; 
            integer intPortionOfReply = 0; 
            
        llSetTimerEvent(190);
        llShout(-543,sval);

            list varlist = [];
            string col; 
            string anim; 
            string level;

            varlist = llParseStringKeepNulls(sval,[","],[]);
            
            col = llList2String(varlist,0);
            anim = llList2String(varlist,1);
            level = llList2String(varlist,2);
            
            if (col){
                if (col != c){  llShout(0,"message received from Real Life over MQTT");}     
            colour(col);  
            }

            if (level){
                if (level != b){  llShout(0,"message received from Real Life over MQTT");}     
            brightness(level);
            }
            
            if (anim){
                if (anim != a){  llShout(0,"message received from Real Life over MQTT");}     
            animation(anim);
            }
             
            state restart;
                             
            llRemoteDataReply(channel, message_id, stringPortionOfReply, intPortionOfReply); 
             
        } else DEBUG(["Unexpected event type:", type, channel, message_id, sender, ival, sval]); 
    }       

    listen(integer channel, string name, key id, string message)                             
        { 
        if (channel = -700){    
        
            llShout(-543,message);

            list varlist = [];
            string col; 
            string anim; 
            string level;

            varlist = llParseStringKeepNulls(message,[","],[]);
            
            col = llList2String(varlist,0);
            anim = llList2String(varlist,1);
            level = llList2String(varlist,2);
            
            if (col){
            colour(col);  
            llSetTimerEvent(190);
            }

            if (level){
            brightness(level);
            llSetTimerEvent(190);
            }
            
            if (anim){
            animation(anim);
            llSetTimerEvent(190);
            }
        }
    }
    
    link_message(integer sender_num, integer num, string message, key id)
    {
        Pulse((float)message);
    }

    
    timer()
    {
    llResetScript();
    }


    touch_start(integer N)
    {
    llWhisper(0,"Use the colour chart on the kitchen wall to change the setting of the Ambient Orb");
    }
}

state restart
{   
    state_entry()
    {  
        state waiting;
        llMessageLinked(LINK_THIS, 0, "", NULL_KEY); // THIS DID NOTHING
    }
}
Woopsy Dazy
Registered User
Join date: 12 Nov 2006
Posts: 173
03-16-2007 08:36
As a side note, why not use list-commands to get rid of all those if-statements?

list listcolors = ["red", "<1,0,0>", "light red", <1,0.16,0>"... a.s.o

and something like...

integer colorpos = llListFindList(listcolors, col) + 1;
vector colorcode = llList2Vector(listcolors, colorpos);

llSetPrimitiveParams([PRIM_COLOR, ALL_SIDES, colorcode, 1, PRIM_POINT_LIGHT, TRUE, colorcode, c_i, 10, 0.75]);

P.s.
Code not tested.

[EDIT]
Notice you already have list commands in code in other places. Better performance with if's?
Newgate Ludd
Out of Chesse Error
Join date: 8 Apr 2005
Posts: 2,103
03-16-2007 16:15
oh dont let Osgeld see that if tree.
As Woopys suggested, use lists the performance hit is negligible compared to the additional code space and processing required for that many if's.
Diego Pannotia
Laronzo Fitzgerald
Join date: 14 Nov 2006
Posts: 37
03-17-2007 01:53
Okay I'll go with that =P Much neater and yes faster

Side note: If I send detectedName via HTTPRequest how can I avoid receiving

"DiegoPannotia" instead of Diego Pannotia? Substring the two seperate parts of the name and place %20 inbetween? Answered my own question right... =P

llHTTPRequest("http://nakedimagination.co.uk/secondlife/publish.php?topic=slstats/Fan&msg=" + llDetectedName(0) + "&uid=slhome",[HTTP_METHOD,"GET"],"";);

That aside, any suggestions on how to get rid of that thread when I receive new remote_data or listen?
Diego Pannotia
Laronzo Fitzgerald
Join date: 14 Nov 2006
Posts: 37
03-17-2007 01:54
Okay I'll go with that =P Much neater and yes faster

Side note: If I send detectedName via HTTPRequest how can I avoid receiving

"DiegoPannotia" instead of Diego Pannotia? Substring the two seperate parts of the name and place %20 inbetween? Answered my own question right... =P

llHTTPRequest("http://xxx/publish.php?msg=" + llDetectedName(0) + ",[HTTP_METHOD,"GET"],"";);

That aside, any suggestions on how to get rid of that thread when I receive new remote_data or listen?
Diego Pannotia
Laronzo Fitzgerald
Join date: 14 Nov 2006
Posts: 37
03-17-2007 01:55
Okay I'll go with that =P Much neater and yes faster

Side note: If I send detectedName via HTTPRequest how can I avoid receiving

"DiegoPannotia" instead of Diego Pannotia? Substring the two seperate parts of the name and place %20 inbetween? Answered my own question right... =P

llHTTPRequest("http://xxx/publish.php?msg=" + llDetectedName(0),[HTTP_METHOD,"GET"],"";);

That aside, any suggestions on how to get rid of that thread when I receive new remote_data or listen?
Strife Onizuka
Moonchild
Join date: 3 Mar 2004
Posts: 5,887
03-17-2007 02:49
That implementation of colour(string col) above, is about the worst way it could be written.
This way is marginally better. The right solution is to pack the vectors into integers.
There are some nice functions for doing that on:
https://wiki.secondlife.com/wiki/Category:LSL_Color

CODE

list names = [
        "red",          "light red",    "dark orange",      "orange",
        "light orange", "dark yellow",  "yellow",           "lime green",
        "pale green",   "green-3",      "green-2",          "green-1",
        "green",        "green+1",      "green+2",          "pale aqua",
        "aqua",         "dark aqua",    "cyan",             "dark cyan",
        "light blue",   "sky blue",     "blue-2",           "blue-1",
        "blue",         "deep blue",    "very deep blue",   "violet",
        "purple",       "light purple", "magenta",          "magenta+1",
        "magenta+2",    "pink",         "magenta+4",        "magenta+5",
        "white"
    ];
list rgb = [
        <1.0,0.0,0.0>,  <1.0,0.16,0.0>, <1.0,0.32,0.0>, <1.0,0.52,0.0>,
        <1.0,0.68,0.0>, <1.0,0.84,0.0>, <1.0,1.0,0.0>,  <0.84,1.0,0.0>,
        <0.68,1.0,0.0>, <0.52,1.0,0.0>, <0.32,1.0,0.0>, <0.16,1.0,0.0>,
        <0.0,1.0,0.0>,  <0.0,1.0,0.16>, <0.0,1.0,0.32>, <0.0,1.0,0.52>,
        <0.0,1.0,0.68>, <0.0,1.0,0.84>, <0.0,1.0,1.0>,  <0.0,0.84,1.0>,
        <0.0,0.68,1.0>, <0.0,0.52,1.0>, <0.0,0.32,1.0>, <0.0,0.16,1.0>,
        <0.0,0.0,1.0>,  <0.16,0.0,1.0>, <0.32,0.0,1.0>, <0.52,0.0,1.0>,
        <0.68,0.0,1.0>, <0.84,0.0,1.0>, <1.0,0.0,1.0>,  <1.0,0.0,0.84>,
        <1.0,0.0,0.68>, <1.0,0.0,0.52>, <1.0,0.0,0.32>, <1.0,0.0,0.16>,
        <1.0,1.0,1.0>
    ];

colour(string col)
{
    integer index = llListFindList(names, [c=col]);
    if(~index)
    {
        vector color = llList2Vector(rgb, index);
        llSetPrimitiveParams([PRIM_COLOR, ALL_SIDES, color, 1, PRIM_POINT_LIGHT, TRUE, color, llList2Float(llGetPrimitiveParams([PRIM_POINT_LIGHT], 2)), 10, 0.75]);
    }
}
_____________________
Truth is a river that is always splitting up into arms that reunite. Islanded between the arms, the inhabitants argue for a lifetime as to which is the main river.
- Cyril Connolly

Without the political will to find common ground, the continual friction of tactic and counter tactic, only creates suspicion and hatred and vengeance, and perpetuates the cycle of violence.
- James Nachtwey
Diego Pannotia
Laronzo Fitzgerald
Join date: 14 Nov 2006
Posts: 37
03-17-2007 14:30
excellent! very much better than before =D teeny error

llList2Float(llGetPrimitiveParams([PRIM_POINT_LIGHT], 2)), should be

llList2Float(llGetPrimitiveParams([PRIM_POINT_LIGHT]), 2),

__________________________


However! Wonderful as that was, it slightly detracts from the point of this thread =P

Any furthur thoughts?

Many thanks to all

Mark