Need help. how do i make a auto blue greetings card for my land.

Hi! all
i hope someone can help me.
does any one know what is the name of the "auto blue greetings card" that we get and how to make one.

If all it does is say "Hello," then all you have to do is use the default "Hello, Avatar" script that is there when you click the "New Script" button in the contents tab of a prim. Change the touch event to a sensor event or a collision_start event and you're good to go.

this is just a simple llDialog box, with no buttons... I'd suggest NOT using this method unless it contains either important need to know information in the dialog, or gives a notecard of that info from one of the buttons... otherwise you're just likely to annoy your visitors.

I am sure Mr Hema didn't ask if a blue welcome would annoy anyone
Here is my first primitive attempt I made from bits and pieces a long time ago:

//  Greater and Visitor detector
//  by Dora Gustafson august 2007
//  Refference: IBM BasicRadar

//  Purpose
//  --------------------------------------------------------------
//  With this script you can detect visitors within a radius (g_Range)
//  of the the prim that has the script.
//  If a visitor is detected and over my land (script owners land)
//  the visitor is registered and will receive a welcome sign.
//  The first sound in objects inventory will play
//  Visitors may/will be reported to the owner no matter where she is
//  in SL.
//  If 'Send IM to Email' is set in preferences she will get
//  reports in her Email when off line.
//  A visitor stays registered for g_Rate*Life seconds after he leaves
//  in order to avoid multiple registrations

//  Requirements
//  --------------------------------------------------------------
//  A single prim is all that is necessary hold the script.

//  GLOBAL VARIABLES
//  --------------------------------------------------------------

float   g_Range     = 96.0;     //  The range of the sensor in meters
float   g_Arc       = PI;       //  The ½ arc of the sensor (PI sense all 360 deg)
float   senseRate   = 1.0;      //  The repeat rate of the sensor in seconds
float   ageRate     = 5.0;      //  The repeat rate of life count in seconds
integer Life        = 6;        //  Registration will be deleted if not renewed before this number of shots
string soundName;

string WelcomMessage = "\n\t\tWelcome!\n\nYou qualify to visit this land\nStay as long as you like";
list MENU_MAIN = []; // no buttons
integer CHANNEL = 5726; // dialog channel

list Name_register  = [];       //  for detected names
list Hit_register   = [];       //  number of times each name was detected

//  EVENTS
//  --------------------------------------------------------------

default
{
    state_entry()
    {
        llSensorRepeat("", NULL_KEY, AGENT, g_Range, g_Arc, senseRate);

        //  Since we passed an empty string and key value to the sensor,
        //  this tells the sensor that we want to look for any name with
        //  any key as long as it's an AGENT

        soundName = llGetInventoryName(INVENTORY_SOUND, 0 ); // optional sound (first sound in objects inventory)
        llSetTimerEvent(ageRate);   //timer to age entries
    }

    sensor(integer num_detected)
    {
        //  ------------------------------------------------------
        //  This event will fire at the rate of senseRate in seconds
        //  after being called by either llSensor() or llSensorRepeat()
        //  ------------------------------------------------------
        integer x;
        //  This next section will loop through each one of the num_detected
        //  items properly sensed (in this case, it will be AGENTS or Avatars)
        //  and add it to a list if new.
        //  New agents are send on Instant Messenger to the prim owner
        //  and the Agent gets a 'Welcome' on the public channel
        //  If not new, then the Hit Register for the agent is reset to zero
        //  and the agents removal from register, postponed

        for(x = 0 ; x < num_detected ; x++)
        {
            //if (llGetOwner() != llDetectedKey(x))
            {
                integer position = llListFindList(Name_register, llCSV2List( llDetectedName(x) ) );
                if (position >= 0)
                    Hit_register = llListReplaceList( Hit_register, [ 0 ], position , position );
                else
                if (llOverMyLand(llDetectedKey(x)))
                {
                     Name_register = llListInsertList(Name_register, llCSV2List( llDetectedName(x)), llGetListLength( Name_register ));
                     Hit_register = llListInsertList(Hit_register, [ 0 ], llGetListLength( Hit_register ));

                     if ( llGetInventoryType( soundName ) == INVENTORY_SOUND )
                         llPlaySound( soundName, 1.0);

                     llDialog(llDetectedKey(x), WelcomMessage , MENU_MAIN, CHANNEL); // blue sign message for visitor

                     //llWhisper( PUBLIC_CHANNEL, " welcome " + llDetectedName(x) );
                     //llInstantMessage(llGetOwner(),llDetectedName(x) + " has entered" );
                }
            }
        }
     }

    timer()
    {
        // In this part the Hit Registers for each Agent are incrementet by one
        // When one register value exceeds the Limit: Life, the agent is removed
        // from the register. Next time this agent is detected he will be registered
        // and generate a new instant message and 'Welcome' (see above)

        integer i;
        integer j;
        for (i = llGetListLength( Hit_register ) - 1 ; i >= 0; i-- )
        {
            j = llList2Integer( Hit_register, i ) + 1 ;
            Hit_register = llListReplaceList(Hit_register, [ j ], i , i );
            if (j > Life)
            {
                Hit_register = llDeleteSubList( Hit_register, i, i );
                Name_register = llDeleteSubList( Name_register, i, i );
            }
        }
    }
}

The llOverMyLand function has a bug that shows near the sim border. The wiki has a work around that is NOT implemented in this code.
Happy scripting

IM greets are good. Notecard givers are good if they are the touch kind. Landmarks are on the menu. I am adding everybody with a menu greeter to my list.

like all advice here it's freely given, and was included as a social caveat that OP may not have been aware of, and would depend on their usage.

if you have a specific taboo on your sim a blue pop-up is definitely the way to go. if you have a list of extensive rules, offering that via the pop-up button is also an excellent usage. (and uses less bandwidth than an automated notecard giver) if you are just saying "hi", you can do that via llInstantMessage without forcing the user to cancel a dialog box every time they visit.

these types of things aren't always considered by people, but definitely contribute to visitor satisfaction, which can be a boon or a detriment to encouraging repeat visits, especially in a business setting, and directly affect convenience of use.

I noted it both for the benefit of the OP and anyone else that might read the thread looking for a similar solution. all useful information is good information.

I must agree with Void here, but further qualify that almost any form of greeting can be annoying, depending upon how it is used.

Any greeter that suddenly blinds me with forty lines of chat is annoying.
Any multiple dialog menu greeting that requires me to individually accept or refuse notecards, landmarks, and group invitations, and click "ignore" three or four times is annoying.

No, he didn't ask, but Void has a valid point, here. So many people don't seem to think about it, but they really should. I find myself thinking "If I WANT to LM this place, or join your group, or read your notecard, I will, once I've seen the place." Trying to shove it all down my throat when I first arrive, however, almost guarantees I will not.

One of the best I have ever seen in this regard was a thing that popped up at a small texture store, inviting me to browse the artist's stuff on XSL while I was waiting for the store to rez, and providing a link. No group invitations. landmarks, dire threats regarding the theft of content, or anything of the sort. Just an offer of convenience, and for this I was grateful.