menu driven item giver

Im trying to create a menu driver drink giver for a bar Im creating for my house. Im tired of giving my guests a big box of drinks to fill there inventory up with stuff they do not want. so I decided to make a menu system where they select the drink they want. needless to say I hit a road block because I wouldnt be here seeking help if I didnt

the menu drops down perfectly, I can select what I want but the item will not give out the drink. I do have the drinks inside the prim, and I did triple check that each name is exactly equal to the object given. this is what I have so far

list DRINK_OPTIONS = ["Beer", "Jack", "smokes", "coctail", "vodka", "sake", "blood",]; 
integer Beer = -1234;
integer coctail = -1235 ;
integer Jack = -1245; 
integer vodka = -1243;  
integer smokes = -3454; 
integer sake = -5564; 
integer blood = -6645;    
integer CHANNEL = -8788;     


    
default { 
    state_entry() 
    { 
        llListen(CHANNEL, "", NULL_KEY, ""); // listen for dialog answers (from multiple users) 
    } // end state_entry() 

    touch_start(integer total_number) 
    { 
        llDialog(llDetectedKey(0), "what can I help you with?", DRINK_OPTIONS, CHANNEL); // present dialog on click 
        
    }// end touch_start() 

    listen(integer channel, string name, key id, string message) 
    { 
        if (llListFindList(DRINK_OPTIONS, [message]) != -1)  // verify dialog choice 
        { 
            if (message == "Beer") 
            { 
                 llGiveInventory(llDetectedKey(0),"Beer_Dag- Beer");
                 
            } 
            else if (message == "Jack") 
            { 
                 llGiveInventory(llDetectedKey(0),"Jack Daniels Whiskey");
               
            } 
            else if (message == "Smokes") 
            { 
                 llGiveInventory(llDetectedKey(0),"Smokes_Cigarette");
                 
            } 
            else if (message == "coctail") 
            { 
                 llGiveInventory(llDetectedKey(0),"(drink)**Baki Green Queen Coctail");
                 
            } 
            else if (message == "vodka") 
            { 
                 llGiveInventory(llDetectedKey(0),"YadNi s Bottle of Absynthe");
                 
            } 
            else if (message == "sake") 
            { 
                 llGiveInventory(llDetectedKey(0),"glass of sake");
                
            } 
            else if (message == "blood") 
            { 
                llGiveInventory(llDetectedKey(0),"goblet");
                
            } 
           
         
             } 
          }  
    }

you cant use llDetectedKey(0) inside a listen event
instead, listen gives you the key of the user from the dialog()
in you listen event, instead use

llGiveInventory(id, Beer_Dag- Beer"); 

You may want to look at the fridge script.

Well I aswell had a need for such a script though never gave it more than more drink to give but here is what I used I changed it up to support 3 drinks but i'm shure you can expand it to how ever you like

integer menu_handler;
integer menu_channel;
menu(key user,string title,list buttons)
{
    menu_channel = (integer)(llFrand(99999.0) * -1);
    menu_handler = llListen(menu_channel,"","","");
    llDialog(user,title,buttons,menu_channel);
    llSetTimerEvent(5.0);
}

default
{
    touch_start(integer t)
    {
        menu(llDetectedKey(0),"Care for a Drink?",["Drink1","Drink2","Drink3"]);
    }
    timer() 
    {
        llSetTimerEvent(0.0);
        llListenRemove(menu_handler);
    }
    listen(integer channel,string name,key id,string message)
    {
        if (channel == menu_channel)
        {
            llSetTimerEvent(0.0);
            llListenRemove(menu_handler);
            if(message == "Drink1")
            {
                llGiveInventory(id,"Drink1");
            }
            else if(message == "Drink2")
           {
                llGiveInventory(id,"Drink2");
            }
            else if(message == "Drink3")
           {
                llGiveInventory(id,"Drink3");
            }
        }
    }
}