Notecard script help

string DIE_STRING = "die";
string SCENE_TOKEN = "scene";
string OBJECT_TOKEN = "object";

list scenes;
list objectSceneStartIndices;
list objects;
list positions;
list rotations;

integer notecardLineNumber;
string notecardName;
key notecardQueryID;

integer notecardRead;
integer dieChannel;

readNextNotecardLine()
{
    notecardQueryID = llGetNotecardLine(notecardName, notecardLineNumber++);
}

default
{
    state_entry()
    {
        notecardName = llGetInventoryName(INVENTORY_NOTECARD, 0);
        readNextNotecardLine();
    }
    touch_start(integer total_number)
    {
        if (dieChannel) // non-zero if anything is rezzed
            llWhisper(dieChannel, DIE_STRING);
        dieChannel = -500000000 - (integer)llFrand(1000000000);
        // choose a random scene:
        integer sceneIndex = (integer)llFrand(llGetListLength(scenes));
        llWhisper(0, "Rezzing " + llList2String(scenes, sceneIndex));        
        integer objectIndex = llList2Integer(objectSceneStartIndices, sceneIndex);
        integer objectEndIndex = llList2Integer(objectSceneStartIndices, sceneIndex + 1);
        for (; objectIndex < objectEndIndex; objectIndex++)
            llRezObject
              ( llList2String(objects, objectIndex)
              // assuming the positions are offsets from the rezzer:
              , llGetPos() + (llList2Vector(positions, objectIndex) * llGetRot())
              , ZERO_VECTOR // velocity
              , llList2Rot(rotations, objectIndex) * llGetRot()
              , dieChannel
              );
    }
    dataserver(key queryid, string data)
    {
        if (queryid != notecardQueryID)
            return; // Triggered by a different script
        if (EOF == data)
        {
            objectSceneStartIndices += llGetListLength(objects);
            notecardRead = TRUE;
            return;
        }
        readNextNotecardLine();
        list dataList = llParseString2List(data, [" | "], []);
        string lineTypeToken = llList2String(dataList, 1);
        if (SCENE_TOKEN == lineTypeToken)
        {
            scenes += llList2String(dataList, 2);
            objectSceneStartIndices += llGetListLength(objects);
        }
        else
        if (OBJECT_TOKEN == lineTypeToken)
        {
            string objectName = llList2String(dataList, 2);
            if (INVENTORY_OBJECT != llGetInventoryType(objectName))
            {
                llSay(DEBUG_CHANNEL, "skipping missing object: " + objectName);
                return;
            }
            objects += objectName;
            positions += (vector)llList2String(dataList, 3);
            rotations += llEuler2Rot((vector)llList2String(dataList, 4));
        }
        else
            llWhisper(DEBUG_CHANNEL, "unknown token \"" + lineTypeToken 
              + "\" in line:\n" + data
              + " in notecard " + notecardName);
    }
}

string DIE_STRING = "die";  // As rezzer llWhisper() to us.

default
{
    on_rez(integer start_param)
    {
        llListen
          ( start_param // on channel passed from rezzer
          , ""          // from anything (unless we knew the name of rezzer)
          , NULL_KEY    // from anything (unless we knew the key of rezzer)
          , DIE_STRING
          );
    }
    listen(integer channel, string name, key id, string message)
    {
        // Only listening for command to die
        llDie();
        //llOwnerSay("sayanara");
    }
}